meta-openembedded: subtree update:1ecd8b4364..f3018013ff
Adrian Bunk (1):
Add irda-utils
Khem Raj (1):
openocd: Upgrade to latest git version
Martin Jansa (8):
gtkwave: add distro_features_check
ndctl: make MACHINE_ARCH and ignore from libblockdev
oprofile: make MACHINE_ARCH
umip: make MACHINE_ARCH
mscgen: fix SRC_URI for multilib
python-cassandra-driver.inc: fix DEPENDS
triggerhappy: fix issues
opencv: use the same package name in PACKAGES and RDEPENDS
Oleksandr Kravchuk (4):
znc: update to 1.7.3
pure-ftpd: update to 1.0.47
xl2tpd: update to 1.3.14
ell: remove recipe
Scott Ellis (1):
wireguard: Upgrade 20190123 -> 20190406
Tom Rini (1):
toybox: Re-order inherit location so we can override do_configure
Zang Ruochen (8):
python-pyparsing: upgrade 2.2.0 -> 2.4.0
python-six: upgrade 1.11.0 -> 1.12.0
python-typing: upgrade 3.6.4 -> 3.6.6
python-urllib3: upgrade 1.23 -> 1.25.2
python-wrapt: upgrade 1.10.11 -> 1.11.1
python-mako:upgrade 1.0.9 -> 1.0.10
python-pip: upgrade 19.1 -> 19.1.1
python-pysocks: upgrade 1.6.8 -> 1.7.0
Change-Id: I9a4d8fb60195b1cfd0f39cebf8b113b3bb63808d
Signed-off-by: Brad Bishop <bradleyb@fuzziesquirrel.com>
diff --git a/meta-openembedded/meta-oe/recipes-bsp/irda-utils/irda-utils_0.9.18.bb b/meta-openembedded/meta-oe/recipes-bsp/irda-utils/irda-utils_0.9.18.bb
new file mode 100644
index 0000000..caffcb6
--- /dev/null
+++ b/meta-openembedded/meta-oe/recipes-bsp/irda-utils/irda-utils_0.9.18.bb
@@ -0,0 +1,64 @@
+SUMMARY = "Common files for IrDA"
+DESCRIPTION = "Provides common files needed to use IrDA. \
+IrDA allows communication over Infrared with other devices \
+such as phones and laptops."
+HOMEPAGE = "http://irda.sourceforge.net/"
+BUGTRACKER = "http://sourceforge.net/p/irda/bugs/"
+SECTION = "base"
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://irdadump/COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
+ file://smcinit/COPYING;md5=0636e73ff0215e8d672dc4c32c317bb3 \
+ file://man/COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
+ file://irdadump/irdadump.c;beginline=1;endline=24;md5=d78b9dce3cd78c2220250c9c7a2be178"
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/irda/irda-utils-${PV}.tar.gz \
+ file://ldflags.patch \
+ file://musl.patch \
+ file://init"
+
+SRC_URI[md5sum] = "84dc12aa4c3f61fccb8d8919bf4079bb"
+SRC_URI[sha256sum] = "61980551e46b2eaa9e17ad31cbc1a638074611fc33bff34163d10c7a67a9fdc6"
+
+inherit update-rc.d
+
+RRECOMMENDS_${PN} = "\
+ kernel-module-pxaficp-ir \
+ kernel-module-irda \
+ kernel-module-ircomm \
+ kernel-module-ircomm-tty \
+ kernel-module-irlan \
+ ${@bb.utils.contains('DISTRO_FEATURES', 'ppp', 'kernel-module-irnet', '',d)} \
+ kernel-module-irport \
+ kernel-module-irtty \
+ kernel-module-irtty-sir \
+ kernel-module-sir-dev \
+ ${@bb.utils.contains('COMBINED_FEATURES', 'usbhost', 'kernel-module-ir-usb', '',d)} "
+
+EXTRA_OEMAKE = "\
+ 'CC=${CC}' \
+ 'LD=${LD}' \
+ 'CFLAGS=${CFLAGS}' \
+ 'LDFLAGS=${LDFLAGS}' \
+ 'SYS_INCLUDES=' \
+ 'V=1' \
+"
+
+INITSCRIPT_NAME = "irattach"
+INITSCRIPT_PARAMS = "defaults 20"
+
+TARGETS ??= "irattach irdaping"
+do_compile () {
+ for t in ${TARGETS}; do
+ oe_runmake -C $t
+ done
+}
+
+do_install () {
+ install -d ${D}${sbindir}
+ for t in ${TARGETS}; do
+ oe_runmake -C $t ROOT="${D}" install
+ done
+
+ install -d ${D}${sysconfdir}/init.d
+ install -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/${INITSCRIPT_NAME}
+}