diff --git a/common/recipes-bsp/u-boot/u-boot-common.inc b/common/recipes-bsp/u-boot/u-boot-common.inc
new file mode 100644
index 0000000..8e278bd
--- /dev/null
+++ b/common/recipes-bsp/u-boot/u-boot-common.inc
@@ -0,0 +1,17 @@
+HOMEPAGE = "https://github.com/openbmc/u-boot"
+SECTION = "bootloaders"
+
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://Licenses/README;md5=a2c678cfd4a4d97135585cad908541c6"
+PE = "1"
+
+# We use the revision in order to avoid having to fetch it from the
+# repo during parse
+SRCREV = "7fb88a88d08c19b0e6f88c0a484ab001a4476a27"
+
+UBRANCH = "v2016.07-aspeed-openbmc"
+SRC_URI = "git://git@github.com/openbmc/u-boot.git;branch=${UBRANCH};protocol=https"
+
+S = "${WORKDIR}/git"
+
+PV = "v2016.07+git${SRCPV}"
diff --git a/common/recipes-bsp/u-boot/u-boot-fw-utils_2016.07.bb b/common/recipes-bsp/u-boot/u-boot-fw-utils_2016.07.bb
new file mode 100644
index 0000000..e5a9036
--- /dev/null
+++ b/common/recipes-bsp/u-boot/u-boot-fw-utils_2016.07.bb
@@ -0,0 +1,34 @@
+SUMMARY = "U-Boot bootloader fw_printenv/setenv utilities"
+DEPENDS = "mtd-utils"
+
+require u-boot-common.inc
+
+INSANE_SKIP_${PN} = "already-stripped"
+EXTRA_OEMAKE_class-target = 'CROSS_COMPILE=${TARGET_PREFIX} CC="${CC} ${CFLAGS} ${LDFLAGS}" V=1'
+EXTRA_OEMAKE_class-cross = 'ARCH=${TARGET_ARCH} CC="${CC} ${CFLAGS} ${LDFLAGS}" V=1'
+
+inherit uboot-config
+
+do_compile () {
+	oe_runmake ${UBOOT_MACHINE}
+	oe_runmake env
+}
+
+do_install () {
+	install -d ${D}${base_sbindir}
+	install -d ${D}${sysconfdir}
+	install -m 755 ${S}/tools/env/fw_printenv ${D}${base_sbindir}/fw_printenv
+	install -m 755 ${S}/tools/env/fw_printenv ${D}${base_sbindir}/fw_setenv
+	install -m 0644 ${S}/tools/env/fw_env.config ${D}${sysconfdir}/fw_env.config
+}
+
+do_install_class-cross () {
+	install -d ${D}${bindir_cross}
+	install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_printenv
+	install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_setenv
+}
+
+SYSROOT_DIRS_append_class-cross = " ${bindir_cross}"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+BBCLASSEXTEND = "cross"
diff --git a/common/recipes-bsp/u-boot/u-boot_2016.07.bb b/common/recipes-bsp/u-boot/u-boot_2016.07.bb
new file mode 100644
index 0000000..0df7f2b
--- /dev/null
+++ b/common/recipes-bsp/u-boot/u-boot_2016.07.bb
@@ -0,0 +1,4 @@
+require recipes-bsp/u-boot/u-boot.inc
+require u-boot-common.inc
+
+DEPENDS += "dtc-native"