| SUMMARY = "GStreamer 1.0 multimedia framework" |
| DESCRIPTION = "GStreamer is a multimedia framework for encoding and decoding video and sound. \ |
| It supports a wide range of formats including mp3, ogg, avi, mpeg and quicktime." |
| HOMEPAGE = "http://gstreamer.freedesktop.org/" |
| BUGTRACKER = "https://bugzilla.gnome.org/enter_bug.cgi?product=Gstreamer" |
| SECTION = "multimedia" |
| LICENSE = "LGPLv2+" |
| |
| DEPENDS = "glib-2.0 glib-2.0-native libxml2 bison-native flex-native" |
| |
| inherit meson pkgconfig gettext upstream-version-is-even gobject-introspection ptest-gnome |
| |
| LIC_FILES_CHKSUM = "file://COPYING;md5=6762ed442b3822387a51c92d928ead0d \ |
| file://gst/gst.h;beginline=1;endline=21;md5=e059138481205ee2c6fc1c079c016d0d" |
| |
| S = "${WORKDIR}/gstreamer-${PV}" |
| |
| SRC_URI = "https://gstreamer.freedesktop.org/src/gstreamer/gstreamer-${PV}.tar.xz \ |
| file://run-ptest \ |
| file://0001-gst-gstpluginloader.c-when-env-var-is-set-do-not-fal.patch \ |
| file://0002-Remove-unused-valgrind-detection.patch \ |
| file://0003-tests-seek-Don-t-use-too-strict-timeout-for-validati.patch \ |
| file://0004-tests-respect-the-idententaion-used-in-meson.patch \ |
| file://0005-tests-add-support-for-install-the-tests.patch \ |
| file://0006-tests-use-a-dictionaries-for-environment.patch \ |
| file://0007-tests-install-the-environment-for-installed_tests.patch \ |
| " |
| SRC_URI[sha256sum] = "55862232a63459bbf56abebde3085ca9aec211b478e891dacea4d6df8cafe80a" |
| |
| PACKAGECONFIG ??= "${@bb.utils.contains('PTEST_ENABLED', '1', 'tests', '', d)} \ |
| check \ |
| debug \ |
| tools" |
| |
| PACKAGECONFIG[debug] = "-Dgst_debug=true,-Dgst_debug=false" |
| PACKAGECONFIG[tracer-hooks] = "-Dtracer_hooks=true,-Dtracer_hooks=false" |
| PACKAGECONFIG[coretracers] = "-Dcoretracers=enabled,-Dcoretracers=disabled" |
| PACKAGECONFIG[check] = "-Dcheck=enabled,-Dcheck=disabled" |
| PACKAGECONFIG[tests] = "-Dtests=enabled -Dinstalled-tests=true,-Dtests=disabled -Dinstalled-tests=false" |
| PACKAGECONFIG[unwind] = "-Dlibunwind=enabled,-Dlibunwind=disabled,libunwind" |
| PACKAGECONFIG[dw] = "-Dlibdw=enabled,-Dlibdw=disabled,elfutils" |
| PACKAGECONFIG[bash-completion] = "-Dbash-completion=enabled,-Dbash-completion=disabled,bash-completion" |
| PACKAGECONFIG[tools] = "-Dtools=enabled,-Dtools=disabled" |
| PACKAGECONFIG[setcap] = "-Dptp-helper-permissions=capabilities,,libcap libcap-native" |
| |
| # TODO: put this in a gettext.bbclass patch |
| def gettext_oemeson(d): |
| if d.getVar('USE_NLS') == 'no': |
| return '-Dnls=disabled' |
| # Remove the NLS bits if USE_NLS is no or INHIBIT_DEFAULT_DEPS is set |
| if d.getVar('INHIBIT_DEFAULT_DEPS') and not oe.utils.inherits(d, 'cross-canadian'): |
| return '-Dnls=disabled' |
| return '-Dnls=enabled' |
| |
| EXTRA_OEMESON += " \ |
| -Ddoc=disabled \ |
| -Dexamples=disabled \ |
| -Ddbghelp=disabled \ |
| ${@gettext_oemeson(d)} \ |
| " |
| |
| GIR_MESON_ENABLE_FLAG = "enabled" |
| GIR_MESON_DISABLE_FLAG = "disabled" |
| |
| PACKAGES += "${PN}-bash-completion" |
| |
| # Add the core element plugins to the main package |
| FILES:${PN} += "${libdir}/gstreamer-1.0/*.so" |
| FILES:${PN}-dev += "${libdir}/gstreamer-1.0/*.a ${libdir}/gstreamer-1.0/include" |
| FILES:${PN}-bash-completion += "${datadir}/bash-completion/completions/ ${datadir}/bash-completion/helpers/gst*" |
| FILES:${PN}-dbg += "${datadir}/gdb ${datadir}/gstreamer-1.0/gdb" |
| |
| CVE_PRODUCT = "gstreamer" |
| |
| PTEST_BUILD_HOST_FILES = "" |