meta-phosphor: inventory: enable non-native recipes
There exists a number native class recipes throughout meta-phosphor
that simply provide a data (often YAML) file as input to building
another application.
Having these data file recipes implemented as native class recipes
prevents the use of machine overrides because bitbake (rightfully so)
discards machine qualifiers from native recipes. Further, data files
aren't really any different than library header files and those are
consumed by recipes as target class recipes that are DEPENDed on. Do
the same thing for data file recipes.
Change-Id: Ic1e648dbaf1dbf8156679d840331d9662c8a9c72
Signed-off-by: Brad Bishop <bradleyb@fuzziesquirrel.com>
diff --git a/recipes-phosphor/inventory/phosphor-inventory-manager-assettag-native.bb b/recipes-phosphor/inventory/phosphor-inventory-manager-assettag-native.bb
deleted file mode 100644
index b02ea28..0000000
--- a/recipes-phosphor/inventory/phosphor-inventory-manager-assettag-native.bb
+++ /dev/null
@@ -1,21 +0,0 @@
-SUMMARY = "Recipe to create AssetTag property in inventory manager"
-PR = "r1"
-LICENSE = "Apache-2.0"
-LIC_FILES_CHKSUM = "file://${PHOSPHORBASE}/COPYING.apache-2.0;md5=34400b68072d710fecd0a2940a0d1658"
-
-inherit native
-inherit phosphor-inventory-manager
-
-PROVIDES += "virtual/phosphor-inventory-manager-assettag"
-
-SRC_URI += "file://assettag.yaml"
-
-S = "${WORKDIR}"
-
-do_install() {
- # This recipe would provide the yaml for inventory manager to
- # create AssetTag property at startup
-
- install -d ${D}${base_datadir}/events.d/
- install assettag.yaml ${D}${base_datadir}/events.d/assettag.yaml
-}
diff --git a/recipes-phosphor/inventory/phosphor-inventory-manager-assettag.bb b/recipes-phosphor/inventory/phosphor-inventory-manager-assettag.bb
new file mode 100644
index 0000000..2dd6e28
--- /dev/null
+++ b/recipes-phosphor/inventory/phosphor-inventory-manager-assettag.bb
@@ -0,0 +1,18 @@
+SUMMARY = "Recipe to create AssetTag property in inventory manager"
+PR = "r1"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://${PHOSPHORBASE}/COPYING.apache-2.0;md5=34400b68072d710fecd0a2940a0d1658"
+
+inherit allarch
+inherit phosphor-inventory-manager
+
+PROVIDES += "virtual/phosphor-inventory-manager-assettag"
+S = "${WORKDIR}"
+
+SRC_URI = "file://assettag.yaml"
+
+do_install() {
+ install -D assettag.yaml ${D}${base_datadir}/events.d/assettag.yaml
+}
+
+FILES_${PN} += "${base_datadir}/events.d/assettag.yaml"
diff --git a/recipes-phosphor/inventory/phosphor-inventory-manager_git.bb b/recipes-phosphor/inventory/phosphor-inventory-manager_git.bb
index 1b54dd5..520cdcc 100644
--- a/recipes-phosphor/inventory/phosphor-inventory-manager_git.bb
+++ b/recipes-phosphor/inventory/phosphor-inventory-manager_git.bb
@@ -15,7 +15,7 @@
require phosphor-inventory-manager.inc
DEPENDS += " \
- ${PN}-config-native \
+ phosphor-inventory-manager-assettag \
phosphor-dbus-interfaces \
phosphor-dbus-interfaces-native \
phosphor-logging \
@@ -33,11 +33,11 @@
S = "${WORKDIR}/git"
EXTRA_OECONF = " \
- YAML_PATH=${STAGING_DIR_NATIVE}${base_datadir} \
+ YAML_PATH=${STAGING_DIR_HOST}${base_datadir} \
BUSNAME=${OBMC_INVENTORY_MGR_IFACE} \
INVENTORY_ROOT=${OBMC_INVENTORY_PATH} \
IFACE=${OBMC_INVENTORY_MGR_IFACE} \
- IFACES_PATH=${STAGING_DIR_NATIVE}${yaml_dir} \
+ IFACES_PATH=${STAGING_DIR_HOST}${yaml_dir} \
"
PACKAGECONFIG ??= ""