| SUMMARY = "PNG image format decoding library" |
| DESCRIPTION = "An open source project to develop and maintain the reference \ |
| library for use in applications that read, create, and manipulate PNG \ |
| (Portable Network Graphics) raster image files. " |
| HOMEPAGE = "http://www.libpng.org/" |
| SECTION = "libs" |
| LICENSE = "Libpng" |
| LIC_FILES_CHKSUM = "file://LICENSE;md5=5c900cc124ba35a274073b5de7639b13" |
| DEPENDS = "zlib" |
| |
| LIBV = "16" |
| |
| SRC_URI = "${SOURCEFORGE_MIRROR}/${BPN}/${BPN}${LIBV}/${BP}.tar.xz" |
| SRC_URI[sha256sum] = "1f4696ce70b4ee5f85f1e1623dc1229b210029fa4b7aee573df3e2ba7b036937" |
| |
| MIRRORS += "${SOURCEFORGE_MIRROR}/${BPN}/${BPN}${LIBV}/ ${SOURCEFORGE_MIRROR}/${BPN}/${BPN}${LIBV}/older-releases/" |
| |
| UPSTREAM_CHECK_URI = "http://libpng.org/pub/png/libpng.html" |
| |
| BINCONFIG = "${bindir}/libpng-config ${bindir}/libpng16-config" |
| |
| inherit autotools binconfig-disabled pkgconfig |
| |
| # Work around missing symbols |
| ARMNEON = "${@bb.utils.contains("TUNE_FEATURES", "neon", "--enable-arm-neon=on", "--enable-arm-neon=off", d)}" |
| ARMNEON:aarch64 = "--enable-hardware-optimizations=on" |
| EXTRA_OECONF += "${ARMNEON}" |
| |
| PACKAGES =+ "${PN}-tools" |
| |
| FILES:${PN}-tools = "${bindir}/png-fix-itxt ${bindir}/pngfix ${bindir}/pngcp" |
| |
| BBCLASSEXTEND = "native nativesdk" |
| |
| # CVE-2019-17371 is actually a memory leak in gif2png 2.x |
| CVE_CHECK_IGNORE += "CVE-2019-17371" |