diff --git a/gui/lib/gui_resource.robot b/gui/lib/gui_resource.robot
new file mode 100644
index 0000000..bad145f
--- /dev/null
+++ b/gui/lib/gui_resource.robot
@@ -0,0 +1,107 @@
+*** Settings ***
+Documentation  This is a resource file containing user-defined keywords for new Vue based OpenBMC GUI.
+
+Library        XvfbRobot
+Library        SeleniumLibrary
+Library        SSHLibrary  30 Seconds
+Resource       ../../lib/state_manager.robot
+Variables      ../data/gui_variables.py
+
+
+*** Variables ***
+${obmc_gui_url}              https://${OPENBMC_HOST}
+
+# Default GUI broswer and mode is set to "Firefox" and "headless"
+# respectively here.
+${GUI_BROWSER}               ff
+${GUI_MODE}                  headless
+
+${CMD_INTERNAL_FAILURE}      busctl call xyz.openbmc_project.Logging /xyz/openbmc_project/logging
+...  xyz.openbmc_project.Logging.Create Create ssa{ss} xyz.openbmc_project.Common.Error.InternalFailure
+...  xyz.openbmc_project.Logging.Entry.Level.Error 0
+
+
+*** Keywords ***
+
+Open Browser With URL
+    [Documentation]  Open browser with specified URL and returns browser id.
+    [Arguments]  ${URL}  ${browser}=ff  ${mode}=${GUI_MODE}
+
+    # Description of argument(s):
+    # URL      Openbmc GUI URL to be open
+    #          (e.g. https://openbmc-test.mybluemix.net/#/login).
+    # browser  Browser used to open above URL
+    #          (e.g. gc for google chrome, ff for firefox).
+    # mode     Browser opening mode(e.g. headless, header).
+
+    ${browser_ID}=  Run Keyword If  '${mode}' == 'headless'
+    ...  Launch Headless Browser  ${URL}  ${browser}
+    ...  ELSE  Open Browser  ${URL}  ${browser}
+
+    [Return]  ${browser_ID}
+
+
+Launch Header Browser
+    [Documentation]  Open the browser with the URL and
+    ...              login on windows platform.
+    [Arguments]  ${browser_type}=${GUI_BROWSER}
+
+    # Description of argument(s):
+    # browser_type  Type of browser (e.g. "firefox", "chrome", etc.).
+
+    ${BROWSER_ID}=  Open Browser  ${obmc_gui_url}  ${browser_type}
+    Maximize Browser Window
+    Set Global Variable  ${BROWSER_ID}
+
+
+Launch Headless Browser
+    [Documentation]  Launch headless browser.
+    [Arguments]  ${URL}=${obmc_gui_url}  ${browser}=${GUI_BROWSER}
+
+    # Description of argument(s):
+    # URL      Openbmc GUI URL to be open
+    #          (e.g. https://openbmc-test.mybluemix.net/#/login).
+    # browser  Browser to open given URL in headless way
+    #          (e.g. gc for google chrome, ff for firefox).
+
+    Start Virtual Display
+    ${browser_ID}=  Open Browser  ${URL}
+    Set Window Size  1920  1080
+
+    [Return]  ${browser_ID}
+
+
+Launch Browser And Login GUI
+    [Documentation]  Launch browser and login to OpenBMC GUI.
+
+    Open Browser With URL  ${obmc_gui_url}
+    Login GUI  ${OPENBMC_USERNAME}  ${OPENBMC_PASSWORD}
+
+
+Login GUI
+    [Documentation]  Login to OpenBMC GUI.
+    [Arguments]  ${username}=${OPENBMC_USERNAME}  ${password}=${OPENBMC_PASSWORD}
+
+    # Description of argument(s):
+    # username  The username to be used for login.
+    # password  The password to be used for login.
+
+    Go To  ${obmc_gui_url}
+    Wait Until Element Is Enabled  ${xpath_textbox_username}
+    Input Text  ${xpath_textbox_username}  ${username}
+    Input Password  ${xpath_textbox_password}  ${password}
+    Click Element  ${xpath_login_button}
+    Wait Until Page Contains  Overview  timeout=30s
+
+
+Logout GUI
+    [Documentation]  Logout of OpenBMC GUI.
+
+    Click Element  ${xpath_logout_button}
+    Wait Until Page Contains Element  ${xpath_login_button}
+
+
+Generate Test Error Log
+    [Documentation]  Generate test error log.
+
+    BMC Execute Command  ${CMD_INTERNAL_FAILURE}