| SUMMARY = "User space daemon for extended IEEE 802.11 management" |
| HOMEPAGE = "http://w1.fi/hostapd/" |
| SECTION = "kernel/userland" |
| LICENSE = "BSD-3-Clause" |
| LIC_FILES_CHKSUM = "file://hostapd/README;md5=1ec986bec88070e2a59c68c95d763f89" |
| |
| DEPENDS = "libnl openssl" |
| |
| SRC_URI = " \ |
| http://w1.fi/releases/hostapd-${PV}.tar.gz \ |
| file://defconfig \ |
| file://init \ |
| file://hostapd.service \ |
| file://0001-Prepare-for-CVE-2021-30004.patch.patch \ |
| file://CVE-2019-16275.patch \ |
| file://CVE-2019-5061.patch \ |
| file://CVE-2021-0326.patch \ |
| file://CVE-2021-27803.patch \ |
| file://CVE-2021-30004.patch \ |
| " |
| |
| SRC_URI[md5sum] = "f188fc53a495fe7af3b6d77d3c31dee8" |
| SRC_URI[sha256sum] = "881d7d6a90b2428479288d64233151448f8990ab4958e0ecaca7eeb3c9db2bd7" |
| |
| S = "${WORKDIR}/hostapd-${PV}" |
| B = "${WORKDIR}/hostapd-${PV}/hostapd" |
| |
| inherit update-rc.d systemd pkgconfig features_check |
| |
| CONFLICT_DISTRO_FEATURES = "openssl-no-weak-ciphers" |
| |
| INITSCRIPT_NAME = "hostapd" |
| |
| SYSTEMD_SERVICE:${PN} = "hostapd.service" |
| SYSTEMD_AUTO_ENABLE:${PN} = "disable" |
| |
| do_configure:append() { |
| install -m 0644 ${WORKDIR}/defconfig ${B}/.config |
| } |
| |
| do_compile() { |
| export CFLAGS="-MMD -O2 -Wall -g" |
| export EXTRA_CFLAGS="${CFLAGS}" |
| make V=1 |
| } |
| |
| do_install() { |
| install -d ${D}${sbindir} ${D}${sysconfdir}/init.d ${D}${systemd_unitdir}/system/ |
| install -m 0644 ${B}/hostapd.conf ${D}${sysconfdir} |
| install -m 0755 ${B}/hostapd ${D}${sbindir} |
| install -m 0755 ${B}/hostapd_cli ${D}${sbindir} |
| install -m 755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/hostapd |
| install -m 0644 ${WORKDIR}/hostapd.service ${D}${systemd_unitdir}/system/ |
| sed -i -e 's,@SBINDIR@,${sbindir},g' -e 's,@SYSCONFDIR@,${sysconfdir},g' ${D}${systemd_unitdir}/system/hostapd.service |
| } |
| |
| CONFFILES:${PN} += "${sysconfdir}/hostapd.conf" |