Add webui-vue recipe
webui-vue is a vue rewrite of the phosphor-webui.
This recipe is a copy from the phosphor-webui recipe.
Left in things like the allarch, proxy (needed for corporate
proxies), and removing node_modules before building.
Existing webui recipe:
https://github.com/openbmc/openbmc/blob/master/meta-phosphor/recipes-phosphor/webui/phosphor-webui_git.bb
Targeting June 2020 for the vue rewrite to be of feature parity with
phosphor-webui.
More information on the vue rewrite can be found on the mailing list.
Tested: Changed line 5 of
meta-ibm/meta-witherspoon/recipes-phosphor/packagegroups/packagegroup-obmc-apps.bbappend
to webui-vue and loaded on a Witherspoon.
Change-Id: Ic02079ae88bf2fe41d90741676879aba3a25377e
Signed-off-by: Gunnar Mills <gmills@us.ibm.com>
diff --git a/recipes-phosphor/webui/webui-vue_git.bb b/recipes-phosphor/webui/webui-vue_git.bb
new file mode 100644
index 0000000..2ec49ed
--- /dev/null
+++ b/recipes-phosphor/webui/webui-vue_git.bb
@@ -0,0 +1,47 @@
+# This recipe requires online access to build, as it uses NPM for dependency
+# management and resolution.
+PR = "r1"
+PV = "1.0+git${SRCPV}"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=e3fc50a88d0a364313df4b21ef20c29e"
+
+SRC_URI = "git://github.com/openbmc/webui-vue.git"
+SRCREV = "28cb682967ef35b90f295834d2ffb105e1d30e21"
+S = "${WORKDIR}/git"
+
+DEPENDS_prepend = "nodejs-native "
+
+# allarch is required because the files this recipe produces (html and
+# javascript) are valid for any target, regardless of architecture. The allarch
+# class removes your compiler definitions, as it assumes that anything that
+# requires a compiler is platform specific. Unfortunately, one of the build
+# tools uses libsass for compiling the css templates, and it needs a compiler to
+# build the library that it then uses to compress the scss into normal css.
+# Enabling allarch, then re-adding the compiler flags was the best of the bad
+# options
+
+inherit allarch
+
+export CXX = "${BUILD_CXX}"
+export CC = "${BUILD_CC}"
+export CFLAGS = "${BUILD_CFLAGS}"
+export CPPFLAGS = "${BUILD_CPPFLAGS}"
+export CXXFLAGS = "${BUILD_CXXFLAGS}"
+
+FILES_${PN} += "${datadir}/www/*"
+
+do_compile () {
+ cd ${S}
+ rm -rf node_modules
+ npm --loglevel info --proxy=${http_proxy} --https-proxy=${https_proxy} install
+ npm run build
+}
+
+do_install () {
+ # create directory structure
+ install -d ${D}${datadir}/www
+ cp -r ${S}/dist/** ${D}${datadir}/www
+ find ${D}${datadir}/www -type f -exec chmod a=r,u+w '{}' +
+ find ${D}${datadir}/www -type d -exec chmod a=rx,u+w '{}' +
+}
+