Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 1 | SUMMARY = "The New Curses library" |
| 2 | DESCRIPTION = "SVr4 and XSI-Curses compatible curses library and terminfo tools including tic, infocmp, captoinfo. Supports color, multiple highlights, forms-drawing characters, and automatic recognition of keypad and function-key sequences. Extensions include resizable windows and mouse support on both xterm and Linux console using the gpm library." |
| 3 | HOMEPAGE = "http://www.gnu.org/software/ncurses/ncurses.html" |
| 4 | LICENSE = "MIT" |
Andrew Geissler | 82c905d | 2020-04-13 13:39:40 -0500 | [diff] [blame] | 5 | LIC_FILES_CHKSUM = "file://ncurses/base/version.c;beginline=1;endline=27;md5=5526f2f3a29edc95538b368a4771edda" |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 6 | SECTION = "libs" |
| 7 | DEPENDS = "ncurses-native" |
Patrick Williams | 213cb26 | 2021-08-07 19:21:33 -0500 | [diff] [blame] | 8 | DEPENDS:class-native = "" |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 9 | |
Brad Bishop | 6e60e8b | 2018-02-01 10:27:11 -0500 | [diff] [blame] | 10 | BINCONFIG = "${bindir}/ncurses5-config ${bindir}/ncursesw5-config \ |
| 11 | ${bindir}/ncurses6-config ${bindir}/ncursesw6-config" |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 12 | |
| 13 | inherit autotools binconfig-disabled multilib_header pkgconfig |
| 14 | |
| 15 | # Upstream has useful patches at times at ftp://invisible-island.net/ncurses/ |
Andrew Geissler | 595f630 | 2022-01-24 19:11:47 +0000 | [diff] [blame] | 16 | SRC_URI = "git://salsa.debian.org/debian/ncurses.git;protocol=https;branch=master" |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 17 | |
| 18 | EXTRA_AUTORECONF = "-I m4" |
Andrew Geissler | c9f7865 | 2020-09-18 14:11:35 -0500 | [diff] [blame] | 19 | |
| 20 | CACHED_CONFIGUREVARS = "cf_cv_func_nanosleep=yes" |
Andrew Geissler | 595f630 | 2022-01-24 19:11:47 +0000 | [diff] [blame] | 21 | CACHED_CONFIGUREVARS:append:linux = " cf_cv_working_poll=yes" |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 22 | |
Brad Bishop | 6e60e8b | 2018-02-01 10:27:11 -0500 | [diff] [blame] | 23 | EXTRASITECONFIG = "CFLAGS='${CFLAGS} -I${SYSROOT_DESTDIR}${includedir}'" |
| 24 | |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 25 | # Whether to enable separate widec libraries; must be 'true' or 'false' |
| 26 | # |
| 27 | # TODO: remove this variable when widec is supported in every setup? |
| 28 | ENABLE_WIDEC ?= "true" |
| 29 | |
| 30 | # _GNU_SOURCE is required for widec stuff and is detected automatically |
| 31 | # for target objects. But it must be set manually for native and sdk |
| 32 | # builds. |
| 33 | BUILD_CPPFLAGS += "-D_GNU_SOURCE" |
| 34 | |
| 35 | # natives don't generally look in base_libdir |
Patrick Williams | 213cb26 | 2021-08-07 19:21:33 -0500 | [diff] [blame] | 36 | base_libdir:class-native = "${libdir}" |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 37 | |
| 38 | # Display corruption occurs on 64 bit hosts without these settings |
| 39 | # This was derrived from the upstream debian ncurses which uses |
| 40 | # these settings for 32 and 64 bit hosts. |
| 41 | EXCONFIG_ARGS = "" |
Patrick Williams | 213cb26 | 2021-08-07 19:21:33 -0500 | [diff] [blame] | 42 | EXCONFIG_ARGS:class-native = " \ |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 43 | --disable-lp64 \ |
| 44 | --with-chtype='long' \ |
| 45 | --with-mmask-t='long'" |
Patrick Williams | 213cb26 | 2021-08-07 19:21:33 -0500 | [diff] [blame] | 46 | EXCONFIG_ARGS:class-nativesdk = " \ |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 47 | --disable-lp64 \ |
| 48 | --with-chtype='long' \ |
| 49 | --with-mmask-t='long'" |
| 50 | |
| 51 | PACKAGES_DYNAMIC = "^${PN}-lib.*" |
| 52 | |
| 53 | # Fall back to the host termcap / terminfo for -nativesdk and -native |
| 54 | # The reality is a work around for strange problems with things like |
| 55 | # "bitbake -c menuconfig busybox" where it cannot find the terminfo |
| 56 | # because the sstate had a hard coded search path. Until this is fixed |
| 57 | # another way this is deemed good enough. |
| 58 | EX_TERMCAP = "" |
Patrick Williams | 213cb26 | 2021-08-07 19:21:33 -0500 | [diff] [blame] | 59 | EX_TERMCAP:class-native = ":/etc/termcap:/usr/share/misc/termcap" |
| 60 | EX_TERMCAP:class-nativesdk = ":/etc/termcap:/usr/share/misc/termcap" |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 61 | EX_TERMINFO = "" |
Patrick Williams | 213cb26 | 2021-08-07 19:21:33 -0500 | [diff] [blame] | 62 | EX_TERMINFO:class-native = ":/etc/terminfo:/usr/share/terminfo:/usr/share/misc/terminfo:/lib/terminfo" |
| 63 | EX_TERMINFO:class-nativesdk = ":/etc/terminfo:/usr/share/terminfo:/usr/share/misc/terminfo:/lib/terminfo" |
Brad Bishop | 316dfdd | 2018-06-25 12:45:53 -0400 | [diff] [blame] | 64 | EX_TERMLIB ?= "tinfo" |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 65 | |
| 66 | # Helper function for do_configure to allow multiple configurations |
| 67 | # $1 the directory to run configure in |
| 68 | # $@ the arguments to pass to configure |
| 69 | ncurses_configure() { |
| 70 | mkdir -p $1 |
| 71 | cd $1 |
| 72 | shift |
| 73 | oe_runconf \ |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 74 | --without-debug \ |
| 75 | --without-ada \ |
| 76 | --without-gpm \ |
| 77 | --enable-hard-tabs \ |
| 78 | --enable-xmc-glitch \ |
| 79 | --enable-colorfgbg \ |
| 80 | --with-termpath='${sysconfdir}/termcap:${datadir}/misc/termcap${EX_TERMCAP}' \ |
| 81 | --with-terminfo-dirs='${sysconfdir}/terminfo:${datadir}/terminfo${EX_TERMINFO}' \ |
| 82 | --with-shared \ |
| 83 | --disable-big-core \ |
| 84 | --program-prefix= \ |
| 85 | --with-ticlib \ |
Brad Bishop | 316dfdd | 2018-06-25 12:45:53 -0400 | [diff] [blame] | 86 | --with-termlib=${EX_TERMLIB} \ |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 87 | --enable-sigwinch \ |
| 88 | --enable-pc-files \ |
| 89 | --disable-rpath-hack \ |
| 90 | ${EXCONFIG_ARGS} \ |
| 91 | --with-manpage-format=normal \ |
Andrew Geissler | 82c905d | 2020-04-13 13:39:40 -0500 | [diff] [blame] | 92 | --without-manpage-renames \ |
Brad Bishop | 1a4b7ee | 2018-12-16 17:11:34 -0800 | [diff] [blame] | 93 | --disable-stripping \ |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 94 | "$@" || return 1 |
| 95 | cd .. |
| 96 | } |
| 97 | |
| 98 | # Override the function from the autotools class; ncurses requires a |
| 99 | # patched autoconf213 to generate the configure script. This autoconf |
| 100 | # is not available so that the shipped script will be used. |
| 101 | do_configure() { |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 102 | #Remove ${includedir} from CPPFLAGS, need for cross compile |
| 103 | sed -i 's#-I${cf_includedir}##g' ${S}/configure || die "sed CPPFLAGS" |
| 104 | |
| 105 | # The --enable-pc-files requires PKG_CONFIG_LIBDIR existed |
| 106 | mkdir -p ${PKG_CONFIG_LIBDIR} |
| 107 | ( cd ${S}; gnu-configize --force ) |
| 108 | ncurses_configure "narrowc" || \ |
| 109 | return 1 |
| 110 | ! ${ENABLE_WIDEC} || \ |
| 111 | ncurses_configure "widec" "--enable-widec" "--without-progs" |
| 112 | |
| 113 | } |
| 114 | |
| 115 | do_compile() { |
| 116 | oe_runmake -C narrowc libs |
| 117 | oe_runmake -C narrowc/progs |
| 118 | |
| 119 | ! ${ENABLE_WIDEC} || \ |
| 120 | oe_runmake -C widec libs |
| 121 | } |
| 122 | |
| 123 | # set of expected differences between narrowc and widec header |
| 124 | # |
| 125 | # TODO: the NCURSES_CH_T difference can cause real problems :( |
| 126 | _unifdef_cleanup = " \ |
| 127 | -e '\!/\* \$Id: curses.wide,v!,\!/\* \$Id: curses.tail,v!d' \ |
| 128 | -e '/^#define NCURSES_CH_T /d' \ |
| 129 | -e '/^#include <wchar.h>/d' \ |
| 130 | -e '\!^/\* .* \*/!d' \ |
| 131 | " |
| 132 | |
| 133 | do_test[depends] = "unifdef-native:do_populate_sysroot" |
| 134 | do_test[dirs] = "${S}" |
| 135 | do_test() { |
| 136 | ${ENABLE_WIDEC} || return 0 |
| 137 | |
| 138 | # make sure that the narrow and widec header are compatible |
| 139 | # and differ only in minor details. |
| 140 | unifdef -k narrowc/include/curses.h | \ |
| 141 | sed ${_unifdef_cleanup} > curses-narrowc.h |
| 142 | unifdef -k widec/include/curses.h | \ |
| 143 | sed ${_unifdef_cleanup} > curses-widec.h |
| 144 | |
| 145 | diff curses-narrowc.h curses-widec.h |
| 146 | } |
| 147 | |
| 148 | # Split original _install_opts to two parts. |
| 149 | # One is the options to install contents, the other is the parameters \ |
| 150 | # when running command "make install" |
Patrick Williams | d8c66bc | 2016-06-20 12:57:21 -0500 | [diff] [blame] | 151 | # Note that install.libs will also implicitly install header files, |
| 152 | # so we do not need to explicitly specify install.includes. |
| 153 | # Doing so could in fact result in a race condition, as both targets |
| 154 | # (install.libs and install.includes) would install the same headers |
| 155 | # at the same time |
| 156 | |
| 157 | _install_opts = " install.libs install.man " |
| 158 | |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 159 | _install_cfgs = "\ |
| 160 | DESTDIR='${D}' \ |
| 161 | PKG_CONFIG_LIBDIR='${libdir}/pkgconfig' \ |
| 162 | " |
| 163 | |
| 164 | do_install() { |
| 165 | # Order of installation is important; widec installs a 'curses.h' |
| 166 | # header with more definitions and must be installed last hence. |
| 167 | # Compatibility of these headers will be checked in 'do_test()'. |
| 168 | oe_runmake -C narrowc ${_install_cfgs} ${_install_opts} \ |
| 169 | install.progs |
| 170 | |
| 171 | # The install.data should run after install.libs, otherwise |
| 172 | # there would be a race issue in a very critical conditon, since |
| 173 | # tic will be run by install.data, and tic needs libtinfo.so |
| 174 | # which would be regenerated by install.libs. |
| 175 | oe_runmake -C narrowc ${_install_cfgs} \ |
| 176 | install.data |
| 177 | |
| 178 | |
| 179 | ! ${ENABLE_WIDEC} || \ |
| 180 | oe_runmake -C widec ${_install_cfgs} ${_install_opts} |
| 181 | |
| 182 | cd narrowc |
| 183 | |
| 184 | # include some basic terminfo files |
| 185 | # stolen ;) from gentoo and modified a bit |
| 186 | for x in ansi console dumb linux rxvt screen screen-256color sun vt52 vt100 vt102 vt200 vt220 xterm-color xterm-xfree86 xterm-256color |
| 187 | do |
| 188 | local termfile="$(find "${D}${datadir}/terminfo/" -name "${x}" 2>/dev/null)" |
| 189 | local basedir="$(basename $(dirname "${termfile}"))" |
| 190 | |
| 191 | if [ -n "${termfile}" ] |
| 192 | then |
| 193 | install -d ${D}${sysconfdir}/terminfo/${basedir} |
| 194 | mv ${termfile} ${D}${sysconfdir}/terminfo/${basedir}/ |
| 195 | ln -s /etc/terminfo/${basedir}/${x} \ |
| 196 | ${D}${datadir}/terminfo/${basedir}/${x} |
| 197 | fi |
| 198 | done |
| 199 | # i think we can use xterm-color as default xterm |
| 200 | if [ -e ${D}${sysconfdir}/terminfo/x/xterm-color ] |
| 201 | then |
| 202 | ln -sf xterm-color ${D}${sysconfdir}/terminfo/x/xterm |
| 203 | fi |
| 204 | |
Brad Bishop | 316dfdd | 2018-06-25 12:45:53 -0400 | [diff] [blame] | 205 | # When changing ${libdir} to e.g. /usr/lib/myawesomelib/ ncurses |
| 206 | # still installs '/usr/lib/terminfo', so try to rm both |
| 207 | # the proper path and a slightly hardcoded one |
| 208 | rm -f ${D}${libdir}/terminfo ${D}${prefix}/lib/terminfo |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 209 | |
| 210 | # create linker scripts for libcurses.so and libncurses to |
| 211 | # link against -ltinfo when needed. Some builds might break |
| 212 | # else when '-Wl,--no-copy-dt-needed-entries' has been set in |
| 213 | # linker flags. |
| 214 | for i in libncurses libncursesw; do |
| 215 | f=${D}${libdir}/$i.so |
| 216 | test -h $f || continue |
| 217 | rm -f $f |
| 218 | echo '/* GNU ld script */' >$f |
| 219 | echo "INPUT($i.so.5 AS_NEEDED(-ltinfo))" >>$f |
| 220 | done |
| 221 | |
| 222 | # Make sure that libcurses is linked so that it gets -ltinfo |
| 223 | # also, this should be addressed upstream really. |
| 224 | ln -sf libncurses.so ${D}${libdir}/libcurses.so |
| 225 | |
| 226 | # create libtermcap.so linker script for backward compatibility |
| 227 | f=${D}${libdir}/libtermcap.so |
| 228 | echo '/* GNU ld script */' >$f |
| 229 | echo 'INPUT(AS_NEEDED(-ltinfo))' >>$f |
| 230 | |
| 231 | if [ ! -d "${D}${base_libdir}" ]; then |
| 232 | # Setting base_libdir to libdir as is done in the -native |
| 233 | # case will skip this code |
Brad Bishop | 316dfdd | 2018-06-25 12:45:53 -0400 | [diff] [blame] | 234 | mkdir -p ${D}${base_libdir} |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 235 | mv ${D}${libdir}/libncurses.so.* ${D}${base_libdir} |
| 236 | ! ${ENABLE_WIDEC} || \ |
| 237 | mv ${D}${libdir}/libncursesw.so.* ${D}${base_libdir} |
| 238 | |
| 239 | mv ${D}${libdir}/libtinfo.so.* ${D}${base_libdir} |
| 240 | rm ${D}${libdir}/libtinfo.so |
| 241 | |
Andrew Geissler | 595f630 | 2022-01-24 19:11:47 +0000 | [diff] [blame] | 242 | # Use ln -rs to ensure this is a relative link despite absolute paths |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 243 | # (as we can't know the relationship between base_libdir and libdir). |
Andrew Geissler | 595f630 | 2022-01-24 19:11:47 +0000 | [diff] [blame] | 244 | ln -rs ${D}${base_libdir}/libtinfo.so.5 ${D}${libdir}/libtinfo.so |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 245 | fi |
| 246 | if [ -d "${D}${includedir}/ncurses" ]; then |
| 247 | for f in `find ${D}${includedir}/ncurses -name "*.h"` |
| 248 | do |
| 249 | f=`basename $f` |
| 250 | test -e ${D}${includedir}/$f && continue |
| 251 | ln -sf ncurses/$f ${D}${includedir}/$f |
| 252 | done |
| 253 | fi |
| 254 | oe_multilib_header curses.h |
| 255 | } |
| 256 | |
Patrick Williams | 213cb26 | 2021-08-07 19:21:33 -0500 | [diff] [blame] | 257 | python populate_packages:prepend () { |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 258 | libdir = d.expand("${libdir}") |
| 259 | base_libdir = d.expand("${base_libdir}") |
| 260 | pnbase = d.expand("${PN}-lib%s") |
Brad Bishop | 1932369 | 2019-04-05 15:28:33 -0400 | [diff] [blame] | 261 | do_split_packages(d, libdir, r'^lib(.*)\.so\..*', pnbase, 'ncurses %s library', prepend=True, extra_depends = '', allow_links=True) |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 262 | if libdir is not base_libdir: |
Brad Bishop | 1932369 | 2019-04-05 15:28:33 -0400 | [diff] [blame] | 263 | do_split_packages(d, base_libdir, r'^lib(.*)\.so\..*', pnbase, 'ncurses %s library', prepend=True, extra_depends = '', allow_links=True) |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 264 | } |
| 265 | |
| 266 | |
| 267 | inherit update-alternatives |
| 268 | |
| 269 | ALTERNATIVE_PRIORITY = "100" |
| 270 | |
Patrick Williams | 213cb26 | 2021-08-07 19:21:33 -0500 | [diff] [blame] | 271 | ALTERNATIVE:ncurses-tools:class-target = "clear reset" |
| 272 | ALTERNATIVE:ncurses-terminfo:class-target = "st st-256color" |
Andrew Geissler | c3d88e4 | 2020-10-02 09:45:00 -0500 | [diff] [blame] | 273 | |
| 274 | ALTERNATIVE_LINK_NAME[st] = "${datadir}/terminfo/s/st" |
| 275 | |
| 276 | ALTERNATIVE_LINK_NAME[st-256color] = "${datadir}/terminfo/s/st-256color" |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 277 | |
| 278 | BBCLASSEXTEND = "native nativesdk" |
| 279 | |
| 280 | PACKAGES += " \ |
| 281 | ${PN}-tools \ |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 282 | ${PN}-terminfo-base \ |
Patrick Williams | d8c66bc | 2016-06-20 12:57:21 -0500 | [diff] [blame] | 283 | ${PN}-terminfo \ |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 284 | " |
| 285 | |
Patrick Williams | 213cb26 | 2021-08-07 19:21:33 -0500 | [diff] [blame] | 286 | FILES:${PN} = "\ |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 287 | ${bindir}/tput \ |
| 288 | ${bindir}/tset \ |
| 289 | ${bindir}/ncurses5-config \ |
| 290 | ${bindir}/ncursesw5-config \ |
Brad Bishop | 6e60e8b | 2018-02-01 10:27:11 -0500 | [diff] [blame] | 291 | ${bindir}/ncurses6-config \ |
| 292 | ${bindir}/ncursesw6-config \ |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 293 | ${datadir}/tabset \ |
| 294 | " |
| 295 | |
| 296 | # This keeps only tput/tset in ncurses |
| 297 | # clear/reset are in already busybox |
Patrick Williams | 213cb26 | 2021-08-07 19:21:33 -0500 | [diff] [blame] | 298 | FILES:${PN}-tools = "\ |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 299 | ${bindir}/tic \ |
| 300 | ${bindir}/toe \ |
| 301 | ${bindir}/infotocap \ |
| 302 | ${bindir}/captoinfo \ |
| 303 | ${bindir}/infocmp \ |
Patrick Williams | d8c66bc | 2016-06-20 12:57:21 -0500 | [diff] [blame] | 304 | ${bindir}/clear${@['', '.${BPN}']['${CLASSOVERRIDE}' == 'class-target']} \ |
| 305 | ${bindir}/reset${@['', '.${BPN}']['${CLASSOVERRIDE}' == 'class-target']} \ |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 306 | ${bindir}/tack \ |
| 307 | ${bindir}/tabs \ |
| 308 | " |
| 309 | |
| 310 | # 'reset' is a symlink to 'tset' which is in the 'ncurses' package |
Patrick Williams | 213cb26 | 2021-08-07 19:21:33 -0500 | [diff] [blame] | 311 | RDEPENDS:${PN}-tools = "${PN} ${PN}-terminfo-base" |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 312 | |
Patrick Williams | 213cb26 | 2021-08-07 19:21:33 -0500 | [diff] [blame] | 313 | FILES:${PN}-terminfo = "\ |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 314 | ${datadir}/terminfo \ |
| 315 | " |
| 316 | |
Patrick Williams | 213cb26 | 2021-08-07 19:21:33 -0500 | [diff] [blame] | 317 | FILES:${PN}-terminfo-base = "\ |
Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 318 | ${sysconfdir}/terminfo \ |
| 319 | " |
| 320 | |
Patrick Williams | 213cb26 | 2021-08-07 19:21:33 -0500 | [diff] [blame] | 321 | RSUGGESTS:${PN}-libtinfo = "${PN}-terminfo" |
| 322 | RRECOMMENDS:${PN}-libtinfo = "${PN}-terminfo-base" |
Andrew Geissler | d1e8949 | 2021-02-12 15:35:20 -0600 | [diff] [blame] | 323 | |
| 324 | # Putting terminfo into the sysroot adds around 2800 files to |
| 325 | # each recipe specific sysroot. We can live without this, particularly |
| 326 | # as many recipes may have native and target copies. |
Patrick Williams | 213cb26 | 2021-08-07 19:21:33 -0500 | [diff] [blame] | 327 | SYSROOT_DIRS:remove = "${datadir}" |