| Brad Bishop | 316dfdd | 2018-06-25 12:45:53 -0400 | [diff] [blame] | 1 | SUMMARY = "ALSA sound utilities" |
| 2 | HOMEPAGE = "http://www.alsa-project.org" |
| 3 | BUGTRACKER = "http://alsa-project.org/main/index.php/Bug_Tracking" |
| 4 | SECTION = "console/utils" |
| 5 | LICENSE = "GPLv2+" |
| 6 | LIC_FILES_CHKSUM = "file://COPYING;md5=59530bdf33659b29e73d4adb9f9f6552 \ |
| 7 | file://alsactl/utils.c;beginline=1;endline=20;md5=fe9526b055e246b5558809a5ae25c0b9" |
| 8 | DEPENDS = "alsa-lib ncurses libsamplerate0" |
| 9 | |
| 10 | PACKAGECONFIG ??= "udev" |
| 11 | |
| 12 | # alsabat can be built also without fftw support (with reduced functionality). |
| 13 | # It would be better to always enable alsabat, but provide an option for |
| 14 | # enabling/disabling fftw. The configure script doesn't support that, however |
| 15 | # (at least in any obvious way), so for now we only support alsabat with fftw |
| 16 | # or no alsabat at all. |
| 17 | PACKAGECONFIG[bat] = "--enable-bat,--disable-bat,fftwf" |
| 18 | |
| 19 | PACKAGECONFIG[udev] = "--with-udev-rules-dir=`pkg-config --variable=udevdir udev`/rules.d,--with-udev-rules-dir=/unwanted/rules.d,udev" |
| 20 | PACKAGECONFIG[manpages] = "--enable-xmlto, --disable-xmlto, xmlto-native docbook-xml-dtd4-native docbook-xsl-stylesheets-native" |
| 21 | |
| 22 | SRC_URI = "ftp://ftp.alsa-project.org/pub/utils/alsa-utils-${PV}.tar.bz2 \ |
| 23 | file://0001-alsactl-don-t-let-systemd-unit-restore-the-volume-wh.patch \ |
| 24 | " |
| 25 | |
| 26 | SRC_URI[md5sum] = "dfe6ea147a5e07a056919591c2f5dac3" |
| 27 | SRC_URI[sha256sum] = "320bd285e91db6e7fd7db3c9ec6f55b02f35449ff273c7844780ac6a5a3de2e8" |
| 28 | |
| 29 | # On build machines with python-docutils (not python3-docutils !!) installed |
| 30 | # rst2man (not rst2man.py) is detected and compile fails with |
| 31 | # | make[1]: *** No rule to make target 'alsaucm.1', needed by 'all-am'. Stop. |
| 32 | # Avoid this by disabling expicitly |
| 33 | EXTRA_OECONF = "--disable-rst2man" |
| 34 | |
| 35 | inherit autotools gettext pkgconfig manpages |
| 36 | |
| 37 | # This are all packages that we need to make. Also, the now empty alsa-utils |
| 38 | # ipk depends on them. |
| 39 | |
| 40 | ALSA_UTILS_PKGS = "\ |
| 41 | ${@bb.utils.contains('PACKAGECONFIG', 'bat', 'alsa-utils-alsabat', '', d)} \ |
| 42 | alsa-utils-alsamixer \ |
| 43 | alsa-utils-alsatplg \ |
| 44 | alsa-utils-midi \ |
| 45 | alsa-utils-aplay \ |
| 46 | alsa-utils-amixer \ |
| 47 | alsa-utils-aconnect \ |
| 48 | alsa-utils-iecset \ |
| 49 | alsa-utils-speakertest \ |
| 50 | alsa-utils-aseqnet \ |
| 51 | alsa-utils-aseqdump \ |
| 52 | alsa-utils-alsactl \ |
| 53 | alsa-utils-alsaloop \ |
| 54 | alsa-utils-alsaucm \ |
| 55 | " |
| 56 | |
| 57 | PACKAGES += "${ALSA_UTILS_PKGS}" |
| 58 | RDEPENDS_${PN} += "${ALSA_UTILS_PKGS}" |
| 59 | |
| 60 | FILES_${PN} = "" |
| 61 | FILES_alsa-utils-alsabat = "${bindir}/alsabat" |
| 62 | FILES_alsa-utils-alsatplg = "${bindir}/alsatplg" |
| 63 | FILES_alsa-utils-aplay = "${bindir}/aplay ${bindir}/arecord" |
| 64 | FILES_alsa-utils-amixer = "${bindir}/amixer" |
| 65 | FILES_alsa-utils-alsamixer = "${bindir}/alsamixer" |
| 66 | FILES_alsa-utils-speakertest = "${bindir}/speaker-test ${datadir}/sounds/alsa/ ${datadir}/alsa/speaker-test/" |
| 67 | FILES_alsa-utils-midi = "${bindir}/aplaymidi ${bindir}/arecordmidi ${bindir}/amidi" |
| 68 | FILES_alsa-utils-aconnect = "${bindir}/aconnect" |
| 69 | FILES_alsa-utils-aseqnet = "${bindir}/aseqnet" |
| 70 | FILES_alsa-utils-iecset = "${bindir}/iecset" |
| 71 | FILES_alsa-utils-alsactl = "${sbindir}/alsactl */udev/rules.d */*/udev/rules.d ${systemd_unitdir} ${localstatedir}/lib/alsa ${datadir}/alsa/init/" |
| 72 | FILES_alsa-utils-aseqdump = "${bindir}/aseqdump" |
| 73 | FILES_alsa-utils-alsaloop = "${bindir}/alsaloop" |
| 74 | FILES_alsa-utils-alsaucm = "${bindir}/alsaucm" |
| 75 | |
| 76 | SUMMARY_alsa-utils-alsabat = "Command-line sound tester for ALSA sound card driver" |
| 77 | SUMMARY_alsa-utils-alsatplg = "Converts topology text files into binary format for kernel" |
| 78 | SUMMARY_alsa-utils-aplay = "Play (and record) sound files using ALSA" |
| 79 | SUMMARY_alsa-utils-amixer = "Command-line control for ALSA mixer and settings" |
| 80 | SUMMARY_alsa-utils-alsamixer = "ncurses-based control for ALSA mixer and settings" |
| 81 | SUMMARY_alsa-utils-speakertest = "ALSA surround speaker test utility" |
| 82 | SUMMARY_alsa-utils-midi = "Miscellaneous MIDI utilities for ALSA" |
| 83 | SUMMARY_alsa-utils-aconnect = "ALSA sequencer connection manager" |
| 84 | SUMMARY_alsa-utils-aseqnet = "Network client/server for ALSA sequencer" |
| 85 | SUMMARY_alsa-utils-iecset = "ALSA utility for setting/showing IEC958 (S/PDIF) status bits" |
| 86 | SUMMARY_alsa-utils-alsactl = "Saves/restores ALSA-settings in /etc/asound.state" |
| 87 | SUMMARY_alsa-utils-aseqdump = "Shows the events received at an ALSA sequencer port" |
| 88 | SUMMARY_alsa-utils-alsaloop = "ALSA PCM loopback utility" |
| 89 | SUMMARY_alsa-utils-alsaucm = "ALSA Use Case Manager" |
| 90 | |
| 91 | RRECOMMENDS_alsa-utils-alsactl = "alsa-states" |
| 92 | |
| 93 | ALLOW_EMPTY_alsa-utils = "1" |
| 94 | |
| 95 | do_install() { |
| 96 | autotools_do_install |
| 97 | |
| 98 | # We don't ship this here because it requires a dependency on bash. |
| 99 | # See alsa-utils-scripts_${PV}.bb |
| 100 | rm ${D}${sbindir}/alsaconf |
| 101 | rm ${D}${sbindir}/alsa-info.sh |
| 102 | rm -f ${D}${sbindir}/alsabat-test.sh |
| 103 | |
| 104 | # If udev is disabled, we told configure to install the rules |
| 105 | # in /unwanted, so we can remove them now. If udev is enabled, |
| 106 | # then /unwanted won't exist and this will have no effect. |
| 107 | rm -rf ${D}/unwanted |
| 108 | } |