meta-openpower: host-fw: New recipe to include the host firmware
This recipe will be used to bundle the bmc and host firmware into a
single image file.
The location of the host firmware image can be specified via variables.
If no host firmware image is specified, still create the default
destination directory, to mimic a blank PNOR device.
(From meta-openpower rev: d552bf6e0cf9cc1c9d4bfd650cf2765277cda980)
Change-Id: I4719cce17ae947610691a38cb0dc48ce7011db14
Signed-off-by: Adriana Kobylak <anoo@us.ibm.com>
Signed-off-by: Brad Bishop <bradleyb@fuzziesquirrel.com>
diff --git a/meta-openpower/recipes-phosphor/flash/host-fw_git.bb b/meta-openpower/recipes-phosphor/flash/host-fw_git.bb
new file mode 100644
index 0000000..00fc1fd
--- /dev/null
+++ b/meta-openpower/recipes-phosphor/flash/host-fw_git.bb
@@ -0,0 +1,33 @@
+SUMMARY = "OpenPOWER Host Firmware Image"
+DESCRIPTION = "Adds the OpenPOWER Host Firmware image to the BMC image"
+PR = "r1"
+
+inherit allarch
+
+HOST_FW_LICENSE ?= "Apache-2.0"
+HOST_FW_LIC_FILES_CHKSUM ?= "file://${COREBASE}/meta/files/common-licenses/Apache-2.0;md5=89aea4e17d99a7cacdbeed46a0096b10"
+HOST_FW_SRC_URI ?= ""
+
+LICENSE = "${HOST_FW_LICENSE}"
+LIC_FILES_CHKSUM = "${HOST_FW_LIC_FILES_CHKSUM}"
+SRC_URI = "${HOST_FW_SRC_URI}"
+
+DEPENDS = "squashfs-tools-native"
+
+S = "${WORKDIR}"
+B = "${WORKDIR}/build"
+do_compile[cleandirs] = "${B}"
+
+do_compile() {
+ if [ -n "${HOST_FW_SRC_URI}" ]; then
+ unsquashfs -d ${B}/squashfs-root ${S}/pnor.xz.squashfs
+ fi
+}
+
+do_install() {
+ install -d ${D}${datadir}/${BPN}
+
+ if [ -n "${HOST_FW_SRC_URI}" ]; then
+ install -m 0440 ${B}/squashfs-root/* ${D}${datadir}/${BPN}
+ fi
+}