meta-google: add google-ipmi-sys package
meta-google: Add the google-ipmi-sys package. This package handles a
series of OEM IPMI commands we expect to exist to provide information to
the host software infrastructure.
Tested: Verified the daemon and systemd target are installed when added
to the obmc-phosphor-image.
Change-Id: I6942cb0952fb639c94669f8562f8b1e430028d26
Signed-off-by: Patrick Venture <venture@google.com>
diff --git a/recipes-google/ipmi/google-ipmi-sys.bb b/recipes-google/ipmi/google-ipmi-sys.bb
new file mode 100644
index 0000000..b6eaaa8
--- /dev/null
+++ b/recipes-google/ipmi/google-ipmi-sys.bb
@@ -0,0 +1,36 @@
+HOMEPAGE = "http://github.com/openbmc/google-ipmi-sys"
+SUMMARY = "Google Sys OEM commands"
+DESCRIPTION = "Google sys OEM commands"
+
+inherit autotools pkgconfig
+inherit obmc-phosphor-license
+inherit systemd
+inherit obmc-phosphor-ipmiprovider-symlink
+
+DEPENDS += "autoconf-archive-native"
+DEPENDS += "sdbusplus"
+DEPENDS += "phosphor-logging"
+
+# We depend on this to be built first so we can build our providers.
+DEPENDS += "phosphor-ipmi-host"
+
+RDEPENDS_${PN} += "sdbusplus phosphor-dbus-interfaces"
+
+S = "${WORKDIR}/git"
+SRC_URI = "git://github.com/openbmc/google-ipmi-sys"
+SRCREV = "f9a19b80bea5987292e61b8b2aedcc3baedcaf8f"
+
+FILES_${PN}_append = " ${libdir}/ipmid-providers/lib*${SOLIBS}"
+FILES_${PN}_append = " ${libdir}/host-ipmid/lib*${SOLIBS}"
+FILES_${PN}_append = " ${libdir}/net-ipmid/lib*${SOLIBS}"
+FILES_${PN}-dev_append = " ${libdir}/ipmid-providers/lib*${SOLIBSDEV} ${libdir}/ipmid-providers/*.la"
+
+HOSTIPMI_PROVIDER_LIBRARY += "libsyscmds.so"
+
+SYSTEMD_PACKAGES = "${PN}"
+SYSTEMD_SERVICE_${PN} = "gbmc-psu-hardreset.target"
+
+do_install_append() {
+ install -d ${D}${systemd_system_unitdir}
+ install -m 0644 ${S}/gbmc-psu-hardreset.target ${D}${systemd_system_unitdir}
+}