meta-openembedded: subtree update:08c0280b7c..4fe1065655
Alexander Kanavin (1):
libmicrohttpd: remove the recipe
Andreas Müller (4):
jack: upgrade 1.19.17 -> 1.19.18
xfce4-settings: upgrade 4.16.0 -> 4.16.1
zsh: reduce priority slightly to avoid conflict with bash
mutter/wayland: replace xserver-xorg-xwayland by xwayland in rdep
Andrej Kozemcak (1):
proftpd: Update to 1.3.7a release
Armin Kuster (3):
wireguard: update to v1.0.20210219 +1
nostromo: remove recipe
packagegroup-meta-webserver: remove nostromo from pkg grp
Chen Qi (3):
tigervnc: upgrade to 1.11.0
python3-django: upgrade to 2.2.20
tigervnc: fix do_package error when enabling user merge
Gianfranco (1):
vboxguestdrivers: upgrade 6.1.18 -> 6.1.20
Hongxu Jia (1):
debootstrap: explicitly add virtual/fakeroot-native to depends
Joe Hershberger (1):
strongswan: Make PACKAGECONFIG a default value
Justin Standring (1):
tslib: add PACKAGECONFIG for evthres, one-wire-ts-input
Kai Kang (1):
freeradius: check existence of openssl's commands in bootstrap
Khem Raj (36):
nss: Re-enable -Werror
gimp: Disable vector icon generation on mips/glibc too
iwd: Upgade to 1.13
python3-icu: Upgrade to 2.7.2
nodejs: Update to 14.16.1
nodejs: Fix build with icu-69
nodejs: Use qemu usermode to run target binaries during build
nodejs: Fix build on mips
nodejs: Fix build with clang for x86 target
tbb: Re-introduce PE
bearssl: Update to tip of master
gimp: Disable vector icons on musl/x86
gd: Replace deprecated types from tiff
nodejs: Enable snapshot
python3-docutils: Delete
libchamplain: Require opengl distro feature
aom: Match the name for AOM-Patent-License-1.0
libdevmapper,lvm2: Do not inherit license
gnome-disk-utility: Require polkit in distro features
README: Make git send-email example work
sysprof: Enable sysprofd/libsysprof only when polkit in DISTRO_FEATURES
packagegroup-gnome-apps: Add gnome-disk-utility only if polkit is in DISTRO_FEATURES
python3-jinja2_2.%.bbappend: Delete
python3-pyyaml: Do not check for meta-python
python3-pyyaml: Delete
python3-markupsafe: Delete bbappend
snort,proftpd,net-snmp: Deal with -ffile-prefix-map as well
apache2: Deal with -ffile-prefix-map
vk-gl-cts: Fix build with GCC 11
gegl: Update to 0.4.30
python3-m2crypto: Upgrade to 0.37.1
libupnp: Upgrade to 1.14.6
ctags: Switch to universal ctags
dibbler: Add libpthread to linker flags
libowfat: Replace __pure__ with pure and remove using __deprecated__
emacs: Do not use SIGSTKSZ
Leon Anavi (21):
python3-bitarray: Upgrade 1.9.2 -> 2.0.0
python3-xxhash: Upgrade 2.0.0 -> 2.0.2
python3-xlsxwriter: Upgrade 1.3.8 -> 1.3.9
python3-docutils: Upgrade 0.17 -> 0.17.1
python3-portion: Upgrade 2.1.5 -> 2.1.6
python3-huey: Upgrade 2.3.1 -> 2.3.2
python3-pysonos: Upgrade 0.0.42 -> 0.0.43
python3-asttokens: Upgrade 2.0.4 -> 2.0.5
python3-hyperframe: Upgrade 6.0.0 -> 6.0.1
python3-argcomplete: Upgrade 1.12.2 -> 1.12.3
python3-python-vlc: Upgrade 3.0.12117 -> 3.0.12118
python3-bitarray: Upgrade 2.0.0 -> 2.0.1
python3-sqlalchemy: Upgrade 1.4.7 -> 1.4.11
python3-watchdog: Upgrade 2.0.2 -> 2.0.3
python3-pytest-asyncio: Upgrade 0.14.0 -> 0.15.1
python3-xlsxwriter: Upgrade 1.3.9 -> 1.4.0
python3-astroid: Upgrade 2.5.3 -> 2.5.6
python3-arpeggio: Upgrade 1.10.1 -> 1.10.2
python3-cachetools: Upgrade 4.2.1 -> 4.2.2
python3-pymisp: Upgrade 2.4.141.1 -> 2.4.142
python3-et-xmlfile: Upgrade 1.0.1 -> 1.1.0
Mingli Yu (4):
python3-cryptography: Upgrade to 3.3.2
onig: add oniguruma to PROVIDES
php: Upgrade to 7.4.16
tk: adapt to potential pseudo changes
Persian Prince (1):
libdvdnav 6.1.1
Peter Kjellerstedt (1):
syslog-ng: Merge .bb and .inc
Ramon Fried (1):
bitwise: Upgrade 0.41 -> 0.42
Reto Schneider (1):
nng: Upgrade 1.2.5 -> 1.4.0
Saul Wold (2):
tbb: Disable PPC as COMPATIBLE_MACHINE
packagegroup-meta-oe: conditional remove tbb for powerpc
Silcet (2):
ufw: fix python shebang
ufw: bump version to 0.36 and add services
Sinan Kaya (1):
zram: add support for mem_limit
Stefan Ghinea (1):
python3-django: fix CVE-2021-28658
Ulrich Ölmann (1):
v4l-utils: fix reproducibility
Yi Fan Yu (3):
syslog-ng: upgrade 3.24.1 -> 3.31.2
syslog-ng: remove CONFIG_TLS override for arm DEBUG_BUILD
syslog-ng: Drop an obsolete patch to add --enable-libnet
Yi Zhao (1):
gvfs: rdepend on gsettings-desktop-schemas
zangrc (19):
fuse3: upgrade 3.10.2 -> 3.10.3
cifs-utils: upgrade 6.12 -> 6.13
dnsmasq: upgrade 2.84 -> 2.85
nbdkit: upgrade 1.25.5 -> 1.25.6
wolfssl: upgrade 4.7.0 -> 4.7.1
networkmanager: upgrade 1.30.2 -> 1.30.4
libdvdread: upgrade 6.1.1 -> 6.1.2
libwebsockets: upgrade 4.1.6 -> 4.2.0
ostree: upgrade 2021.1 -> 2021.2
redis: upgrade 6.2.1 -> 6.2.2
tinyproxy: upgrade 1.10.0 -> 1.11.0
nss: upgrade 3.63 -> 3.64
babeld: upgrade 1.9.2 -> 1.10
fetchmail: upgrade 6.4.18 -> 6.4.19
openvpn: upgrade 2.5.1 -> 2.5.2
wireshark: upgrade 3.4.4 -> 3.4.5
debootstrap: upgrade 1.0.123 -> 1.0.124
mailcap: upgrade 2.1.52 -> 2.1.53
rsyslog: upgrade 8.2102.0 -> 8.2104.0
zhengruoqin (7):
irssi: upgrade 1.2.2 -> 1.2.3
librsync: upgrade 2.3.1 -> 2.3.2
hiawatha: upgrade 10.11 -> 10.12
python3-supervisor: upgrade 4.2.1 -> 4.2.2
python3-zopeinterface: upgrade 5.3.0 -> 5.4.0
sdparm: upgrade 1.11 -> 1.12
tcsh: upgrade 6.22.03 -> 6.22.04
Signed-off-by: Andrew Geissler <geissonator@yahoo.com>
Change-Id: Iaeb2fe4ee0a49cf44ea60bc3c1aef83528d92f55
diff --git a/meta-openembedded/meta-oe/recipes-graphics/tigervnc/tigervnc_1.11.0.bb b/meta-openembedded/meta-oe/recipes-graphics/tigervnc/tigervnc_1.11.0.bb
new file mode 100644
index 0000000..c45fc02
--- /dev/null
+++ b/meta-openembedded/meta-oe/recipes-graphics/tigervnc/tigervnc_1.11.0.bb
@@ -0,0 +1,133 @@
+DESCRIPTION = "TigerVNC remote display system"
+HOMEPAGE = "http://www.tigervnc.com/"
+LICENSE = "GPLv2+"
+SECTION = "x11/utils"
+DEPENDS = "xserver-xorg gnutls jpeg libxtst gettext-native fltk libpam"
+RDEPENDS_${PN} = "coreutils hicolor-icon-theme perl bash"
+
+LIC_FILES_CHKSUM = "file://LICENCE.TXT;md5=75b02c2872421380bbd47781d2bd75d3"
+
+S = "${WORKDIR}/git"
+
+inherit features_check
+REQUIRED_DISTRO_FEATURES = "x11 pam"
+
+inherit autotools cmake
+B = "${S}"
+
+SRCREV = "540bfc3278e396321124d4b18a798ac2bc18b6ca"
+
+SRC_URI = "git://github.com/TigerVNC/tigervnc.git;branch=1.11-branch \
+ file://0002-do-not-build-tests-sub-directory.patch \
+ file://0003-add-missing-dynamic-library-to-FLTK_LIBRARIES.patch \
+ file://0004-tigervnc-add-fPIC-option-to-COMPILE_FLAGS.patch \
+"
+
+# Keep sync with xorg-server in oe-core
+XORG_PN ?= "xorg-server"
+XORG_PV ?= "1.20.6"
+SRC_URI += "${XORG_MIRROR}/individual/xserver/${XORG_PN}-${XORG_PV}.tar.bz2;name=xorg"
+XORG_S = "${WORKDIR}/${XORG_PN}-${XORG_PV}"
+SRC_URI[xorg.md5sum] = "a98170084f2c8fed480d2ff601f8a14b"
+SRC_URI[xorg.sha256sum] = "6316146304e6e8a36d5904987ae2917b5d5b195dc9fc63d67f7aca137e5a51d1"
+
+# It is the directory containing the Xorg source for the
+# machine on which you are building TigerVNC.
+XSERVER_SOURCE_DIR="${S}/unix/xserver"
+
+do_patch[postfuncs] += "do_patch_xserver"
+do_patch_xserver () {
+ for subdir in Xext xkb GL hw/xquartz/bundle hw/xfree86/common; do
+ install -d ${XSERVER_SOURCE_DIR}/$subdir
+ done
+
+ for subdir in hw/dmx/doc man doc hw/dmx/doxygen; do
+ install -d ${XSERVER_SOURCE_DIR}/$subdir
+ done
+
+ sources="hw/xquartz/bundle/cpprules.in man/Xserver.man doc/smartsched \
+ hw/dmx/doxygen/doxygen.conf.in xserver.ent.in xkb/README.compiled \
+ hw/xfree86/xorgconf.cpp hw/xfree86/Xorg.sh.in"
+ for i in ${sources}; do
+ install -m 0644 ${XORG_S}/$i ${XSERVER_SOURCE_DIR}/$i;
+ done
+
+ cd ${XORG_S}
+ find . -type f | egrep '.*\.(c|h|am|ac|inc|m4|h.in|pc.in|man.pre|pl|txt)$' | \
+ xargs tar cf - | (cd ${XSERVER_SOURCE_DIR} && tar xf -)
+
+ cd ${XSERVER_SOURCE_DIR}
+ xserverpatch="${S}/unix/xserver120.patch"
+ echo "Apply $xserverpatch"
+ patch -p1 -b --suffix .vnc < $xserverpatch
+}
+
+EXTRA_OECONF = "--disable-xorg --disable-xnest --disable-xvfb --disable-dmx \
+ --disable-xwin --disable-xephyr --disable-kdrive --with-pic \
+ --disable-static --disable-xinerama \
+ --with-xkb-output=${localstatedir}/lib/xkb \
+ --disable-glx --disable-dri --disable-dri2 \
+ --disable-config-hal \
+ --disable-config-udev \
+ --without-dtrace \
+ --disable-unit-tests \
+ --disable-devel-docs \
+ --disable-selective-werror \
+ --disable-xshmfence \
+ --disable-config-udev \
+ --disable-dri3 \
+ --disable-libunwind \
+ --without-xmlto \
+ --enable-systemd-logind=no \
+ --disable-xinerama \
+ --disable-xwayland \
+"
+
+EXTRA_OECMAKE += "${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '-DCMAKE_INSTALL_UNITDIR=${systemd_unitdir}', '-DINSTALL_SYSTEMD_UNITS=OFF', d)}"
+
+do_configure_append () {
+ olddir=`pwd`
+ cd ${XSERVER_SOURCE_DIR}
+
+ rm -rf aclocal-copy/
+ rm -f aclocal.m4
+
+ export ACLOCALDIR="${XSERVER_SOURCE_DIR}/aclocal-copy"
+ mkdir -p ${ACLOCALDIR}/
+ if [ -d ${STAGING_DATADIR_NATIVE}/aclocal ]; then
+ cp-noerror ${STAGING_DATADIR_NATIVE}/aclocal/ ${ACLOCALDIR}/
+ fi
+ if [ -d ${STAGING_DATADIR}/aclocal -a "${STAGING_DATADIR_NATIVE}/aclocal" != "${STAGING_DATADIR}/aclocal" ]; then
+ cp-noerror ${STAGING_DATADIR}/aclocal/ ${ACLOCALDIR}/
+ fi
+ ACLOCAL="aclocal --system-acdir=${ACLOCALDIR}/" autoreconf -Wcross --verbose --install --force ${EXTRA_AUTORECONF} $acpaths || bbfatal "autoreconf execution failed."
+ chmod +x ./configure
+ ${CACHED_CONFIGUREVARS} ./configure ${CONFIGUREOPTS} ${EXTRA_OECONF}
+ cd $olddir
+}
+
+do_compile_append () {
+ olddir=`pwd`
+ cd ${XSERVER_SOURCE_DIR}
+
+ oe_runmake
+
+ cd $olddir
+}
+
+do_install_append() {
+ olddir=`pwd`
+ cd ${XSERVER_SOURCE_DIR}/hw/vnc
+
+ oe_runmake 'DESTDIR=${D}' install
+
+ cd $olddir
+}
+
+FILES_${PN} += " \
+ ${libdir}/xorg/modules/extensions \
+ ${datadir}/icons \
+ ${systemd_unitdir} \
+"
+
+FILES_${PN}-dbg += "${libdir}/xorg/modules/extensions/.debug"