require conf/distro/poky.conf
require conf/distro/include/phosphor-defaults.inc

DISTRO = "openbmc-phosphor"
DISTRO_NAME = "Phosphor OpenBMC (Phosphor OpenBMC Project Reference Distro)"
DISTRO_VERSION = "0.1.0"
TARGET_VENDOR="-openbmc"

IMAGE_LINGUAS = "en-us"

VIRTUAL-RUNTIME_keymaps = ""

# Phosphor OpenBMC uses systemd and udev
DISTRO_FEATURES_append = " systemd pam"
VIRTUAL-RUNTIME_init_manager = "systemd"
DISTRO_FEATURES_BACKFILL_CONSIDERED = "sysvinit"
VIRTUAL-RUNTIME_initscripts = ""

DISTRO_FEATURES = "\
        ipv6 \
        obmc-phosphor-fan-mgmt \
        obmc-phosphor-chassis-mgmt \
        obmc-phosphor-flash-mgmt \
        obmc-phosphor-user-mgmt \
        obmc-settings-mgmt \
        obmc-phosphor-system-mgmt \
        obmc-host-ipmi \
        obmc-logging-mgmt \
        obmc-host-ctl \
        avahi \
        slp \
        obmc-net-ipmi \
        ${DISTRO_FEATURES_LIBC} \
        "

MACHINE_FEATURES += " \
        ${OBMC_MACHINE_FEATURES} \
        "

DISTRO_EXTRA_RDEPENDS_remove_qemuarm = "packagegroup-core-device-devel"

# TODO: openbmc/openbmc#12345 - Upgrade to pygobject-3.
PREFERRED_VERSION_python-pygobject = "2.%"

INHERIT_append = " obmc-phosphor-utils"

include conf/distro/include/openbmc-phosphor/${MACHINE}.inc

# TODO: openbmc/openbmc#1407 - Remove with RHEL6 support deprecation.
#  RHEL6.4's kernel is too old to use the uninative-shim due to missing
#  syscall support.  Disable uninative and set OLDEST_KERNEL back to
#  the version in RHEL6.4.
INHERIT_remove = " uninative"
OLDEST_KERNEL = "2.6.32"

KERNEL_FEATURES_append = " phosphor-gpio-keys"
KERNEL_FEATURES_remove_qemuall = " phosphor-gpio-keys"

IMAGE_CLASSES_append = " image_types_phosphor"

# OpenBMC uses a couple recipes from meta-virtualization
# but we do not actually want any virtualization support
# enabled on a BMC distribution.  Silence the emitted
# warning.
SKIP_META_VIRT_SANITY_CHECK = "1"