meta-google: Add glome-login and glome-config
We have to use glome-config since the sample config is removed in
glome recipe. As a result, now glome depends on glome-config.
The platform also needs to overwrite these variables in their
bbappend files:
- glome-login.bb
* GLOME_FALLBACK_SERV
* GLOME_FALLBACK_OBJ
* GLOME_HOSTNAME_SUFFIX
* GLOME_BOARDSN_KEY
- glome-config.bb
* GLOME_PUBLIC_KEY
* GLOME_KEY_VERSION
* GLOME_URL_PREFIX
Tested:
1) `bitbake obmc-phosphor-image` build passes
2) inplace update the image on a real machine
3) connect to it
The glome is enabled and login is successful
Signed-off-by: Leo Tu <leotu@google.com>
Change-Id: I21a48cbdcfea67772f143b4fc115f717e6d7cbc5
diff --git a/meta-google/recipes-google/console/glome-login.bb b/meta-google/recipes-google/console/glome-login.bb
new file mode 100644
index 0000000..ea043d3
--- /dev/null
+++ b/meta-google/recipes-google/console/glome-login.bb
@@ -0,0 +1,59 @@
+SUMMARY = "Glome Login Scripts"
+DESCRIPTION = "Glome Login Scripts"
+PR = "r1"
+
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/Apache-2.0;md5=89aea4e17d99a7cacdbeed46a0096b10"
+
+GLOME_FALLBACK_SERV ?= ""
+GLOME_FALLBACK_OBJ ?= ""
+GLOME_HOSTNAME_SUFFIX ?= ""
+GLOME_BOARDSN_KEY ?= "bmc-boardsn"
+
+RDEPENDS:${PN} += "bash"
+RDEPENDS:${PN} += "glome"
+RDEPENDS:${PN} += "jq"
+RDEPENDS:${PN} += "obmc-console"
+
+SRC_URI += "file://glome-login.sh.in"
+
+do_install:append() {
+ if [ -z '${GLOME_FALLBACK_SERV}' ]; then
+ echo 'Missing GLOME_FALLBACK_SERV' >&2
+ exit 1
+ fi
+
+ if [ -z '${GLOME_FALLBACK_OBJ}' ]; then
+ echo 'Missing GLOME_FALLBACK_OBJ' >&2
+ exit 1
+ fi
+
+ if [ -z '${GLOME_HOSTNAME_SUFFIX}' ]; then
+ echo 'Missing GLOME_HOSTNAME_SUFFIX' >&2
+ exit 1
+ fi
+
+ sed ${WORKDIR}/glome-login.sh.in \
+ -e 's#@INV_SERV@#${GLOME_FALLBACK_SERV}#' \
+ -e 's#@INV_OBJ@#${GLOME_FALLBACK_OBJ}#' \
+ -e 's#@HOSTNAME_SUFFIX@#${GLOME_HOSTNAME_SUFFIX}#' \
+ -e 's#@BOARDSN_KEY@#${GLOME_BOARDSN_KEY}#' \
+ > ${WORKDIR}/glome-login.sh
+
+ install -d ${D}${bindir}
+ install -m 0755 ${WORKDIR}/glome-login.sh ${D}${bindir}
+}
+
+# This is an example to override the glome login service in the bbappend for 'prod'
+#
+#FILES:${PN}:append:prod = " \
+# ${systemd_system_unitdir}/serial-to-bmc@.service.d/bmc-login-glome-override.conf \
+# ${systemd_system_unitdir}/serial-getty@.service.d/bmc-login-glome-override.conf \
+# "
+#
+#do_install:append:prod() {
+# install -D -m 0644 ${WORKDIR}/bmc-login-glome-override.conf \
+# ${D}${systemd_system_unitdir}/serial-to-bmc@.service.d/bmc-login-glome-override.conf
+# install -D -m 0644 ${WORKDIR}/bmc-login-glome-override.conf \
+# ${D}${systemd_system_unitdir}/serial-getty@.service.d/bmc-login-glome-override.conf
+#}