| SUMMARY = "Web-based MySQL administration interface" |
| HOMEPAGE = "http://www.phpmyadmin.net" |
| # Main code is GPLv2, vendor/tecnickcom/tcpdf is under LGPLv3, js/jquery is under MIT |
| LICENSE = "GPLv2 & LGPLv3 & MIT" |
| LIC_FILES_CHKSUM = "file://LICENSE;md5=b234ee4d69f5fce4486a80fdaf4a4263 \ |
| file://vendor/tecnickcom/tcpdf/LICENSE.TXT;md5=dd6470bbcd3436ca317f82d34abaf688 \ |
| file://js/vendor/jquery/MIT-LICENSE.txt;md5=75308107741f7dcdc39127209c7e3fc8 \ |
| " |
| |
| SRC_URI = "https://files.phpmyadmin.net/phpMyAdmin/${PV}/phpMyAdmin-${PV}-all-languages.tar.xz \ |
| file://apache.conf \ |
| " |
| |
| SRC_URI[md5sum] = "e73377b11b7d38fa3f3014f2799c5252" |
| SRC_URI[sha256sum] = "1964d7190223c11e89fa1b7970c618e3a3bae2e859f5f60383f64c3848ef6921" |
| |
| UPSTREAM_CHECK_URI = "https://www.phpmyadmin.net/downloads/" |
| UPSTREAM_CHECK_REGEX = "phpMyAdmin-(?P<pver>\d+(\.\d+)+)-all-languages.tar.xz" |
| |
| S = "${WORKDIR}/phpMyAdmin-${PV}-all-languages" |
| |
| inherit allarch |
| |
| do_install() { |
| install -d ${D}${datadir}/${BPN} |
| cp -R --no-dereference --preserve=mode,links -v * ${D}${datadir}/${BPN} |
| chown -R root:root ${D}${datadir}/${BPN} |
| # Don't install patches to target |
| rm -rf ${D}${datadir}/${BPN}/patches |
| |
| install -d ${D}${sysconfdir}/apache2/conf.d |
| install -m 0644 ${WORKDIR}/apache.conf ${D}${sysconfdir}/apache2/conf.d/phpmyadmin.conf |
| |
| # Remove a few scripts that explicitly require bash (!) |
| rm -f ${D}${datadir}/phpmyadmin/libraries/transformations/*.sh |
| } |
| |
| FILES:${PN} = "${datadir}/${BPN} \ |
| ${sysconfdir}/apache2/conf.d" |
| |
| RDEPENDS:${PN} += "bash php-cli" |