| SUMMARY = "Extra machine specific configuration files" |
| HOMEPAGE = "https://wiki.gentoo.org/wiki/Eudev" |
| DESCRIPTION = "Extra machine specific configuration files for udev, specifically blacklist information." |
| LICENSE = "MIT" |
| LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420" |
| |
| SRC_URI = " \ |
| file://automount.rules \ |
| file://mount.sh \ |
| file://mount.blacklist \ |
| file://autonet.rules \ |
| file://network.sh \ |
| file://localextra.rules \ |
| " |
| |
| S = "${WORKDIR}" |
| |
| |
| do_install() { |
| install -d ${D}${sysconfdir}/udev/rules.d |
| |
| install -m 0644 ${WORKDIR}/automount.rules ${D}${sysconfdir}/udev/rules.d/automount.rules |
| install -m 0644 ${WORKDIR}/autonet.rules ${D}${sysconfdir}/udev/rules.d/autonet.rules |
| install -m 0644 ${WORKDIR}/localextra.rules ${D}${sysconfdir}/udev/rules.d/localextra.rules |
| |
| install -d ${D}${sysconfdir}/udev/mount.blacklist.d |
| install -m 0644 ${WORKDIR}/mount.blacklist ${D}${sysconfdir}/udev/ |
| |
| install -d ${D}${sysconfdir}/udev/scripts/ |
| |
| install -m 0755 ${WORKDIR}/mount.sh ${D}${sysconfdir}/udev/scripts/mount.sh |
| sed -i 's|@systemd_unitdir@|${systemd_unitdir}|g' ${D}${sysconfdir}/udev/scripts/mount.sh |
| sed -i 's|@base_sbindir@|${base_sbindir}|g' ${D}${sysconfdir}/udev/scripts/mount.sh |
| |
| install -m 0755 ${WORKDIR}/network.sh ${D}${sysconfdir}/udev/scripts |
| } |
| |
| FILES:${PN} = "${sysconfdir}/udev" |
| RDEPENDS:${PN} = "udev" |
| CONFFILES:${PN} = "${sysconfdir}/udev/mount.blacklist" |
| |
| # to replace udev-extra-rules from meta-oe |
| RPROVIDES:${PN} = "udev-extra-rules" |
| RREPLACES:${PN} = "udev-extra-rules" |
| RCONFLICTS:${PN} = "udev-extra-rules" |