Squashed 'import-layers/meta-raspberrypi/' content from commit 2745399
Change-Id: I8a89d81813dea98209d089ef500a403ea4da5d9d
git-subtree-dir: import-layers/meta-raspberrypi
git-subtree-split: 2745399f75d7564fcc586d0365ff73be47849d0e
Signed-off-by: Patrick Williams <patrick@stwcx.xyz>
diff --git a/import-layers/meta-raspberrypi/recipes-graphics/userland/userland_git.bb b/import-layers/meta-raspberrypi/recipes-graphics/userland/userland_git.bb
new file mode 100644
index 0000000..6e73ca7
--- /dev/null
+++ b/import-layers/meta-raspberrypi/recipes-graphics/userland/userland_git.bb
@@ -0,0 +1,73 @@
+DESCRIPTION = "This repository contains the source code for the ARM side \
+libraries used on Raspberry Pi. These typically are installed in /opt/vc/lib \
+and includes source for the ARM side code to interface to: EGL, mmal, GLESv2,\
+vcos, openmaxil, vchiq_arm, bcm_host, WFC, OpenVG."
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENCE;md5=0448d6488ef8cc380632b1569ee6d196"
+
+PR = "r5"
+
+PROVIDES = "virtual/libgles2 \
+ virtual/egl"
+
+RPROVIDES_${PN} += "libgles2 libgl"
+
+COMPATIBLE_MACHINE = "raspberrypi"
+
+SRCBRANCH = "master"
+SRCFORK = "raspberrypi"
+SRCREV = "0147f98bdd4fdc822d25d8a70cf5adc5adb89096"
+
+SRC_URI = "\
+ git://github.com/${SRCFORK}/userland.git;protocol=git;branch=${SRCBRANCH} \
+ file://0001-Allow-applications-to-set-next-resource-handle.patch \
+ file://0002-wayland-Add-support-for-the-Wayland-winsys.patch \
+ file://0003-wayland-Add-Wayland-example.patch \
+ file://0004-wayland-egl-Add-bcm_host-to-dependencies.patch \
+ file://0005-interface-remove-faulty-assert-to-make-weston-happy-.patch \
+ file://0006-zero-out-wl-buffers-in-egl_surface_free.patch \
+ file://0007-initialize-front-back-wayland-buffers.patch \
+ file://0008-Remove-RPC_FLUSH.patch \
+ file://0009-fix-cmake-dependency-race.patch \
+ file://0010-Fix-enum-conversion-warnings.patch \
+ file://0011-Fix-for-framerate-with-nested-composition.patch \
+ file://0012-build-shared-library-for-vchostif.patch \
+ file://0013-implement-buffer-wrapping-interface-for-dispmanx.patch \
+"
+S = "${WORKDIR}/git"
+
+inherit cmake pkgconfig
+
+EXTRA_OECMAKE = "-DCMAKE_BUILD_TYPE=Release -DCMAKE_EXE_LINKER_FLAGS='-Wl,--no-as-needed' \
+ -DVMCS_INSTALL_PREFIX=${exec_prefix} \
+"
+
+PACKAGECONFIG ?= "${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'wayland', '', d)}"
+
+PACKAGECONFIG[wayland] = "-DBUILD_WAYLAND=TRUE -DWAYLAND_SCANNER_EXECUTABLE:FILEPATH=${STAGING_BINDIR_NATIVE}/wayland-scanner,,wayland-native wayland"
+
+CFLAGS_append = " -fPIC"
+
+do_install_append () {
+ for f in `find ${D}${includedir}/interface/vcos/ -name "*.h"`; do
+ sed -i 's/include "vcos_platform.h"/include "pthreads\/vcos_platform.h"/g' ${f}
+ sed -i 's/include "vcos_futex_mutex.h"/include "pthreads\/vcos_futex_mutex.h"/g' ${f}
+ sed -i 's/include "vcos_platform_types.h"/include "pthreads\/vcos_platform_types.h"/g' ${f}
+ done
+}
+
+# Shared libs from userland package build aren't versioned, so we need
+# to force the .so files into the runtime package (and keep them
+# out of -dev package).
+FILES_SOLIBSDEV = ""
+INSANE_SKIP_${PN} += "dev-so"
+
+FILES_${PN} += " \
+ ${libdir}/*.so \
+ ${libdir}/plugins"
+FILES_${PN}-dev += "${includedir} \
+ ${prefix}/src"
+FILES_${PN}-doc += "${datadir}/install"
+FILES_${PN}-dbg += "${libdir}/plugins/.debug"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"