diff --git a/meta-asrock/meta-x570d4u/conf/layer.conf b/meta-asrock/meta-x570d4u/conf/layer.conf
new file mode 100644
index 0000000..484b6a3
--- /dev/null
+++ b/meta-asrock/meta-x570d4u/conf/layer.conf
@@ -0,0 +1,10 @@
+# We have a conf and classes directory, add to BBPATH
+BBPATH .= ":${LAYERDIR}"
+
+# We have recipes-* directories, add to BBFILES
+BBFILES += "${LAYERDIR}/recipes-*/*/*.bb \
+            ${LAYERDIR}/recipes-*/*/*.bbappend"
+
+BBFILE_COLLECTIONS += "x570d4u-layer"
+BBFILE_PATTERN_x570d4u-layer := "^${LAYERDIR}/"
+LAYERSERIES_COMPAT_x570d4u-layer = "nanbield scarthgap"
diff --git a/meta-asrock/meta-x570d4u/conf/machine/x570d4u.conf b/meta-asrock/meta-x570d4u/conf/machine/x570d4u.conf
new file mode 100644
index 0000000..8ff4d77
--- /dev/null
+++ b/meta-asrock/meta-x570d4u/conf/machine/x570d4u.conf
@@ -0,0 +1,21 @@
+KMACHINE = "aspeed"
+KERNEL_DEVICETREE = "aspeed/${KMACHINE}-bmc-asrock-${MACHINE}.dtb"
+
+UBOOT_DEVICETREE = "ast2500-evb"
+UBOOT_MACHINE = "evb-ast2500_defconfig"
+
+FLASH_SIZE = "65536"
+
+require conf/machine/include/ast2500.inc
+require conf/machine/include/obmc-bsp-common.inc
+
+PREFERRED_PROVIDER_virtual/obmc-fan-mgmt = "packagegroup-asrock-apps"
+PREFERRED_PROVIDER_virtual/obmc-chassis-mgmt = "packagegroup-asrock-apps"
+PREFERRED_PROVIDER_virtual/obmc-flash-mgmt = "packagegroup-asrock-apps"
+PREFERRED_PROVIDER_virtual/obmc-system-mgmt = "packagegroup-asrock-apps"
+
+VIRTUAL-RUNTIME_obmc-inventory-manager = "entity-manager"
+VIRTUAL-RUNTIME_obmc-sensors-hwmon = "dbus-sensors"
+
+VIRTUAL-RUNTIME_obmc-host-state-manager = "x86-power-control"
+VIRTUAL-RUNTIME_obmc-chassis-state-manager = "x86-power-control"
diff --git a/meta-asrock/meta-x570d4u/conf/templates/default/bblayers.conf.sample b/meta-asrock/meta-x570d4u/conf/templates/default/bblayers.conf.sample
new file mode 100644
index 0000000..c533858
--- /dev/null
+++ b/meta-asrock/meta-x570d4u/conf/templates/default/bblayers.conf.sample
@@ -0,0 +1,17 @@
+# LAYER_CONF_VERSION is increased each time build/conf/bblayers.conf
+# changes incompatibly
+LCONF_VERSION = "8"
+
+BBPATH = "${TOPDIR}"
+BBFILES ?= ""
+
+BBLAYERS ?= " \
+  ##OEROOT##/meta \
+  ##OEROOT##/meta-openembedded/meta-oe \
+  ##OEROOT##/meta-openembedded/meta-networking \
+  ##OEROOT##/meta-openembedded/meta-python \
+  ##OEROOT##/meta-phosphor \
+  ##OEROOT##/meta-aspeed \
+  ##OEROOT##/meta-asrock \
+  ##OEROOT##/meta-asrock/meta-x570d4u \
+  "
diff --git a/meta-asrock/meta-x570d4u/conf/templates/default/conf-notes.txt b/meta-asrock/meta-x570d4u/conf/templates/default/conf-notes.txt
new file mode 100644
index 0000000..4819992
--- /dev/null
+++ b/meta-asrock/meta-x570d4u/conf/templates/default/conf-notes.txt
@@ -0,0 +1,3 @@
+Example build invocations:
+
+bitbake obmc-phosphor-image
diff --git a/meta-asrock/meta-x570d4u/conf/templates/default/local.conf.sample b/meta-asrock/meta-x570d4u/conf/templates/default/local.conf.sample
new file mode 100644
index 0000000..6829912
--- /dev/null
+++ b/meta-asrock/meta-x570d4u/conf/templates/default/local.conf.sample
@@ -0,0 +1,17 @@
+MACHINE ??= "x570d4u"
+DISTRO ?= "openbmc-phosphor"
+PACKAGE_CLASSES ?= "package_ipk"
+SANITY_TESTED_DISTROS:append ?= " *"
+EXTRA_IMAGE_FEATURES = "debug-tweaks"
+USER_CLASSES ?= "buildstats"
+PATCHRESOLVE = "noop"
+BB_DISKMON_DIRS = "\
+    STOPTASKS,${TMPDIR},1G,100K \
+    STOPTASKS,${DL_DIR},1G,100K \
+    STOPTASKS,${SSTATE_DIR},1G,100K \
+    STOPTASKS,/tmp,100M,100K \
+    HALT,${TMPDIR},100M,1K \
+    HALT,${DL_DIR},100M,1K \
+    HALT,${SSTATE_DIR},100M,1K \
+    HALT,/tmp,10M,1K"
+CONF_VERSION = "2"
diff --git a/meta-asrock/meta-x570d4u/recipes-asrock/packagegroups/packagegroup-asrock-apps.bb b/meta-asrock/meta-x570d4u/recipes-asrock/packagegroups/packagegroup-asrock-apps.bb
new file mode 100644
index 0000000..49b78c6
--- /dev/null
+++ b/meta-asrock/meta-x570d4u/recipes-asrock/packagegroups/packagegroup-asrock-apps.bb
@@ -0,0 +1,29 @@
+SUMMARY = "OpenBMC for ASRock - Applications"
+PR = "r1"
+
+inherit packagegroup
+
+PROVIDES = "${PACKAGES}"
+PACKAGES = " \
+        ${PN}-flash \
+        ${PN}-system \
+        "
+
+PROVIDES += "virtual/obmc-flash-mgmt"
+PROVIDES += "virtual/obmc-system-mgmt"
+
+RPROVIDES:${PN}-flash += "virtual-obmc-flash-mgmt"
+RPROVIDES:${PN}-system += "virtual-obmc-system-mgmt"
+
+SUMMARY:${PN}-flash = "ASRock Flash"
+RDEPENDS:${PN}-flash = " \
+        phosphor-ipmi-flash \
+        "
+
+SUMMARY:${PN}-system = "ASRock System"
+RDEPENDS:${PN}-system = " \
+        phosphor-host-postd \
+        phosphor-ipmi-kcs \
+        phosphor-post-code-manager \
+        phosphor-power-regulators \
+        "
diff --git a/meta-asrock/meta-x570d4u/recipes-kernel/linux/linux-aspeed/x570d4u.cfg b/meta-asrock/meta-x570d4u/recipes-kernel/linux/linux-aspeed/x570d4u.cfg
new file mode 100644
index 0000000..29af18a
--- /dev/null
+++ b/meta-asrock/meta-x570d4u/recipes-kernel/linux/linux-aspeed/x570d4u.cfg
@@ -0,0 +1,4 @@
+# include i2c super-i/o driver, but not host-side (lpc) driver
+CONFIG_SENSORS_NCT6775_CORE=y
+CONFIG_SENSORS_NCT6775_I2C=y
+CONFIG_SENSORS_NCT6775=n
diff --git a/meta-asrock/meta-x570d4u/recipes-kernel/linux/linux-aspeed_%.bbappend b/meta-asrock/meta-x570d4u/recipes-kernel/linux/linux-aspeed_%.bbappend
new file mode 100644
index 0000000..6b7b10a
--- /dev/null
+++ b/meta-asrock/meta-x570d4u/recipes-kernel/linux/linux-aspeed_%.bbappend
@@ -0,0 +1,4 @@
+FILESEXTRAPATHS:prepend := "${THISDIR}/${PN}:"
+SRC_URI:append:x570d4u = " \
+    file://x570d4u.cfg \
+"