meta-openembedded: subtree update:679bb49126..7c02c7d411
Adam Miartus (1):
toybox: allow user to provide own defconfig
Adrian Bunk (5):
uftrace: Fix PR
mraa: Replace -fcommon with fix
mozjs: Remove workaround for gcc < 4.9
flatbuffers: Remove workarounds for gcc < 6
protobuf-c: Remove workarounds for gcc < 6
Alejandro Enedino Hernandez Samaniego (2):
weechat: introduce weechat recipe providing a fully working IRC client
imapfilter: introduce imapfilter recipe providing a mailbox filter through the IMAP protocol
Alejandro Hernandez Samaniego (1):
remmina: Upgrade to version 1.4.3
Alexander Vickberg (2):
tcpdump: Fix PACKAGECONFIG for OpenSSL
iperf3: Add OpenSSL build option to PACKAGECONFIG
Alistair Francis (2):
geany-plugins: Support libgit2 version 1.0
libgit2: Update to v1.0.0
Andreas Müller (5):
xfce4-notifyd: upgrade 0.6.0 -> 0.6.1
xfconf: upgrade 4.14.1 -> 4.14.2
xfwm4: upgrade 4.14.1 -> 4.14.2
qpdf: upgrade 9.1.0 -> 10.0.1
qpdf: link libatomic explicitly on mips
Bartłomiej Burdukiewicz (2):
pugixml: generate pkgconfig files.
pugixml: add native and nativesdk BBCLASSEXTEND
Claude Bing (3):
php: fix PACKAGECONFIG for soap
php: fix opcache link error in 7.4
php: update fix for opcache link issue in 7.4.4
Emmanuel Roullit (1):
cockpit: fix metainfo.xml file ownership
Gianfranco Costamagna (1):
cpprest: Disable one more test requiring internet connection
Gregory Vimont (1):
opencv: 4.1.0 -> 4.3.0
Jonathan Liu (1):
x11vnc: fix xfc NULL pointer dereference
Jorge Solla (1):
Cockpit: Added missing dependency on udisks2 for package cockpit-storaged
Khem Raj (7):
remmina: Depend on avahi instead of Avahi-ui
libgit2: Enable pcre2 regexp backend
con2fbmap: Add recipe
xf86-input-void: Drop INC_PR
nodejs: Fix build with icu 67.1
nss: Remove mcpu to avoid march conflicts
pmdk: Update to 1.8
Konrad Weihmann (2):
php: fix zip package config
php: add multibyte string support config
Leon Anavi (1):
lirc: upgrade 0.9.4d -> 0.10.1
Michael Haener (1):
cockpit: Add recipe version 218
Mingli Yu (10):
python3-ntplib: add missing python3-io RDEPENDS
python3-pid: add the missing rdepends
python3-parallax: add the missing rdepends
python3-pkgconfig: add missing rdepends
python3-pathlib2: add the missing rdepends
python3-ptyprocess: add the missing rdepends
python3-pydbus: add the missing rdepends
python3-pyudev: add the missing rdepends
python3-zipp: add the missing rdepends
gnome-themes-extra: correct the recipe name
Pierre-Jean Texier (1):
ccid: upgrade 1.4.31 -> 1.4.32
Rasmus Villemoes (1):
libgpiod: split c++ library to its own package
Sean Nyekjaer (1):
gpsd: Upgrade 3.19 -> 3.20
Slater, Joseph (2):
python-pretty-table: add rdep's
python3-pyhamcrest: add rdep
Trevor Gamblin (7):
python3-py: add python3-netclient to RDEPENDS
python3-markdown: add logging and setuptools to RDEPENDS
python3-pyrsistent: add python3-numbers to RDEPENDS
python3-pytoml: add datetime and stringold to RDEPENDS
python3-dbusmock: re-add recipe and fix patch path
python3-pyyaml: add python3-netclient to RDEPENDS
python3-werkzeug: add python3-logging to RDEPENDS
Wang Mingyu (6):
mailcap: upgrade 2.1.48 -> 2.1.49
sanlock: upgrade 3.8.0 -> 3.8.1
libcgi-perl: upgrade 4.46 -> 4.47
libencode-perl: upgrade 3.05 -> 3.06
python3-idna: upgrade 2.8 -> 2.9
multipath-tools: upgrade 0.8.3 -> 0.8.4
Yi Zhao (1):
nginx: remove /var/log/nginx when do_install
Zang Ruochen (8):
python3-parse-type: Modify ptest output format
python3-pluggy: Modify ptest output format
python3-polyline: Modify ptest output format
python3-precise-runner: Modify ptest output format
python3-prettytable: Modify ptest output format
python3-ptyprocess: Modify ptest output format
python3-pyasn1: Modify ptest output format
python3-pyasn1-modules: Modify ptest output format
Zheng Ruoqin (4):
python3-pyserial: Modify ptest output format
python3-pyroute2: Modify ptest output format
v4l-utils: upgrade 1.18.0 -> 1.18.1
cpprest: upgrade 2.10.15 -> 2.10.16
Zong Li (1):
Upgrade testfloat to 3e version.
niko.mauno@vaisala.com (3):
python3-setuptools-scm: Cosmetic improvement
python3-setuptools-scm: Add nativesdk to BBCLASSEXTEND
python3-attrs: Add nativesdk to BBCLASSEXTEND
Change-Id: I696f29557eafda5f9f9d6e26525e1a5819982a4b
Signed-off-by: Andrew Geissler <geissonator@yahoo.com>
diff --git a/meta-openembedded/meta-webserver/recipes-webadmin/cockpit/cockpit_218.bb b/meta-openembedded/meta-webserver/recipes-webadmin/cockpit/cockpit_218.bb
new file mode 100644
index 0000000..0de787f
--- /dev/null
+++ b/meta-openembedded/meta-webserver/recipes-webadmin/cockpit/cockpit_218.bb
@@ -0,0 +1,178 @@
+SUMMARY = "Admin interface for Linux machines"
+DESCRIPTION = "Cockpit makes it easy to administer your GNU/Linux servers via a web browser"
+
+LICENSE = "LGPLv2.1"
+LIC_FILES_CHKSUM = "file://COPYING;md5=4fbd65380cdd255951079008b364516c"
+
+SRC_URI += " \
+ https://github.com/cockpit-project/cockpit/releases/download/${PV}/cockpit-${PV}.tar.xz \
+ file://0001-remove-tests-dep-on-gobject-intro.patch \
+ file://0002-fix-makefile-use-copy-rule-for-unmodified-files.patch \
+ file://0003-install-fix-metainfo.xml-ownership-on-install.patch \
+ file://cockpit.pam \
+ "
+SRC_URI[md5sum] = "e69b0b8a75a5d55ddfd9817d857c71af"
+SRC_URI[sha256sum] = "5f242cefccd7f1120c9e0310581aa51dbe941d9c4a6d8375c45057dcbb6f2fbb"
+
+inherit gettext pkgconfig autotools systemd features_check
+
+DEPENDS += "glib-2.0-native intltool-native gnutls virtual/gettext json-glib krb5 libpam systemd"
+
+COMPATIBLE_HOST_libc-musl = "null"
+
+RDEPENDS_${PN} += "glib-networking"
+
+REQUIRED_DISTRO_FEATURES = "systemd pam"
+
+COCKPIT_USER_GROUP ?= "root"
+COCKPIT_WS_USER_GROUP ?= "${COCKPIT_USER_GROUP}"
+
+EXTRA_AUTORECONF = "-I tools"
+EXTRA_OECONF = " \
+ --with-cockpit-user=${COCKPIT_USER_GROUP} \
+ --with-cockpit-group=${COCKPIT_USER_GROUP} \
+ --with-cockpit-ws-instance-user=${COCKPIT_WS_USER_GROUP} \
+ --with-cockpit-ws-instance-group=${COCKPIT_WS_USER_GROUP} \
+ --disable-doc \
+ --with-systemdunitdir=${systemd_system_unitdir} \
+"
+
+PACKAGECONFIG[pcp] = "--enable-pcp,--disable-pcp,pcp"
+PACKAGECONFIG[dashboard] = "--enable-ssh,--disable-ssh,libssh"
+
+PACKAGES =+ " \
+ ${PN}-pcp \
+ ${PN}-realmd \
+ ${PN}-tuned \
+ ${PN}-shell \
+ ${PN}-systemd \
+ ${PN}-users \
+ ${PN}-kdump \
+ ${PN}-sosreport \
+ ${PN}-storaged \
+ ${PN}-networkmanager \
+ ${PN}-machines \
+ ${PN}-selinux \
+ ${PN}-playground \
+ ${PN}-docker \
+ ${PN}-dashboard \
+ ${PN}-bridge \
+ ${PN}-ws \
+ ${PN}-desktop \
+"
+SYSTEMD_PACKAGES = "${PN}-ws"
+
+FILES_${PN}-pcp = " \
+ ${libexecdir}/cockpit-pcp \
+ ${datadir}/cockpit/pcp \
+ ${localstatedir}/lib/pcp/config/pmlogconf/tools/cockpit \
+"
+FILES_${PN}-realmd = "${datadir}/cockpit/realmd"
+FILES_${PN}-tuned = "${datadir}/cockpit/tuned"
+FILES_${PN}-shell = "${datadir}/cockpit/shell"
+FILES_${PN}-systemd = "${datadir}/cockpit/systemd"
+FILES_${PN}-users = "${datadir}/cockpit/users"
+FILES_${PN}-kdump = " \
+ ${datadir}/cockpit/kdump \
+ ${datadir}/metainfo/org.cockpit-project.cockpit-kdump.metainfo.xml \
+"
+FILES_${PN}-sosreport = " \
+ ${datadir}/cockpit/sosreport \
+ ${datadir}/metainfo/org.cockpit-project.cockpit-sosreport.metainfo.xml \
+ ${datadir}/pixmaps/cockpit-sosreport.png \
+"
+FILES_${PN}-storaged = " \
+ ${datadir}/cockpit/storaged \
+ ${datadir}/metainfo/org.cockpit-project.cockpit-storaged.metainfo.xml \
+"
+RDEPENDS_${PN}-storaged = "udisks2"
+
+FILES_${PN}-networkmanager = "${datadir}/cockpit/networkmanager"
+RDEPENDS_${PN}-networkmanager = "networkmanager"
+
+FILES_${PN}-machines = " \
+ ${datadir}/cockpit/machines \
+ ${datadir}/metainfo/org.cockpit-project.cockpit-machines.metainfo.xml \
+"
+FILES_${PN}-selinux = " \
+ ${datadir}/cockpit/selinux \
+ ${datadir}/metainfo/org.cockpit-project.cockpit-selinux.metainfo.xml \
+"
+FILES_${PN}-playground = "${datadir}/cockpit/playground"
+FILES_${PN}-docker = " \
+ ${datadir}/cockpit/docker \
+ ${datadir}/metainfo/org.cockpit-project.cockpit-docker.metainfo.xml \
+"
+FILES_${PN}-dashboard = "${datadir}/cockpit/dashboard"
+ALLOW_EMPTY_${PN}-dashboard = "1"
+
+FILES_${PN}-bridge = " \
+ ${bindir}/cockpit-bridge \
+ ${libexec}/cockpit-askpass \
+"
+RDEPENDS_${PN}-bridge = ""
+
+FILES_${PN}-desktop = "${libexecdir}/cockpit-desktop"
+RDEPENDS_${PN}-desktop += "bash"
+
+FILES_${PN}-ws = " \
+ ${sysconfdir}/cockpit/ws-certs.d \
+ ${sysconfdir}/pam.d/cockpit \
+ ${sysconfdir}/issue.d/cockpit.issue \
+ ${sysconfdir}/motd.d/cockpit \
+ ${datadir}/cockpit/motd/update-motd \
+ ${datadir}/cockpit/motd/inactive.motd \
+ ${systemd_system_unitdir}/cockpit.service \
+ ${systemd_system_unitdir}/cockpit-motd.service \
+ ${systemd_system_unitdir}/cockpit.socket \
+ ${systemd_system_unitdir}/cockpit-wsinstance-http.socket \
+ ${systemd_system_unitdir}/cockpit-wsinstance-http.service \
+ ${systemd_system_unitdir}/cockpit-wsinstance-http-redirect.socket \
+ ${systemd_system_unitdir}/cockpit-wsinstance-http-redirect.service \
+ ${systemd_system_unitdir}/cockpit-wsinstance-https-factory.socket \
+ ${systemd_system_unitdir}/cockpit-wsinstance-https-factory@.service \
+ ${systemd_system_unitdir}/cockpit-wsinstance-https@.socket \
+ ${systemd_system_unitdir}/cockpit-wsinstance-https@.service \
+ ${systemd_system_unitdir}/system-cockpithttps.slice \
+ ${libdir}/tmpfiles.d/cockpit-tempfiles.conf \
+ ${sbindir}/remotectl \
+ ${libdir}/security/pam_ssh_add.so \
+ ${libdir}/security/pam_cockpit_cert.so \
+ ${libexecdir}/cockpit-ws \
+ ${libexecdir}/cockpit-wsinstance-factory \
+ ${libexecdir}/cockpit-tls \
+ ${libexecdir}/cockpit-session \
+ ${localstatedir}/lib/cockpit \
+ ${datadir}/cockpit/static \
+ ${datadir}/cockpit/branding \
+"
+CONFFILES_${PN}-ws += " \
+ ${sysconfdir}/issue.d/cockpit.issue \
+ ${sysconfdir}/motd.d/cockpit \
+"
+RDEPENDS_${PN}-ws += "openssl-bin"
+SYSTEMD_SERVICE_${PN}-ws = "cockpit.socket"
+
+FILES_${PN} += " \
+ ${datadir}/cockpit/base1 \
+ ${sysconfdir}/cockpit/machines.d \
+ ${datadir}/polkit-1/actions/org.cockpit-project.cockpit-bridge.policy \
+ ${datadir}/cockpit/ssh \
+ ${libexecdir}/cockpit-ssh \
+ ${datadir}/cockpit \
+ ${datadir}/metainfo/cockpit.appdata.xml \
+ ${datadir}/pixmaps/cockpit.png \
+"
+RDEPENDS_${PN} += "${PN}-bridge"
+
+do_install_append() {
+ pkgdatadir=${datadir}/cockpit
+
+ chmod 4750 ${D}${libexecdir}/cockpit-session
+
+ install -d "${D}${sysconfdir}/pam.d"
+ install -p -m 0644 ${WORKDIR}/cockpit.pam ${D}${sysconfdir}/pam.d/cockpit
+
+ # provided by firewalld
+ rm -rf ${D}${libdir}/firewalld
+}