meta-openembedded: subtree update:e0daf6f8e0..3a9262866d
Adrian Bunk (1):
xfce-polkit: Upgrade 0.2 -> 0.3
Alex Kiernan (2):
ostree: Add support for ptest
ostree: Upgrade 2019.4 -> 2019.5
Alistair Francis (1):
openocd: Update to latest git version
Anders Roxell (1):
s-suite: install missing create_config.sh
Andreas Müller (6):
mm-common: upgrade 0.9.12 -> 1.0.0 / meson build / add SUMMARY
mm-common: do really build with meson
libpeas: upgrade 1.22.0 -> 1.24.1
xfce4-screenshooter: upgrade 1.9.6 -> 1.9.7
xfce4-time-out-plugin: upgrade 1.0.3 -> 1.1.0
xfce4-whiskermenu-plugin: upgrade 2.3.3 -> 2.3.4
Andreas Oberritter (4):
haveged: Fix missing initscript when both systemd and sysvinit are enabled
samba: fix installation for minimal build
autofs: set some paths for configure script
autofs: install sysvinit script manually if systemd is enabled
André Draszik (8):
jansson: allow to build a -native package
cunit: allow to build a -native package
libev: allow to build a -native package
nghttp2: fix UPSTREAM_CHECK_URI
nghttp2: update to 1.39.2
nghttp2: build more of this & fix packaging
nghttp2: allow to build a -native package
nodejs: allow use of system nghttp2
Hongxu Jia (10):
python-pluggy: add python-importlib-metadata to RDEPENDS
python-more-itertools.inc: fix python2 package not incorrectly generated
python-more-itertools: downgrade 7.2.0 -> 5.0.0
python-importlib-metadata: add missing runtime depends
python-pathlib2: add python-scandir and python-misc to runtime depends
python-scandir: add version 1.10.0
python-contextlib2/python3-contextlib2: add version 0.6.0
python3-importlib-metadata: add python3-misc to runtime depends
python-importlib-metadata: add python-compression to runtime depends
python-configparser: add python-pkgutil to runtime depends
Kai Kang (4):
xfce4-genmon-plugin: 4.0.1 -> 4.0.2
xfce-panel-plugin.bbclass: correct SRC_URI with xfce_verdir
xfce4-weather-plugin: 0.9.1 -> 0.10.0
xfce4-screensaver: 0.1.5 -> 0.1.8
Khem Raj (8):
iwd: Fix installed-vs-shipped QA errors on systemd units
iwd: Fix build race during documentation build
ifplugd: Include stdint.h for uintXX_t
netkit-rwho: Include stdint.h for int32_t
libowfat: Fix parallel build
grpc: Add dep on libnsl
gtkwave: Upgrade to 3.3.102
syslog-ng: Do not install non-existing systemd file
Ming Liu (2):
python-jsonschema: RDEPENDS on python-importlib-metadata
ostree: fix some invalid condition checking
Oleksandr Kravchuk (1):
iwd: update to 1.0
Stefan Agner (2):
zstd: Upgrade 1.4.3 -> 1.4.4
zstd: move recipe to oe-core
Yi Zhao (2):
libldb: upgrade 1.5.5 -> 1.5.6
samba: upgrade 4.10.8 -> 4.10.10
Zang Ruochen (20):
python-pyjks: upgrade 17.1.1 -> 19.0.0
python-pyjwt: upgrade 1.6.4 -> 1.7.1
python-pymisp: upgrade 2.4.93 -> 2.4.117.2
xorriso: upgrade 1.5.0 -> 1.5.3
python-cython: upgrade 0.29.13 -> 0.29.14
python-decorator: upgrade 4.4.0 -> 4.4.1
python-dominate: upgrade 2.3.1 -> 2.4.0
python-flask-babel: upgrade 0.11.2 -> 0.12.2
python-flask-migrate: upgrade 2.2.1 -> 2.5.2
python-flask-restful: upgrade 0.3.6 -> 0.3.7
python-flask-socketio: upgrade 3.3.2 -> 4.2.1
python-flask-sqlalchemy: upgrade 2.3.2 -> 2.4.1
python-paho-mqtt: upgrade 1.4.0 -> 1.5.0
python-pyroute2: upgrade 0.5.2 -> 0.5.7
python-pyrsistent: upgrade 0.15.4 -> 0.15.5
python-pysmi: upgrade 0.2.2 -> 0.3.4
python-pytest: upgrade 5.2.1 -> 5.2.2
python-serpent: upgrade 1.25 -> 1.28
python-smbus: upgrade 4.0 -> 4.1
python-snimpy: upgrade 0.8.12 -> 0.8.13
Zheng Ruoqin (19):
mdns: upgrade 878.200.35 -> 878.260.1
ledmon: Modify the Upstream-Status to Submitted.
byacc: upgrade 20190617 -> 20191103
ccid: upgrade 1.4.30 -> 1.4.31
dialog: upgrade 1.3-20190728 -> 1.3-20190808
cryptsetup: upgrade 2.2.1 -> 2.2.2
lvm2/libdevmapper: 2.03.05 -> 2.03.06
libssh2: upgrade 1.8.2 -> 1.9.0
mariadb: upgrade 10.3.16 -> 10.3.18
mcelog: upgrade 164 -> 165
mce-test: Update to latest git version
postgresql: upgrade 11.5 -> 12.0
protobuf: upgrade 3.10.0 -> 3.10.1
sshfs-fuse: upgrade 3.5.2 -> 3.6.0
syslog-ng: upgrade 3.19.1 -> 3.24.1
tslib: upgrade 1.16 -> 1.21
xkbprint: upgrade 1.0.4 -> 1.0.5
xterm: upgrade 349 -> 350
zabbix: upgrade 4.2.7 -> 4.2.8
Zhixiong Chi (1):
gtkwave: add the libtirpc dependence and config
Change-Id: I7dd3609b2d3166e5ba2f977e26026f2b675dc108
Signed-off-by: Brad Bishop <bradleyb@fuzziesquirrel.com>
diff --git a/meta-openembedded/meta-oe/recipes-extended/ostree/ostree_2019.5.bb b/meta-openembedded/meta-oe/recipes-extended/ostree/ostree_2019.5.bb
new file mode 100644
index 0000000..b3b34a1
--- /dev/null
+++ b/meta-openembedded/meta-oe/recipes-extended/ostree/ostree_2019.5.bb
@@ -0,0 +1,192 @@
+SUMMARY = "Versioned Operating System Repository."
+DESCRIPTION = "libostree is both a shared library and suite of command line \
+tools that combines a \"git-like\" model for committing and downloading \
+bootable filesystem trees, along with a layer for deploying them and managing \
+the bootloader configuration."
+HOMEPAGE = "https://ostree.readthedocs.io"
+LICENSE = "LGPLv2.1"
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=5f30f0716dfdd0d91eb439ebec522ec2"
+
+DEPENDS = " \
+ glib-2.0 \
+ gpgme \
+ e2fsprogs \
+ libcap \
+ zlib \
+ xz \
+ bison-native \
+"
+
+# The Yocto mirror has an old export of ostree:
+# http://downloads.yoctoproject.org/mirror/sources/git2_github.com.ostreedev.ostree.tar.gz
+PREMIRRORS = ""
+
+SRC_URI = " \
+ gitsm://github.com/ostreedev/ostree \
+ file://0001-macros-Add-TEMP_FAILURE_RETRY-for-musl.patch \
+ file://run-ptest \
+ file://0001-tests-core-Fallback-to-en_US.UTF-8-locale.patch \
+ file://0001-tests-Handle-EPIPE-failures-when-head-terminates.patch \
+ file://0002-tests-core-Assume-C.UTF-8-if-locale-isn-t-found.patch \
+ file://0003-tests-Avoid-musl-failure-with-cp-a.patch \
+ file://0001-build-create-tests-directory-for-split-builds.patch \
+"
+SRCREV = "980ca07b03b3aa7e0012729dd6c84b0878775d93"
+
+UPSTREAM_CHECK_GITTAGREGEX = "v(?P<pver>\d+\.\d+)"
+
+S = "${WORKDIR}/git"
+
+inherit autotools bash-completion gobject-introspection gtk-doc pkgconfig ptest-gnome systemd
+
+# Package configuration - match ostree defaults, but without rofiles-fuse
+# otherwise we introduce a dependendency on meta-filesystems
+PACKAGECONFIG ??= " \
+ ${@bb.utils.filter('DISTRO_FEATURES', 'selinux smack', d)} \
+ ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'systemd libmount', '', d)} \
+ soup \
+"
+
+# We include soup because ostree can't (currently) be built without
+# soup or curl - https://github.com/ostreedev/ostree/issues/1897
+PACKAGECONFIG_class-native ??= " \
+ ${@bb.utils.filter('DISTRO_FEATURES', 'selinux smack', d)} \
+ soup \
+"
+
+PACKAGECONFIG[avahi] = "--with-avahi, --without-avahi, avahi"
+PACKAGECONFIG[curl] = "--with-curl, --without-curl, curl"
+PACKAGECONFIG[dracut] = "--with-dracut, --without-dracut"
+PACKAGECONFIG[gnutls] = "--with-crypto=gnutls, , gnutls"
+PACKAGECONFIG[libarchive] = "--with-libarchive, --without-libarchive, libarchive"
+PACKAGECONFIG[libmount] = "--with-libmount, --without-libmount, util-linux"
+PACKAGECONFIG[man] = "--enable-man, --disable-man, libxslt-native docbook-xsl-stylesheets-native"
+PACKAGECONFIG[mkinitcpio] = "--with-mkinitcpio, --without-mkinitcpio"
+PACKAGECONFIG[no-http2] = "--disable-http2, --enable-http2"
+PACKAGECONFIG[openssl] = "--with-crypto=openssl, , openssl"
+PACKAGECONFIG[rofiles-fuse] = "--enable-rofiles-fuse, --disable-rofiles-fuse, fuse"
+PACKAGECONFIG[selinux] = "--with-selinux, --without-selinux, libselinux"
+PACKAGECONFIG[smack] = "--with-smack, --without-smack, smack"
+PACKAGECONFIG[soup] = "--with-soup, --without-soup --disable-glibtest, libsoup-2.4"
+PACKAGECONFIG[static] = ""
+PACKAGECONFIG[systemd] = "--with-libsystemd --with-systemdsystemunitdir=${systemd_unitdir}/system, --without-libsystemd, systemd"
+PACKAGECONFIG[trivial-httpd-cmdline] = "--enable-trivial-httpd-cmdline, --disable-trivial-httpd-cmdline"
+
+EXTRA_OECONF = " \
+ ${@bb.utils.contains('PACKAGECONFIG', 'static', '--with-static-compiler=\'${CC} ${CFLAGS} ${CPPFLAGS} ${LDFLAGS}\'', '', d)} \
+"
+
+# Makefile-libostree.am overrides this to avoid a build problem with clang,
+# but that fix breaks cross compilation and we don't need it
+EXTRA_OEMAKE = " \
+ INTROSPECTION_SCANNER_ENV= \
+"
+
+EXTRA_OECONF_class-native = " \
+ --with-builtin-grub2-mkconfig \
+ --enable-wrpseudo-compat \
+ --disable-otmpfile \
+"
+
+# Path to ${prefix}/lib/ostree/ostree-grub-generator is hardcoded on the
+# do_configure stage so we do depend on it
+SYSROOT_DIR = "${STAGING_DIR_TARGET}"
+SYSROOT_DIR_class-native = "${STAGING_DIR_NATIVE}"
+do_configure[vardeps] += "SYSROOT_DIR"
+
+do_configure_prepend() {
+ # this reflects what autogen.sh does, but the OE wrappers for autoreconf
+ # allow it to work without the other gyrations which exist there
+ cp ${S}/libglnx/Makefile-libglnx.am ${S}/libglnx/Makefile-libglnx.am.inc
+ cp ${S}/bsdiff/Makefile-bsdiff.am ${S}/bsdiff/Makefile-bsdiff.am.inc
+}
+
+do_install_append_class-native() {
+ create_wrapper ${D}${bindir}/ostree OSTREE_GRUB2_EXEC="${STAGING_LIBDIR_NATIVE}/ostree/ostree-grub-generator"
+}
+
+PACKAGES += " \
+ ${PN}-dracut \
+ ${PN}-grub \
+ ${PN}-mkinitcpio \
+ ${PN}-switchroot \
+ ${PN}-trivial-httpd \
+"
+
+FILES_${PN} = " \
+ ${bindir}/ostree \
+ ${bindir}/rofiles-fuse \
+ ${datadir}/${BPN} \
+ ${datadir}/gir-1.0 \
+ ${libdir}/${BPN}/ostree-remount \
+ ${libdir}/girepository-1.0 \
+ ${libdir}/lib*${SOLIBS} \
+ ${libdir}/tmpfiles.d/ostree-tmpfiles.conf \
+ ${sysconfdir}/ostree/remotes.d \
+ ${systemd_unitdir}/system-generators/ostree-system-generator \
+ ${systemd_unitdir}/system/ostree-finalize-staged.path \
+ ${systemd_unitdir}/system/ostree-finalize-staged.service \
+ ${systemd_unitdir}/system/ostree-remount.service \
+"
+FILES_${PN}-dracut = " \
+ ${sysconfdir}/dracut.conf.d \
+ ${libdir}/dracut \
+"
+FILES_${PN}-grub = " \
+ ${sysconfdir}/grub.d \
+ ${libexecdir}/libostree/grub2-15_ostree \
+"
+FILES_${PN}-mkinitcpio = " \
+ ${sysconfdir}/ostree-mkinitcpio.conf \
+ ${libdir}/initcpio \
+"
+FILES_${PN}-switchroot = " \
+ ${libdir}/ostree/ostree-prepare-root \
+ ${systemd_unitdir}/system/ostree-prepare-root.service \
+"
+FILES_${PN}-trivial-httpd = " \
+ ${libexecdir}/libostree/ostree-trivial-httpd \
+"
+
+RDEPENDS_${PN} = " \
+ ${@bb.utils.contains('PACKAGECONFIG', 'trivial-httpd-cmdline', '${PN}-trivial-httpd', '', d)} \
+"
+RDEPENDS_${PN}-dracut = "bash"
+RDEPENDS_${PN}-mkinitcpio = "bash"
+RDEPENDS_${PN}_class-target = " \
+ gnupg \
+ ${PN}-switchroot \
+"
+RDEPENDS_${PN}-ptest += " \
+ attr \
+ bash \
+ coreutils \
+ cpio \
+ diffutils \
+ findutils \
+ grep \
+ python3-core \
+ python3-multiprocessing \
+ python3-pyyaml \
+ ${PN}-trivial-httpd \
+"
+RDEPENDS_${PN}-ptest_append_libc-glibc = " glibc-utils glibc-localedata-en-us"
+
+RRECOMMENDS_${PN} += "kernel-module-overlay"
+RRECOMMENDS_${PN}-ptest += "strace"
+
+SYSTEMD_SERVICE_${PN} = "ostree-remount.service ostree-finalize-staged.path"
+SYSTEMD_SERVICE_${PN}-switchroot = "ostree-prepare-root.service"
+
+BBCLASSEXTEND = "native"
+
+python __anonymous() {
+ if not bb.data.inherits_class('native', d) and bb.utils.contains('PTEST_ENABLED', '1', 'True', 'False', d):
+ if not bb.utils.contains_any('BBFILE_COLLECTIONS', 'meta-python', 'True', 'False', d):
+ raise bb.parse.SkipRecipe('ptest requires meta-python to be present.')
+ elif not bb.utils.contains_any('PACKAGECONFIG', 'soup curl', 'True', 'False', d):
+ raise bb.parse.SkipRecipe('ptest requires soup enabled in PACKAGECONFIG.')
+ elif not oe.utils.any_distro_features(d, "xattr"):
+ raise bb.parse.SkipRecipe('ptest requires xattr enabled in DISTRO_FEATURES.')
+}