| SUMMARY = "Command line tool and library for client-side URL transfers" |
| HOMEPAGE = "http://curl.haxx.se/" |
| BUGTRACKER = "http://curl.haxx.se/mail/list.cgi?list=curl-tracker" |
| SECTION = "console/network" |
| LICENSE = "MIT" |
| LIC_FILES_CHKSUM = "file://COPYING;beginline=7;md5=3a34942f4ae3fbf1a303160714e664ac" |
| |
| SRC_URI = "http://curl.haxx.se/download/curl-${PV}.tar.bz2 \ |
| file://pkgconfig_fix.patch \ |
| " |
| |
| # curl likes to set -g0 in CFLAGS, so we stop it |
| # from mucking around with debug options |
| # |
| SRC_URI += " file://configure_ac.patch \ |
| file://CVE-2016-0754.patch \ |
| file://CVE-2016-0755.patch" |
| |
| SRC_URI[md5sum] = "6b952ca00e5473b16a11f05f06aa8dae" |
| SRC_URI[sha256sum] = "1e2541bae6582bb697c0fbae49e1d3e6fad5d05d5aa80dbd6f072e0a44341814" |
| |
| inherit autotools pkgconfig binconfig multilib_header |
| |
| PACKAGECONFIG ??= "${@bb.utils.contains("DISTRO_FEATURES", "ipv6", "ipv6", "", d)} gnutls zlib" |
| PACKAGECONFIG_class-native = "ipv6 ssl zlib" |
| PACKAGECONFIG_class-nativesdk = "ipv6 ssl zlib" |
| |
| PACKAGECONFIG[ipv6] = "--enable-ipv6,--disable-ipv6," |
| PACKAGECONFIG[ssl] = "--with-ssl --with-random=/dev/urandom,--without-ssl,openssl" |
| PACKAGECONFIG[gnutls] = "--with-gnutls,--without-gnutls,gnutls" |
| PACKAGECONFIG[zlib] = "--with-zlib=${STAGING_LIBDIR}/../,--without-zlib,zlib" |
| PACKAGECONFIG[rtmpdump] = "--with-librtmp,--without-librtmp,rtmpdump" |
| PACKAGECONFIG[libssh2] = "--with-libssh2,--without-libssh2,libssh2" |
| PACKAGECONFIG[smb] = "--enable-smb,--disable-smb," |
| |
| EXTRA_OECONF = "--without-libidn \ |
| --enable-crypto-auth \ |
| --disable-ldap \ |
| --disable-ldaps \ |
| --with-ca-bundle=${sysconfdir}/ssl/certs/ca-certificates.crt \ |
| " |
| # see https://lists.yoctoproject.org/pipermail/poky/2013-December/009435.html |
| # We should ideally drop ac_cv_sizeof_off_t from site files but until then |
| EXTRA_OECONF += "${@bb.utils.contains('DISTRO_FEATURES', 'largefile', 'ac_cv_sizeof_off_t=8', '', d)}" |
| |
| do_install_append() { |
| oe_multilib_header curl/curlbuild.h |
| } |
| |
| do_install_append_class-target() { |
| # cleanup buildpaths from curl-config |
| sed -i -e 's,${STAGING_DIR_HOST},,g' ${D}${bindir}/curl-config |
| } |
| |
| PACKAGES =+ "lib${BPN}" |
| |
| FILES_lib${BPN} = "${libdir}/lib*.so.*" |
| RRECOMMENDS_lib${BPN} += "ca-certificates" |
| |
| BBCLASSEXTEND = "native nativesdk" |