| Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 1 | SUMMARY = "GNOME XSLT library" |
| 2 | DESCRIPTION = "libxslt is the XSLT C parser and toolkit developed for the Gnome project. \ |
| 3 | XSLT itself is a an XML language to define transformation for XML. Libxslt is based on \ |
| 4 | libxml2 the XML C library developed for the GNOME project. It also implements most of \ |
| 5 | the EXSLT set of processor-portable extensions functions and some of Saxon's evaluate \ |
| 6 | and expressions extensions." |
| 7 | HOMEPAGE = "http://xmlsoft.org/XSLT/" |
| 8 | BUGTRACKER = "https://bugzilla.gnome.org/" |
| 9 | |
| 10 | LICENSE = "MIT" |
| 11 | LIC_FILES_CHKSUM = "file://Copyright;md5=0cd9a07afbeb24026c9b03aecfeba458" |
| 12 | |
| 13 | SECTION = "libs" |
| 14 | DEPENDS = "libxml2" |
| 15 | |
| 16 | SRC_URI = "https://download.gnome.org/sources/libxslt/1.1/libxslt-${PV}.tar.xz" |
| 17 | |
| Patrick Williams | da29531 | 2023-12-05 16:48:56 -0600 | [diff] [blame] | 18 | SRC_URI[sha256sum] = "2a20ad621148339b0759c4d4e96719362dee64c9a096dbba625ba053846349f0" |
| Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 19 | |
| 20 | UPSTREAM_CHECK_REGEX = "libxslt-(?P<pver>\d+(\.\d+)+)\.tar" |
| 21 | |
| Andrew Geissler | 8f84068 | 2023-07-21 09:09:43 -0500 | [diff] [blame] | 22 | CVE_STATUS[CVE-2022-29824] = "not-applicable-config: Static linking to libxml2 is not enabled." |
| Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame] | 23 | |
| Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 24 | S = "${WORKDIR}/libxslt-${PV}" |
| 25 | |
| 26 | BINCONFIG = "${bindir}/xslt-config" |
| 27 | |
| 28 | inherit autotools pkgconfig binconfig-disabled lib_package multilib_header |
| 29 | |
| 30 | do_configure:prepend () { |
| 31 | # We don't DEPEND on binutils for ansidecl.h so ensure we don't use the header. |
| 32 | # This can be removed when upgrading to 1.1.34. |
| 33 | sed -i -e 's/ansidecl.h//' ${S}/configure.ac |
| 34 | |
| 35 | # The timestamps in the 1.1.28 tarball are messed up causing this file to |
| 36 | # appear out of date. Touch it so that we don't try to regenerate it. |
| 37 | touch ${S}/doc/xsltproc.1 |
| 38 | } |
| 39 | |
| Patrick Williams | 2390b1b | 2022-11-03 13:47:49 -0500 | [diff] [blame] | 40 | EXTRA_OECONF = "--without-python --without-debug --without-mem-debug --without-crypto" |
| Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 41 | # older versions of this recipe had ${PN}-utils |
| 42 | RPROVIDES:${PN}-bin += "${PN}-utils" |
| 43 | RCONFLICTS:${PN}-bin += "${PN}-utils" |
| 44 | RREPLACES:${PN}-bin += "${PN}-utils" |
| 45 | |
| 46 | # This is only needed until libxml can load the relocated catalog itself |
| 47 | do_install:append:class-native () { |
| 48 | create_wrapper ${D}/${bindir}/xsltproc XML_CATALOG_FILES=${sysconfdir}/xml/catalog |
| 49 | } |
| 50 | |
| 51 | do_install:append () { |
| 52 | oe_multilib_header libxslt/xsltconfig.h |
| 53 | } |
| 54 | |
| 55 | FILES:${PN} += "${libdir}/libxslt-plugins" |
| 56 | FILES:${PN}-dev += "${libdir}/xsltConf.sh" |
| 57 | |
| 58 | BBCLASSEXTEND = "native nativesdk" |