diff --git a/tools/meson.build b/tools/meson.build
new file mode 100644
index 0000000..826d04c
--- /dev/null
+++ b/tools/meson.build
@@ -0,0 +1,42 @@
+tools_inc = include_directories('.')
+
+updater_pre = [
+  dependency('ipmiblob'),
+  dependency('pciaccess', fallback: ['pciaccess', 'dep_pciaccess']),
+  dependency('stdplus', fallback: ['stdplus', 'stdplus_dep']),
+  blobs_dep,
+  sys_dep]
+
+updater_lib = static_library(
+  'updater_lib',
+  'updater.cpp',
+  'handler.cpp',
+  'helper.cpp',
+  'bt.cpp',
+  'lpc.cpp',
+  'io.cpp',
+  'net.cpp',
+  'pci.cpp',
+  'pciaccess.cpp',
+  'p2a.cpp',
+  'progress.cpp',
+  dependencies: updater_pre,
+  include_directories: root_inc)
+
+updater_dep = declare_dependency(
+  dependencies: updater_pre,
+  include_directories: root_inc,
+  link_with: updater_lib)
+
+executable(
+  'burn_my_bmc',
+  'main.cpp',
+  implicit_include_directories: false,
+  dependencies: updater_dep,
+  include_directories: root_inc,
+  install: true,
+  install_dir: get_option('bindir'))
+
+if not get_option('tests').disabled()
+  subdir('test')
+endif
diff --git a/tools/test/meson.build b/tools/test/meson.build
new file mode 100644
index 0000000..99aab7a
--- /dev/null
+++ b/tools/test/meson.build
@@ -0,0 +1,20 @@
+tool_tests = [
+  'tools_bt',
+  'tools_lpc',
+  'tools_pci',
+  'tools_net',
+  'tools_updater',
+  'tools_helper',
+  'io',
+]
+
+foreach t : tool_tests
+  test(
+    t,
+    executable(
+      t.underscorify(), t + '_unittest.cpp',
+      build_by_default: false,
+      implicit_include_directories: false,
+      include_directories: [root_inc, tools_inc],
+      dependencies: [updater_dep, gtest, gmock]))
+endforeach