meta-openembedded: subtree update:19528ba2a6..ef1b17f4ef
Callaghan, Dan (1):
lmsensors: add a PACKAGECONFIG for sensord
Changqing Li (1):
ntp: fix package split wrongly when enabled usrmerge
Khem Raj (1):
remove spurious file
Nathan Rossi (3):
libeigen: Add native and nativesdk to BBCLASSEXTEND
python*-pyusb: Add native and nativesdk to BBCLASSEXTEND
python*-pyserial: Add native and nativesdk to BBCLASSEXTEND
Oleksandr Kravchuk (23):
babl: update to 0.1.62
znc: update to 1.7.4
zlog: update to 1.2.14
wipe: update to 0.24
upower: update to 0.99.11
python-pyobject: update to 3.34.0
python-pytoml: update to 0.1.21
python-cpuset: update to 1.6
libwebsockets: update to 3.2.0
libvpx: update to 1.8.1
libvdpau: update to 1.3
libmicrohttpd: update to 0.9.66
lcms: update to 2.9
libblockdev: update to 2.23
libbytesize: update to 2.1
iwd: update to 0.20
gsl: update to 2.6
gflags: update to 2.2.2
digitemp: update to 3.7.2
catch2: update to 2.9.2
botan: update to 2.11.0
agent-proxy: update to 1.97
ceres-solver: fix package version
Paul Eggleton (1):
mosquitto: update to 1.6.5
Scott Ellis (1):
wireguard: Upgrade 20190905 to 20190913
Trevor Gamblin (1):
openjpeg: upgrade 2.3.0 -> 2.3.1
Yi Zhao (1):
samba: upgrade 4.10.7 -> 4.10.8
Zang Ruochen (2):
python-dbus: upgrade 1.2.10 -> 1.2.12
python-pluggy: upgrade 0.12.0 -> 0.13.0
Zheng Ruoqin (1):
xrdp: 0.9.4 -> 0.9.11
Change-Id: I3152060569cc5af7f7950c7037f25f54191d20a9
Signed-off-by: Brad Bishop <bradleyb@fuzziesquirrel.com>
diff --git a/meta-openembedded/meta-networking/recipes-connectivity/mosquitto/mosquitto_1.6.5.bb b/meta-openembedded/meta-networking/recipes-connectivity/mosquitto/mosquitto_1.6.5.bb
new file mode 100644
index 0000000..4bb0720
--- /dev/null
+++ b/meta-openembedded/meta-networking/recipes-connectivity/mosquitto/mosquitto_1.6.5.bb
@@ -0,0 +1,98 @@
+SUMMARY = "Open source MQTT implementation"
+DESCRIPTION = "Mosquitto is an open source (Eclipse licensed) message broker \
+that implements the MQ Telemetry Transport protocol version 3.1, 3.1.1 and \
+5, providing both an MQTT broker and several command-line clients. MQTT \
+provides a lightweight method of carrying out messaging using a \
+publish/subscribe model. "
+HOMEPAGE = "http://mosquitto.org/"
+SECTION = "console/network"
+LICENSE = "EPL-1.0 | EDL-1.0"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=62ddc846179e908dc0c8efec4a42ef20 \
+ file://edl-v10;md5=c09f121939f063aeb5235972be8c722c \
+ file://epl-v10;md5=8d383c379e91d20ba18a52c3e7d3a979 \
+ file://notice.html;md5=a00d6f9ab542be7babc2d8b80d5d2a4c \
+"
+DEPENDS = "uthash"
+
+SRC_URI = "http://mosquitto.org/files/source/mosquitto-${PV}.tar.gz \
+ file://mosquitto.init \
+"
+
+SRC_URI[md5sum] = "12a1bd274d5ec454649a06c1bf65d802"
+SRC_URI[sha256sum] = "bc71b38b5a26fc7cc772853e5607c657868db9f9a6d2b15e2b677649a0f85d20"
+
+inherit systemd update-rc.d useradd
+
+PACKAGECONFIG ??= "ssl uuid \
+ ${@bb.utils.filter('DISTRO_FEATURES','systemd', d)} \
+ "
+
+PACKAGECONFIG[dns-srv] = "WITH_SRV=yes,WITH_SRV=no,c-ares"
+PACKAGECONFIG[ssl] = "WITH_TLS=yes WITH_TLS_PSK=yes,WITH_TLS=no WITH_TLS_PSK=no,openssl"
+PACKAGECONFIG[uuid] = "WITH_UUID=yes,WITH_UUID=no,util-linux"
+PACKAGECONFIG[systemd] = "WITH_SYSTEMD=yes,WITH_SYSTEMD=no,systemd"
+PACKAGECONFIG[websockets] = "WITH_WEBSOCKETS=yes,WITH_WEBSOCKETS=no,libwebsockets"
+
+EXTRA_OEMAKE = " \
+ prefix=${prefix} \
+ mandir=${mandir} \
+ localedir=${localedir} \
+ ${PACKAGECONFIG_CONFARGS} \
+ STRIP=/bin/true \
+ WITH_DOCS=no \
+ WITH_BUNDLED_DEPS=no \
+"
+
+export LIB_SUFFIX = "${@d.getVar('baselib').replace('lib', '')}"
+
+do_install() {
+ oe_runmake 'DESTDIR=${D}' install
+
+ install -d ${D}${systemd_unitdir}/system/
+ install -m 0644 ${S}/service/systemd/mosquitto.service.notify ${D}${systemd_unitdir}/system/mosquitto.service
+
+ install -d ${D}${sysconfdir}/mosquitto
+ install -m 0644 ${D}${sysconfdir}/mosquitto/mosquitto.conf.example \
+ ${D}${sysconfdir}/mosquitto/mosquitto.conf
+
+ install -d ${D}${sysconfdir}/init.d/
+ install -m 0755 ${WORKDIR}/mosquitto.init ${D}${sysconfdir}/init.d/mosquitto
+ sed -i -e 's,@SBINDIR@,${sbindir},g' \
+ -e 's,@BASE_SBINDIR@,${base_sbindir},g' \
+ -e 's,@LOCALSTATEDIR@,${localstatedir},g' \
+ -e 's,@SYSCONFDIR@,${sysconfdir},g' \
+ ${D}${sysconfdir}/init.d/mosquitto
+}
+
+PACKAGES += "libmosquitto1 libmosquittopp1 ${PN}-clients"
+
+PACKAGE_BEFORE_PN = "${PN}-examples"
+
+FILES_${PN} = "${sbindir}/mosquitto \
+ ${bindir}/mosquitto_passwd \
+ ${sysconfdir}/mosquitto \
+ ${sysconfdir}/init.d \
+ ${systemd_unitdir}/system/mosquitto.service \
+"
+
+CONFFILES_${PN} += "${sysconfdir}/mosquitto/mosquitto.conf"
+
+FILES_libmosquitto1 = "${libdir}/libmosquitto.so.1"
+
+FILES_libmosquittopp1 = "${libdir}/libmosquittopp.so.1"
+
+FILES_${PN}-clients = "${bindir}/mosquitto_pub \
+ ${bindir}/mosquitto_sub \
+ ${bindir}/mosquitto_rr \
+"
+
+FILES_${PN}-examples = "${sysconfdir}/mosquitto/*.example"
+
+SYSTEMD_SERVICE_${PN} = "mosquitto.service"
+
+INITSCRIPT_NAME = "mosquitto"
+INITSCRIPT_PARAMS = "defaults 30"
+
+USERADD_PACKAGES = "${PN}"
+USERADD_PARAM_${PN} = "--system --no-create-home --shell /bin/false \
+ --user-group mosquitto"