require conf/distro/openbmc-phosphor.conf
require conf/distro/include/phosphor-isolation.inc

GBMC_VERSION ?= "0.5.0.0"
DISTRO = "gbmc"
DISTRO_NAME = "gBMC (OpenBMC + Google customizations)"
DISTRO_VERSION = "gbmc-release-${GBMC_VERSION}"
DISTROOVERRIDES .= ":gbmc"

# Possible values: "dev", "prod"
GBMC_CONFIG ?= "dev"
OVERRIDES .= ":${GBMC_CONFIG}:"

DISTRO_FEATURES:remove = "ldap"
DISTRO_FEATURES:remove = "slp"

# Required to get entity-manager to build with FruDevice service
DISTRO_FEATURES:append = " ipmi-fru"

# Disable u-boot shell for prod builds
DISTRO_FEATURES:append:prod = " disable-u-boot-shell"

WATCHDOG_PKG ?= "watchdog"

SANITY_TESTED_DISTROS:append = " Debian-rodete \n debian-rodete \n "

PREFERRED_PROVIDER_virtual/bmc-update ?= "inplace-gbmc-update"

# Provides reasonable data integrity and faster than sha*
FIT_HASH_ALG = "crc32"

OBMC_ORG_YAML_SUBDIRS += " com/google"

# Force the patches to not have any fuzz for gBMC
ERROR_QA:append = " patch-fuzz"

IGPS_MACHINE:npcm8xx = "Google"
REQUIRED_VERSION_npcm8xx-tip-fw = "0.4.5.0.3.4-GOOGLE2"