poky: subtree update:03d4d9d68f..52a625582e
Alejandro Enedino Hernandez Samaniego (2):
documentation: Update multiconfig syntax and explanation on BBMULTICONFIG
bitbake: bitbake-user-manual: Update multiconfig syntax and explanation of BBMULTICONFIG
Alexander Kanavin (27):
ethtool, libcap: fix upstream version check
socat: turn hard readline dependency into an option
perl: make gdbm optional
python3: make gdbm optional
python3: un-break disabling the readline PACKAGECONFIG
libcheck: split /usr/bin/checkmk into its own package
iproute2: make elfutils support optional
bind: do not RDEPEND on bash
elfutils: do not depend on target libtool
license.bbclass: split incompatible license check into a helper function
license_image.bbclass: check and reject packages which have incompatible licenses
runqemu: unset another environment variable for 'egl-headless'
gobject-introspection: update to 1.62.0
glib-2.0: upgrade to 2.62.1
glib-networking: update to 2.62.1
epiphany: upgrade 3.32.4 -> 3.34.1
webkitgtk: update 2.24.4 -> 2.26.1
gtk-doc: upgrade 1.31 -> 1.32
libdazzle: upgrade 3.32.3 -> 3.34.1
libsecret: upgrade 0.19.0 -> 0.19.1
mpg123: upgrade 1.25.11 -> 1.25.12
p11-kit: upgrade 0.23.16.1 -> 0.23.18.1
vala: upgrade 0.44.7 -> 0.46.3
meson: update to 0.52.0
libmodulemd-v1: introduce the recipe
libmodulemd: remove the recipe
createrepo-c: upgrade to 0.15.1
Alistair Francis (1):
gdb: Bump from 8.3 to 8.3.1
Bruce Ashfield (2):
linux-yocto-rt/5.2: update to -rt9
linux-yocto/5.2: fix strace/ptrace long runtime issues
Changqing Li (1):
llvm: remove -mlongcall from CXXFLAGS for powerpc
Chen Qi (2):
python: CVE-2019-16056
python3: CVE-2019-16056
Christophe PRIOUZEAU (23):
ovmf: Clarify BSD license variant
wpa-supplicant: Clarify BSD license variant
cmake: Clarify BSD license variant
flex: Clarify BSD license variant
file: Clarify BSD license variant
python-async: Clarify BSD license variant
python-smmap: Clarify BSD license variant
libtirpc: Clarify BSD license variant
libarchive: Clarify BSD license variant
pbzip2: Clarify BSD license variant
lighttpd: Clarify BSD license variant
rpcbind: Clarify BSD license variant
tcp-wrappers: Clarify BSD license variant
libxpm: Clarify BSD license variant
libogg: Clarify BSD license variant
libvorbis: Clarify BSD license variant
libtheora: Clarify BSD license variant
speex: Clarify BSD license variant
speexdsp: Clarify BSD license variant
libwebp: Clarify BSD license variant
libpcre: Clarify BSD license variant
p11-kit: Clarify BSD license variant
libpcap: Clarify BSD license variant
David Reyna (1):
bitbake: toaster: Enable Zeus branch in place of Thud
Jaewon Lee (1):
devtool/standard.py: Not filtering devtool workspace for devtool finish
Joerg Vehlow (1):
runqemu: Remove disabling of high resolution timer
Kai Kang (1):
dnf.py: check busybox for case test_dnf_installroot
Khem Raj (7):
musl: Update to latest
qemu: Add ppc64 to QEMU_TARGETS
ghostscript: Disable libpaper
perl: Handle PACKAGES_DYNAMIC for perl-native
gnu-efi: Do not use gcc-only options when building with clang
llvm: Update to 9.0.0
glib-2.0: Fix build with clang compiler
Martin Jansa (1):
kernel-devicetree.bbclass: add missing backslash
Maxime Roussin-Bélanger (4):
meta: add missing some description in devtools
meta: simplify over descriptive descriptions in devtools
shadow: update homepage and bugtracker
meta: add missing description in recipes-extended
Michael Cooper (1):
wic/direct: Partition numbering is broken for MBR primary partition #4
Michael Halstead (1):
uninative: Update to 2.7 release
Peiran Hong (1):
dbus: Change path of system_bus_socket from /var/run/dbus/ to /run/dbus/
Philip Balister (1):
oe.svg: Copy artwork from openembedded-classic.
Richard Purdie (8):
layer.conf: Update for zeus series
layer.conf: Update for zeus series
bitbake: bitbake: Update to version 1.44.0
poky.conf: Bump version for 3.0 zeus release
build-appliance-image: Update to master head revision
scripts/gen-lockedsig-cache: Don't list paths which don't exist
readline-native: Fix builds on tumbleweed
build-appliance-image: Update to master head revision
Ross Burton (15):
meson: fix RDEPENDS
meson: update patch status
meson: fix cross detection
systemd: don't install udev.pc manually
systemd: don't install systemd-hwdb-update.service
insane: add check for perllocal.pod
ref-system-requirements: update support distribution list
toolchain-scripts: export READELF
harfbuzz: add PACKAGECONFIGs for all the optional dependencies
oeqa/sdk: improve Meson test
pango: remove obsolete libtool FILES
bluez5: add needed character encoding for ptests
oeqa/selftest/imagefeatures: improve test_hypervisor_fmts
poky: add Ubuntu 19.04 as a supported distribution
kernel-dev: don't use _append +=
Trevor Gamblin (3):
watchdog: fix PIDFile path in existing patch
lib/oe/terminal.py: fix gnome-terminal start behavior
systemd.bbclass: add RMINITDIR for nativesdk builds
Zang Ruochen (8):
libpcap:upgrade 1.9.0 -> 1.9.1
sqlite3:upgrade 3.29 -> 3.30
expat:upgrade 2.2.8 -> 2.2.9
librepo:upgrade 1.10.5 -> 1.10.6
msmtp:upgrade 1.8.5 -> 1.8.6
libxfont2:upgrade 2.0.3 -> 2.0.4
fribidi:upgrade 1.0.5 -> 1.0.7
iso-codes:upgrade 4.3 -> 4.4
Change-Id: I15802c5814d0dbfd90f16d392dbd975f917a8032
Signed-off-by: Brad Bishop <bradleyb@fuzziesquirrel.com>
diff --git a/poky/meta/recipes-gnome/gobject-introspection/gobject-introspection_1.62.0.bb b/poky/meta/recipes-gnome/gobject-introspection/gobject-introspection_1.62.0.bb
new file mode 100644
index 0000000..c925115
--- /dev/null
+++ b/poky/meta/recipes-gnome/gobject-introspection/gobject-introspection_1.62.0.bb
@@ -0,0 +1,204 @@
+SUMMARY = "Middleware layer between GObject-using C libraries and language bindings"
+HOMEPAGE = "https://wiki.gnome.org/action/show/Projects/GObjectIntrospection"
+BUGTRACKER = "https://bugzilla.gnome.org/"
+SECTION = "libs"
+LICENSE = "LGPLv2+ & GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=c434e8128a68bedd59b80b2ac1eb1c4a \
+ file://tools/compiler.c;endline=20;md5=fc5007fc20022720e6c0b0cdde41fabd \
+ file://giscanner/sourcescanner.c;endline=22;md5=194d6e0c1d00662f32d030ce44de8d39 \
+ file://girepository/giregisteredtypeinfo.c;endline=21;md5=661847611ae6979465415f31a759ba27 \
+ "
+
+SRC_URI = "${GNOME_MIRROR}/${BPN}/${@oe.utils.trim_version("${PV}", 2)}/${BPN}-${PV}.tar.xz \
+ file://0003-giscanner-add-use-binary-wrapper-option.patch \
+ file://0004-giscanner-add-a-use-ldd-wrapper-option.patch \
+ file://0005-Prefix-pkg-config-paths-with-PKG_CONFIG_SYSROOT_DIR-.patch \
+ file://0001-giscanner-add-a-lib-dirs-envvar-option.patch \
+ file://0001-giscanner-ignore-error-return-codes-from-ldd-wrapper.patch \
+ file://0001-Port-cross-compilation-support-to-meson.patch \
+ file://0001-meson.build-disable-tests-when-cross-compiling.patch \
+ "
+
+SRC_URI[md5sum] = "37278eab3704e42234b6080b8cf241f1"
+SRC_URI[sha256sum] = "b1ee7ed257fdbc008702bdff0ff3e78a660e7e602efa8f211dc89b9d1e7d90a2"
+
+SRC_URI_append_class-native = " file://0001-Relocate-the-repository-directory-for-native-builds.patch"
+
+inherit meson pkgconfig gtk-doc python3native qemu gobject-introspection-data upstream-version-is-even multilib_script
+
+GTKDOC_MESON_OPTION = "gtk_doc"
+
+MULTILIB_SCRIPTS = "${PN}:${bindir}/g-ir-annotation-tool ${PN}:${bindir}/g-ir-scanner"
+
+DEPENDS_append = " libffi zlib glib-2.0 python3 flex-native bison-native autoconf-archive"
+
+# target build needs qemu to run temporary introspection binaries created
+# on the fly by g-ir-scanner and a native version of itself to run
+# native versions of its own tools during build.
+# Also prelink-rtld is used to find out library dependencies of introspection binaries
+# (standard ldd doesn't work when cross-compiling).
+DEPENDS_class-target_append = " gobject-introspection-native qemu-native prelink-native"
+
+# needed for writing out the qemu wrapper script
+export STAGING_DIR_HOST
+export B
+
+PACKAGECONFIG ?= ""
+PACKAGECONFIG[doctool] = "-Ddoctool=true,-Ddoctool=false,python3-mako,"
+
+# Configure target build to use native tools of itself and to use a qemu wrapper
+# and optionally to generate introspection data
+EXTRA_OEMESON_class-target = " \
+ -Denable-host-gi=true \
+ -Denable-gi-cross-wrapper=${B}/g-ir-scanner-qemuwrapper \
+ -Denable-gi-ldd-wrapper=${B}/g-ir-scanner-lddwrapper \
+ -Dpkgconfig-sysroot-path=${PKG_CONFIG_SYSROOT_DIR} \
+ ${@bb.utils.contains('GI_DATA_ENABLED', 'True', '-Denable-introspection-data=true', '-Denable-introspection-data=false', d)} \
+ ${@'-Dgir_dir_prefix=${libdir}' if d.getVar('MULTILIBS') else ''} \
+"
+
+# Need to ensure ld.so.conf exists so prelink-native works
+# both before we build and if we install from sstate
+do_configure[prefuncs] += "gobject_introspection_preconfigure"
+python gobject_introspection_preconfigure () {
+ oe.utils.write_ld_so_conf(d)
+}
+
+do_configure_prepend_class-native() {
+ # Tweak the native python scripts so that they don't refer to the
+ # full path of native python binary (the solution is taken from glib-2.0 recipe)
+ # This removes the risk of exceeding Linux kernel's shebang line limit (128 bytes)
+ sed -i -e '1s,#!.*,#!${USRBINPATH}/env python3,' ${S}/tools/g-ir-tool-template.in
+}
+
+do_configure_prepend_class-target() {
+ # Write out a qemu wrapper that will be given to gi-scanner so that it
+ # can run target helper binaries through that.
+ qemu_binary="${@qemu_wrapper_cmdline(d, '$STAGING_DIR_HOST', ['\\$GIR_EXTRA_LIBS_PATH','.libs','$STAGING_DIR_HOST/${libdir}','$STAGING_DIR_HOST/${base_libdir}'])}"
+ cat > ${B}/g-ir-scanner-qemuwrapper << EOF
+#!/bin/sh
+# Use a modules directory which doesn't exist so we don't load random things
+# which may then get deleted (or their dependencies) and potentially segfault
+export GIO_MODULE_DIR=${STAGING_LIBDIR}/gio/modules-dummy
+
+$qemu_binary "\$@"
+if [ \$? -ne 0 ]; then
+ echo "If the above error message is about missing .so libraries, then setting up GIR_EXTRA_LIBS_PATH in the recipe should help."
+ echo "(typically like this: GIR_EXTRA_LIBS_PATH=\"$""{B}/something/.libs\" )"
+ exit 1
+fi
+EOF
+ chmod +x ${B}/g-ir-scanner-qemuwrapper
+
+ # Write out a wrapper for g-ir-scanner itself, which will be used when building introspection files
+ # for glib-based packages. This wrapper calls the native version of the scanner, and tells it to use
+ # a qemu wrapper for running transient target binaries produced by the scanner, and an include directory
+ # from the target sysroot.
+ cat > ${B}/g-ir-scanner-wrapper << EOF
+#!/bin/sh
+# This prevents g-ir-scanner from writing cache data to $HOME
+export GI_SCANNER_DISABLE_CACHE=1
+
+g-ir-scanner --lib-dirs-envvar=GIR_EXTRA_LIBS_PATH --use-binary-wrapper=${STAGING_BINDIR}/g-ir-scanner-qemuwrapper --use-ldd-wrapper=${STAGING_BINDIR}/g-ir-scanner-lddwrapper --add-include-path=${STAGING_DATADIR}/gir-1.0 --add-include-path=${STAGING_LIBDIR}/gir-1.0 "\$@"
+EOF
+ chmod +x ${B}/g-ir-scanner-wrapper
+
+ # Write out a wrapper for g-ir-compiler, which runs the target version of it through qemu.
+ # g-ir-compiler writes out the raw content of a C struct to disk, and therefore is architecture dependent.
+ cat > ${B}/g-ir-compiler-wrapper << EOF
+#!/bin/sh
+${STAGING_BINDIR}/g-ir-scanner-qemuwrapper ${STAGING_BINDIR}/g-ir-compiler "\$@"
+EOF
+ chmod +x ${B}/g-ir-compiler-wrapper
+
+ # Write out a wrapper to use instead of ldd, which does not work when a binary is built
+ # for a different architecture
+ cat > ${B}/g-ir-scanner-lddwrapper << EOF
+#!/bin/sh
+prelink-rtld --root=$STAGING_DIR_HOST "\$@"
+EOF
+ chmod +x ${B}/g-ir-scanner-lddwrapper
+
+ # Also tweak the target python scripts so that they don't refer to the
+ # native version of python binary (the solution is taken from glib-2.0 recipe)
+ sed -i -e '1s,#!.*,#!${USRBINPATH}/env python3,' ${S}/tools/g-ir-tool-template.in
+}
+
+do_compile_prepend() {
+ # This prevents g-ir-scanner from writing cache data to $HOME
+ export GI_SCANNER_DISABLE_CACHE=1
+
+ # Needed to run g-ir unit tests, which won't be able to find the built libraries otherwise
+ export GIR_EXTRA_LIBS_PATH=$B/.libs
+}
+
+# Our wrappers need to be available system-wide, because they will be used
+# to build introspection files for all other gobject-based packages
+do_install_append_class-target() {
+ install -d ${D}${bindir}/
+ install ${B}/g-ir-scanner-qemuwrapper ${D}${bindir}/
+ install ${B}/g-ir-scanner-wrapper ${D}${bindir}/
+ install ${B}/g-ir-compiler-wrapper ${D}${bindir}/
+ install ${B}/g-ir-scanner-lddwrapper ${D}${bindir}/
+}
+
+# we need target versions of introspection tools in sysroot so that they can be run via qemu
+# when building introspection files in other packages
+SYSROOT_DIRS_append_class-target = " ${bindir}"
+
+SYSROOT_PREPROCESS_FUNCS_append_class-target = " gi_binaries_sysroot_preprocess"
+gi_binaries_sysroot_preprocess() {
+ # Tweak the binary names in the introspection pkgconfig file, so that it
+ # picks up our wrappers which do the cross-compile and qemu magic.
+ sed -i \
+ -e "s|g_ir_scanner=.*|g_ir_scanner=${bindir}/g-ir-scanner-wrapper|" \
+ -e "s|g_ir_compiler=.*|g_ir_compiler=${bindir}/g-ir-compiler-wrapper|" \
+ ${SYSROOT_DESTDIR}${libdir}/pkgconfig/gobject-introspection-1.0.pc
+}
+
+SYSROOT_PREPROCESS_FUNCS_append = " gi_ldsoconf_sysroot_preprocess"
+gi_ldsoconf_sysroot_preprocess () {
+ mkdir -p ${SYSROOT_DESTDIR}${bindir}
+ dest=${SYSROOT_DESTDIR}${bindir}/postinst-ldsoconf-${PN}
+ echo "#!/bin/sh" > $dest
+ echo "mkdir -p ${STAGING_DIR_TARGET}${sysconfdir}" >> $dest
+ echo "echo ${base_libdir} >> ${STAGING_DIR_TARGET}${sysconfdir}/ld.so.conf" >> $dest
+ echo "echo ${libdir} >> ${STAGING_DIR_TARGET}${sysconfdir}/ld.so.conf" >> $dest
+ chmod 755 $dest
+}
+
+# Remove wrapper files from the package, only used for cross-compiling
+PACKAGE_PREPROCESS_FUNCS += "gi_package_preprocess"
+gi_package_preprocess() {
+ rm -f ${PKGD}${bindir}/g-ir-scanner-qemuwrapper
+ rm -f ${PKGD}${bindir}/g-ir-scanner-wrapper
+ rm -f ${PKGD}${bindir}/g-ir-compiler-wrapper
+ rm -f ${PKGD}${bindir}/g-ir-scanner-lddwrapper
+}
+
+SSTATE_SCAN_FILES += "g-ir-scanner-qemuwrapper g-ir-scanner-wrapper g-ir-compiler-wrapper g-ir-scanner-lddwrapper Gio-2.0.gir postinst-ldsoconf-${PN}"
+
+# .typelib files are needed at runtime and so they go to the main package
+FILES_${PN}_append = " ${libdir}/girepository-*/*.typelib"
+
+# .gir files go to dev package, as they're needed for developing (but not for running)
+# things that depends on introspection.
+FILES_${PN}-dev_append = " ${datadir}/gir-*/*.gir ${libdir}/gir-*/*.gir"
+FILES_${PN}-dev_append = " ${datadir}/gir-*/*.rnc"
+
+# These are used by gobject-based packages
+# to generate transient introspection binaries
+FILES_${PN}-dev_append = " ${datadir}/gobject-introspection-1.0/gdump.c \
+ ${datadir}/gobject-introspection-1.0/Makefile.introspection"
+
+# These are used by dependent packages (e.g. pygobject) to build their
+# testsuites.
+FILES_${PN}-dev_append = " ${datadir}/gobject-introspection-1.0/tests/*.c \
+ ${datadir}/gobject-introspection-1.0/tests/*.h"
+
+FILES_${PN}-dbg += "${libdir}/gobject-introspection/giscanner/.debug/"
+FILES_${PN}-staticdev += "${libdir}/gobject-introspection/giscanner/*.a"
+
+RDEPENDS_${PN} = "python3-pickle python3-xml"
+
+BBCLASSEXTEND = "native"