| Andrew Geissler | 82c905d | 2020-04-13 13:39:40 -0500 | [diff] [blame] | 1 | SUMMARY = "Cron daemon for executing programs at set times" |
| 2 | DESCRIPTION = "Cronie contains the standard UNIX daemon crond that runs \ |
| 3 | specified programs at scheduled times and related tools. It is based on the \ |
| 4 | original cron and has security and configuration enhancements like the \ |
| 5 | ability to use pam and SELinux." |
| 6 | HOMEPAGE = "https://github.com/cronie-crond/cronie/" |
| 7 | BUGTRACKER = "https://bugzilla.redhat.com" |
| 8 | |
| 9 | # Internet Systems Consortium License |
| 10 | LICENSE = "ISC & BSD-3-Clause & BSD-2-Clause & GPLv2+" |
| 11 | LIC_FILES_CHKSUM = "file://COPYING;md5=dd2a592170760e1386c769e1043b3722 \ |
| 12 | file://src/cron.c;endline=20;md5=b425c334265026177128353a142633b4 \ |
| 13 | file://src/popen.c;beginline=3;endline=31;md5=edd50742d8def712e9472dba353668a9" |
| 14 | |
| 15 | SECTION = "utils" |
| 16 | |
| 17 | UPSTREAM_CHECK_URI = "https://github.com/cronie-crond/${BPN}/releases/" |
| 18 | |
| 19 | SRC_URI = "https://github.com/cronie-crond/cronie/releases/download/cronie-${PV}/cronie-${PV}.tar.gz \ |
| 20 | file://crond.init \ |
| 21 | file://crontab \ |
| 22 | file://crond.service \ |
| 23 | ${@bb.utils.contains('DISTRO_FEATURES', 'pam', '${PAM_SRC_URI}', '', d)}" |
| 24 | |
| 25 | PAM_SRC_URI = "file://crond_pam_config.patch" |
| 26 | PAM_DEPS = "libpam libpam-runtime pam-plugin-access pam-plugin-loginuid" |
| 27 | |
| 28 | SRC_URI[md5sum] = "351a37d0b5bd0144816724b4482747ad" |
| 29 | SRC_URI[sha256sum] = "be34c79505e5544323281854744b9955ff16b160ee569f9df7c0dddae5720eac" |
| 30 | |
| 31 | inherit autotools update-rc.d useradd systemd |
| 32 | |
| 33 | PACKAGECONFIG ?= "${@bb.utils.filter('DISTRO_FEATURES', 'pam', d)}" |
| 34 | |
| 35 | PACKAGECONFIG[audit] = "--with-audit,--without-audit,audit," |
| 36 | PACKAGECONFIG[pam] = "--with-pam,--without-pam,libpam,${PAM_DEPS}" |
| 37 | PACKAGECONFIG[anacron] = "--enable-anacron,--disable-anacron,anacron" |
| 38 | |
| 39 | INITSCRIPT_NAME = "crond" |
| 40 | INITSCRIPT_PARAMS = "start 90 2 3 4 5 . stop 60 0 1 6 ." |
| 41 | |
| 42 | USERADD_PACKAGES = "${PN}" |
| 43 | GROUPADD_PARAM_${PN} = "--system crontab" |
| 44 | |
| 45 | SYSTEMD_SERVICE_${PN} = "crond.service" |
| 46 | |
| 47 | do_install_append () { |
| 48 | install -d ${D}${sysconfdir}/sysconfig/ |
| 49 | install -d ${D}${sysconfdir}/init.d/ |
| 50 | install -m 0644 ${S}/crond.sysconfig ${D}${sysconfdir}/sysconfig/crond |
| 51 | install -m 0755 ${WORKDIR}/crond.init ${D}${sysconfdir}/init.d/crond |
| 52 | |
| 53 | # install systemd unit files |
| 54 | install -d ${D}${systemd_unitdir}/system |
| 55 | install -m 0644 ${WORKDIR}/crond.service ${D}${systemd_unitdir}/system |
| 56 | sed -i -e 's,@BASE_BINDIR@,${base_bindir},g' \ |
| 57 | -e 's,@SBINDIR@,${sbindir},g' \ |
| 58 | ${D}${systemd_unitdir}/system/crond.service |
| 59 | |
| 60 | # below are necessary for a complete cron environment |
| 61 | install -d ${D}${localstatedir}/spool/cron |
| 62 | install -m 0755 ${WORKDIR}/crontab ${D}${sysconfdir}/ |
| 63 | mkdir -p ${D}${sysconfdir}/cron.d |
| 64 | mkdir -p ${D}${sysconfdir}/cron.hourly |
| 65 | mkdir -p ${D}${sysconfdir}/cron.daily |
| 66 | mkdir -p ${D}${sysconfdir}/cron.weekly |
| 67 | mkdir -p ${D}${sysconfdir}/cron.monthly |
| 68 | touch ${D}${sysconfdir}/cron.deny |
| 69 | |
| 70 | # below setting is necessary to allow normal user using crontab |
| 71 | |
| 72 | # setgid for crontab binary |
| 73 | chown root:crontab ${D}${bindir}/crontab |
| 74 | chmod 2755 ${D}${bindir}/crontab |
| 75 | |
| 76 | # allow 'crontab' group write to /var/spool/cron |
| 77 | chown root:crontab ${D}${localstatedir}/spool/cron |
| 78 | chmod 770 ${D}${localstatedir}/spool/cron |
| 79 | |
| 80 | chmod 600 ${D}${sysconfdir}/crontab |
| 81 | } |
| 82 | |
| 83 | FILES_${PN} += "${sysconfdir}/cron*" |
| 84 | CONFFILES_${PN} += "${sysconfdir}/crontab" |