commit 9819cb9533f430797d47dadff558cf4462670976
author William A. Kennington III <wak@google.com> Mon Sep 16 18:29:53 2019 -0700
committer Brad Bishop <radsquirrel@gmail.com> Tue Sep 24 23:56:27 2019 +0000
tree 2885dbbf5e65a3b7fe2f204b1ae0a53fcf31e4e9
parent 11e32d600be46ecd574a10164759079a1472a283

nuvoton: Apply image overrides to all image types

Right now, nuvoton overrides needed for generating and applying the
bootblock are not applied to images other than obmc-phosphor-image. This
means that core-image-minimal is unbootable on nuvoton platforms.

This change makes the nuvoton overrides apply globally to all images.

Change-Id: Ifc99f68ba349e9cf5bbda902ad74948668ad2ead
Signed-off-by: William A. Kennington III <wak@google.com>

classes/image_types_phosphor_nuvoton.bbclass

diff --git a/classes/image_types_phosphor_nuvoton.bbclass b/classes/image_types_phosphor_nuvoton.bbclass
new file mode 100644
index 0000000..16112e6
--- /dev/null
+++ b/classes/image_types_phosphor_nuvoton.bbclass
@@ -0,0 +1,46 @@
+UBOOT_BINARY := "u-boot.${UBOOT_SUFFIX}"
+BOOTBLOCK = "Poleg_bootblock.bin"
+FULL_SUFFIX = "full"
+MERGED_SUFFIX = "merged"
+UBOOT_SUFFIX_append = ".${MERGED_SUFFIX}"
+
+# Prepare the Bootblock and U-Boot images using npcm7xx-bingo
+do_prepare_bootloaders() {
+    local olddir="$(pwd)"
+    cd ${DEPLOY_DIR_IMAGE}
+    bingo ${STAGING_DIR_NATIVE}/${bindir}/BootBlockAndHeader_EB.xml \
+            -o ${DEPLOY_DIR_IMAGE}/${BOOTBLOCK}.${FULL_SUFFIX}
+
+    bingo ${STAGING_DIR_NATIVE}/${bindir}/UbootHeader_EB.xml \
+            -o ${DEPLOY_DIR_IMAGE}/${UBOOT_BINARY}.${FULL_SUFFIX}
+
+    bingo ${STAGING_DIR_NATIVE}/${bindir}/mergedBootBlockAndUboot.xml \
+            -o ${DEPLOY_DIR_IMAGE}/${UBOOT_BINARY}.${MERGED_SUFFIX}
+    cd "$olddir"
+}
+
+do_prepare_bootloaders[depends] += " \
+    npcm7xx-bootblock:do_deploy \
+    npcm7xx-bingo-native:do_populate_sysroot \
+    "
+
+addtask do_prepare_bootloaders before do_generate_static after do_generate_rwfs_static
+
+# Include the full bootblock and u-boot in the final static image
+python do_generate_static_append() {
+    _append_image(os.path.join(d.getVar('DEPLOY_DIR_IMAGE', True),
+                               'u-boot.%s' % d.getVar('UBOOT_SUFFIX',True)),
+                  int(d.getVar('FLASH_UBOOT_OFFSET', True)),
+                  int(d.getVar('FLASH_KERNEL_OFFSET', True)))
+}
+
+do_make_ubi_append() {
+    # Concatenate the uboot and ubi partitions
+    dd bs=1k conv=notrunc seek=${FLASH_UBOOT_OFFSET} \
+        if=${DEPLOY_DIR_IMAGE}/u-boot.${UBOOT_SUFFIX} \
+        of=${IMGDEPLOYDIR}/${IMAGE_NAME}.ubi.mtd
+}
+
+do_make_ubi[depends] += "${PN}:do_prepare_bootloaders"
+do_generate_ubi_tar[depends] += "${PN}:do_prepare_bootloaders"
+do_generate_static_tar[depends] += "${PN}:do_prepare_bootloaders"