| Brad Bishop | 26bdd44 | 2019-08-16 17:08:17 -0400 | [diff] [blame] | 1 | SUMMARY = "Simple DirectMedia Layer" |
| 2 | DESCRIPTION = "Simple DirectMedia Layer is a cross-platform multimedia \ |
| 3 | library designed to provide low level access to audio, keyboard, mouse, \ |
| 4 | joystick, 3D hardware via OpenGL, and 2D video framebuffer." |
| 5 | HOMEPAGE = "http://www.libsdl.org" |
| 6 | BUGTRACKER = "http://bugzilla.libsdl.org/" |
| 7 | |
| 8 | SECTION = "libs" |
| 9 | |
| 10 | LICENSE = "LGPLv2.1" |
| 11 | LIC_FILES_CHKSUM = "file://COPYING;md5=27818cd7fd83877a8e3ef82b82798ef4" |
| 12 | |
| 13 | PROVIDES = "virtual/libsdl" |
| 14 | |
| 15 | PR = "r3" |
| 16 | |
| 17 | SRC_URI = "http://www.libsdl.org/release/SDL-${PV}.tar.gz \ |
| 18 | file://libsdl-1.2.15-xdata32.patch \ |
| 19 | file://pkgconfig.patch \ |
| 20 | file://0001-build-Pass-tag-CC-explictly-when-using-libtool.patch \ |
| 21 | file://CVE-2019-7577.patch \ |
| 22 | file://CVE-2019-7574.patch \ |
| 23 | file://CVE-2019-7572.patch \ |
| 24 | file://CVE-2019-7578.patch \ |
| 25 | file://CVE-2019-7575.patch \ |
| 26 | file://CVE-2019-7635.patch \ |
| 27 | file://CVE-2019-7637.patch \ |
| 28 | file://CVE-2019-7638.patch \ |
| 29 | file://CVE-2019-7576.patch \ |
| 30 | " |
| 31 | |
| 32 | UPSTREAM_CHECK_REGEX = "SDL-(?P<pver>\d+(\.\d+)+)\.tar" |
| 33 | |
| 34 | S = "${WORKDIR}/SDL-${PV}" |
| 35 | |
| 36 | SRC_URI[md5sum] = "9d96df8417572a2afb781a7c4c811a85" |
| 37 | SRC_URI[sha256sum] = "d6d316a793e5e348155f0dd93b979798933fb98aa1edebcc108829d6474aad00" |
| 38 | |
| 39 | BINCONFIG = "${bindir}/sdl-config" |
| 40 | |
| 41 | inherit autotools lib_package binconfig-disabled pkgconfig |
| 42 | |
| 43 | CVE_PRODUCT = "simple_directmedia_layer sdl" |
| 44 | |
| 45 | EXTRA_OECONF = "--disable-static --enable-cdrom --enable-threads --enable-timers \ |
| 46 | --enable-file --disable-oss --disable-esd --disable-arts \ |
| 47 | --disable-diskaudio --disable-nas \ |
| 48 | --disable-mintaudio --disable-nasm --disable-video-dga \ |
| 49 | --disable-video-fbcon --disable-video-ps2gs --disable-video-ps3 \ |
| 50 | --disable-xbios --disable-gem --disable-video-dummy \ |
| 51 | --enable-input-events --enable-pthreads \ |
| 52 | --disable-video-svga \ |
| 53 | --disable-video-picogui --disable-video-qtopia --enable-sdl-dlopen \ |
| 54 | --disable-rpath" |
| 55 | |
| 56 | PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'alsa directfb pulseaudio x11', d)} \ |
| 57 | ${@bb.utils.contains('DISTRO_FEATURES', 'x11 opengl', 'opengl', '', d)}" |
| 58 | PACKAGECONFIG_class-native = "x11" |
| 59 | PACKAGECONFIG_class-nativesdk = "${@bb.utils.filter('DISTRO_FEATURES', 'x11', d)}" |
| 60 | |
| 61 | PACKAGECONFIG[alsa] = "--enable-alsa --disable-alsatest,--disable-alsa,alsa-lib" |
| 62 | PACKAGECONFIG[pulseaudio] = "--enable-pulseaudio,--disable-pulseaudio,pulseaudio" |
| 63 | PACKAGECONFIG[tslib] = "--enable-input-tslib, --disable-input-tslib, tslib" |
| 64 | PACKAGECONFIG[directfb] = "--enable-video-directfb, --disable-video-directfb, directfb" |
| 65 | PACKAGECONFIG[opengl] = "--enable-video-opengl, --disable-video-opengl, virtual/libgl libglu" |
| 66 | PACKAGECONFIG[x11] = "--enable-video-x11 --disable-x11-shared, --disable-video-x11, virtual/libx11 libxext libxrandr libxrender" |
| 67 | |
| 68 | # The following two options should only enabled with mingw support |
| 69 | PACKAGECONFIG[stdio-redirect] = "--enable-stdio-redirect,--disable-stdio-redirect" |
| 70 | PACKAGECONFIG[directx] = "--enable-directx,--disable-directx" |
| 71 | |
| 72 | EXTRA_AUTORECONF += "--include=acinclude --exclude=autoheader" |
| 73 | |
| 74 | do_configure_prepend() { |
| 75 | # Remove old libtool macros. |
| 76 | MACROS="libtool.m4 lt~obsolete.m4 ltoptions.m4 ltsugar.m4 ltversion.m4" |
| 77 | for i in ${MACROS}; do |
| 78 | rm -f ${S}/acinclude/$i |
| 79 | done |
| 80 | export SYSROOT=$PKG_CONFIG_SYSROOT_DIR |
| 81 | } |
| 82 | |
| 83 | BBCLASSEXTEND = "native nativesdk" |