meta-nuvoton: u-boot-nuvoton: move to v2023.10
Signed-off-by: Tim Lee <timlee660101@gmail.com>
Change-Id: I6b053fcecd1a2e7d41566fd5aef87a605dfc7ca2
diff --git a/meta-nuvoton/recipes-bsp/u-boot/u-boot-fw-utils-nuvoton_2023.10.bb b/meta-nuvoton/recipes-bsp/u-boot/u-boot-fw-utils-nuvoton_2023.10.bb
new file mode 100644
index 0000000..4f06ecf
--- /dev/null
+++ b/meta-nuvoton/recipes-bsp/u-boot/u-boot-fw-utils-nuvoton_2023.10.bb
@@ -0,0 +1,42 @@
+require u-boot-common-nuvoton_${PV}.inc
+
+SUMMARY = "U-Boot bootloader fw_printenv/setenv utilities"
+DEPENDS = "mtd-utils bison-native"
+RDEPENDS:${PN} = "udev-nuvoton-mtd-partitions"
+
+PROVIDES += "u-boot-fw-utils"
+SRC_URI += "file://fw_env.config"
+
+INSANE_SKIP:${PN} = "already-stripped"
+
+EXTRA_OEMAKE:class-target = 'CROSS_COMPILE="${TARGET_PREFIX}" HOSTCC="${BUILD_CC} ${BUILD_FLAGS} ${BUILD_LDFLAGS}" CC="${CC} ${CFLAGS} ${LDFLAGS}" STRIP=true V=1'
+EXTRA_OEMAKE:class-cross = 'ARCH=${TARGET_ARCH} CC="${CC} ${CFLAGS} ${LDFLAGS}" V=1'
+
+inherit uboot-config
+
+do_compile () {
+ oe_runmake ${UBOOT_MACHINE}
+ oe_runmake envtools
+}
+
+do_install () {
+ install -d ${D}${base_sbindir}
+ install -d ${D}${sysconfdir}
+ install -m 755 ${S}/tools/env/fw_printenv ${D}${base_sbindir}/fw_printenv
+ install -m 755 ${S}/tools/env/fw_printenv ${D}${base_sbindir}/fw_setenv
+ install -m 0644 ${WORKDIR}/fw_env.config ${D}${sysconfdir}/fw_env.config
+}
+
+do_install:class-cross () {
+ install -d ${D}${bindir_cross}
+ install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_printenv
+ install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_setenv
+}
+
+SYSROOT_PREPROCESS_FUNCS:class-cross = "uboot_fw_utils_cross"
+uboot_fw_utils_cross() {
+ sysroot_stage_dir ${D}${bindir_cross} ${SYSROOT_DESTDIR}${bindir_cross}
+}
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+BBCLASSEXTEND = "cross"