Andrew Geissler | d583833 | 2022-05-27 11:33:10 -0500 | [diff] [blame] | 1 | SUMMARY = "eudev is a fork of systemd's udev" |
| 2 | HOMEPAGE = "https://github.com/eudev-project/eudev" |
| 3 | DESCRIPTION = "eudev is Gentoo's fork of udev, systemd's device file manager for the Linux kernel. It manages device nodes in /dev and handles all user space actions when adding or removing devices." |
| 4 | LICENSE = "GPL-2.0-or-later & LGPL-2.1-or-later" |
| 5 | LICENSE:libudev = "LGPL-2.1-or-later" |
| 6 | LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe" |
| 7 | |
| 8 | DEPENDS = "gperf-native" |
| 9 | |
| 10 | PROVIDES = "udev" |
| 11 | |
Andrew Geissler | 87f5cff | 2022-09-30 13:13:31 -0500 | [diff] [blame] | 12 | SRC_URI = "${GITHUB_BASE_URI}/download/v${PV}/${BP}.tar.gz \ |
Andrew Geissler | d583833 | 2022-05-27 11:33:10 -0500 | [diff] [blame] | 13 | file://init \ |
| 14 | file://local.rules \ |
| 15 | file://0001-build-Remove-dead-g-i-r-configuration.patch \ |
| 16 | " |
| 17 | |
| 18 | SRC_URI[sha256sum] = "19847cafec67897da855fde56f9dc7d92e21c50e450aa79068a7e704ed44558b" |
| 19 | |
Andrew Geissler | 87f5cff | 2022-09-30 13:13:31 -0500 | [diff] [blame] | 20 | GITHUB_BASE_URI = "https://github.com/eudev-project/eudev/releases" |
Andrew Geissler | d583833 | 2022-05-27 11:33:10 -0500 | [diff] [blame] | 21 | |
Andrew Geissler | 87f5cff | 2022-09-30 13:13:31 -0500 | [diff] [blame] | 22 | inherit autotools update-rc.d qemu pkgconfig features_check manpages github-releases |
Andrew Geissler | d583833 | 2022-05-27 11:33:10 -0500 | [diff] [blame] | 23 | |
| 24 | CONFLICT_DISTRO_FEATURES = "systemd" |
| 25 | |
| 26 | EXTRA_OECONF = " \ |
| 27 | --sbindir=${base_sbindir} \ |
| 28 | --with-rootlibdir=${base_libdir} \ |
| 29 | --with-rootlibexecdir=${nonarch_base_libdir}/udev \ |
| 30 | --with-rootprefix= \ |
| 31 | " |
| 32 | |
| 33 | PACKAGECONFIG ?= "blkid hwdb kmod \ |
| 34 | ${@bb.utils.filter('DISTRO_FEATURES', 'selinux', d)} \ |
| 35 | " |
| 36 | PACKAGECONFIG[blkid] = "--enable-blkid,--disable-blkid,util-linux" |
| 37 | PACKAGECONFIG[hwdb] = "--enable-hwdb,--disable-hwdb" |
| 38 | PACKAGECONFIG[kmod] = "--enable-kmod,--disable-kmod,kmod" |
| 39 | PACKAGECONFIG[manpages] = "--enable-manpages,--disable-manpages" |
| 40 | PACKAGECONFIG[rule-generator] = "--enable-rule-generator,--disable-rule-generator" |
| 41 | PACKAGECONFIG[selinux] = "--enable-selinux,--disable-selinux,libselinux" |
| 42 | |
| 43 | do_install:append() { |
| 44 | install -d ${D}${sysconfdir}/init.d |
| 45 | install -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/udev |
| 46 | sed -i s%@UDEVD@%${base_sbindir}/udevd% ${D}${sysconfdir}/init.d/udev |
| 47 | sed -i s%@KMOD@%${base_bindir}/kmod% ${D}${sysconfdir}/init.d/udev |
| 48 | |
| 49 | install -d ${D}${sysconfdir}/udev/rules.d |
| 50 | install -m 0644 ${WORKDIR}/local.rules ${D}${sysconfdir}/udev/rules.d/local.rules |
| 51 | |
| 52 | # Use classic network interface naming scheme |
| 53 | touch ${D}${sysconfdir}/udev/rules.d/80-net-name-slot.rules |
| 54 | } |
| 55 | |
| 56 | do_install:prepend:class-target () { |
| 57 | # Remove references to buildmachine |
| 58 | sed -i -e 's:${RECIPE_SYSROOT_NATIVE}::g' \ |
| 59 | ${B}/src/udev/keyboard-keys-from-name.h |
| 60 | } |
| 61 | |
| 62 | INITSCRIPT_NAME = "udev" |
| 63 | INITSCRIPT_PARAMS = "start 04 S ." |
| 64 | |
| 65 | PACKAGE_BEFORE_PN = "libudev ${PN}-hwdb" |
| 66 | |
| 67 | FILES:${PN} += "${nonarch_base_libdir}/udev" |
| 68 | FILES:libudev = "${base_libdir}/libudev.so.*" |
| 69 | FILES:${PN}-hwdb = "${sysconfdir}/udev/hwdb.d" |
| 70 | |
| 71 | RDEPENDS:${PN}-hwdb += "eudev" |
| 72 | RDEPENDS:${PN} += "kmod" |
| 73 | |
| 74 | RPROVIDES:${PN} = "hotplug udev" |
| 75 | RPROVIDES:${PN}-hwdb += "udev-hwdb" |
| 76 | |
| 77 | PACKAGE_WRITE_DEPS += "qemu-native" |
| 78 | pkg_postinst:${PN}-hwdb () { |
| 79 | if test -n "$D"; then |
| 80 | $INTERCEPT_DIR/postinst_intercept update_udev_hwdb ${PKG} mlprefix=${MLPREFIX} binprefix=${MLPREFIX} |
| 81 | else |
| 82 | udevadm hwdb --update |
| 83 | fi |
| 84 | } |
| 85 | |
| 86 | pkg_prerm:${PN}-hwdb () { |
| 87 | rm -f $D${sysconfdir}/udev/hwdb.bin |
| 88 | } |