| SUMMARY = "Simple DirectMedia Layer" |
| DESCRIPTION = "Simple DirectMedia Layer is a cross-platform multimedia \ |
| library designed to provide low level access to audio, keyboard, mouse, \ |
| joystick, 3D hardware via OpenGL, and 2D video framebuffer." |
| HOMEPAGE = "http://www.libsdl.org" |
| BUGTRACKER = "http://bugzilla.libsdl.org/" |
| |
| SECTION = "libs" |
| |
| LICENSE = "Zlib" |
| LIC_FILES_CHKSUM = "file://COPYING.txt;md5=b2304ad7e91711027590d3f102a754b7" |
| |
| PROVIDES = "virtual/libsdl2" |
| |
| DEPENDS_class-nativesdk = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'virtual/nativesdk-libx11 nativesdk-libxrandr nativesdk-libxrender nativesdk-libxext', '', d)}" |
| |
| SRC_URI = " \ |
| http://www.libsdl.org/release/SDL2-${PV}.tar.gz \ |
| file://linkage.patch \ |
| file://0001-prepend-our-sysroot-path-so-that-make-finds-our-wayl.patch \ |
| file://0002-Avoid-finding-build-host-s-wayland-scanner.patch \ |
| file://fix-build-failure-on-ppc.patch \ |
| " |
| |
| S = "${WORKDIR}/SDL2-${PV}" |
| |
| SRC_URI[md5sum] = "d4055424d556b4a908aa76fad63abd3c" |
| SRC_URI[sha256sum] = "442038cf55965969f2ff06d976031813de643af9c9edc9e331bd761c242e8785" |
| |
| inherit autotools lib_package binconfig pkgconfig |
| |
| EXTRA_OECONF = "--disable-oss --disable-esd --disable-arts \ |
| --disable-diskaudio --disable-nas --disable-esd-shared --disable-esdtest \ |
| --disable-video-dummy \ |
| --enable-pthreads \ |
| --enable-sdl-dlopen \ |
| --disable-rpath \ |
| WAYLAND_PROTOCOLS_SYSROOT_DIR=${RECIPE_SYSROOT}" |
| |
| # opengl packageconfig factored out to make it easy for distros |
| # and BSP layers to pick either (desktop) opengl, gles2, or no GL |
| PACKAGECONFIG_GL ?= "${@bb.utils.filter('DISTRO_FEATURES', 'opengl', d)}" |
| |
| PACKAGECONFIG ??= " \ |
| ${PACKAGECONFIG_GL} \ |
| ${@bb.utils.filter('DISTRO_FEATURES', 'alsa directfb pulseaudio x11', d)} \ |
| ${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'wayland gles2', '', d)} \ |
| " |
| PACKAGECONFIG[alsa] = "--enable-alsa --disable-alsatest,--disable-alsa,alsa-lib," |
| PACKAGECONFIG[directfb] = "--enable-video-directfb,--disable-video-directfb,directfb" |
| PACKAGECONFIG[gles2] = "--enable-video-opengles,--disable-video-opengles,virtual/libgles2" |
| PACKAGECONFIG[opengl] = "--enable-video-opengl,--disable-video-opengl,virtual/libgl" |
| PACKAGECONFIG[pulseaudio] = "--enable-pulseaudio,--disable-pulseaudio,pulseaudio" |
| PACKAGECONFIG[tslib] = "--enable-input-tslib,--disable-input-tslib,tslib" |
| PACKAGECONFIG[wayland] = "--enable-video-wayland,--disable-video-wayland,wayland-native wayland wayland-protocols libxkbcommon" |
| PACKAGECONFIG[x11] = "--enable-video-x11,--disable-video-x11,virtual/libx11 libxext libxrandr libxrender" |
| |
| EXTRA_AUTORECONF += "--include=acinclude --exclude=autoheader" |
| |
| do_configure_prepend() { |
| # Remove old libtool macros. |
| MACROS="libtool.m4 lt~obsolete.m4 ltoptions.m4 ltsugar.m4 ltversion.m4" |
| for i in ${MACROS}; do |
| rm -f ${S}/acinclude/$i |
| done |
| export SYSROOT=$PKG_CONFIG_SYSROOT_DIR |
| } |
| |
| FILES_${PN}-dev += "${libdir}/cmake" |