| Patrick Williams | 92b42cb | 2022-09-03 06:53:57 -0500 | [diff] [blame] | 1 | SUMMARY = "Audio decoder for MPEG-1 Layer 1/2/3" |
| 2 | DESCRIPTION = "The core of mpg123 is an MPEG-1 Layer 1/2/3 decoding library, which can be used by other programs. \ |
| 3 | mpg123 also comes with a command-line tool which can playback using ALSA, PulseAudio, OSS, and several other APIs, \ |
| 4 | and also can write the decoded audio to WAV." |
| 5 | HOMEPAGE = "http://mpg123.de/" |
| 6 | BUGTRACKER = "http://sourceforge.net/p/mpg123/bugs/" |
| 7 | SECTION = "multimedia" |
| 8 | |
| 9 | LICENSE = "LGPL-2.1-only" |
| 10 | LIC_FILES_CHKSUM = "file://COPYING;md5=e7b9c15fcfb986abb4cc5e8400a24169" |
| 11 | |
| 12 | SRC_URI = "https://www.mpg123.de/download/${BP}.tar.bz2" |
| Patrick Williams | 864cc43 | 2023-02-09 14:54:44 -0600 | [diff] [blame] | 13 | SRC_URI[sha256sum] = "b17f22905e31f43b6b401dfdf6a71ed11bb7d056f68db449d70b9f9ae839c7de" |
| Patrick Williams | 92b42cb | 2022-09-03 06:53:57 -0500 | [diff] [blame] | 14 | |
| 15 | UPSTREAM_CHECK_REGEX = "mpg123-(?P<pver>\d+(\.\d+)+)\.tar" |
| 16 | |
| 17 | inherit autotools pkgconfig |
| 18 | |
| 19 | # The options should be mutually exclusive for configuration script. |
| 20 | # If both alsa and pulseaudio are specified (as in the default distro features) |
| 21 | # pulseaudio takes precedence. |
| 22 | PACKAGECONFIG_ALSA = "${@bb.utils.filter('DISTRO_FEATURES', 'alsa', d)}" |
| 23 | PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'pulseaudio', 'pulseaudio', '${PACKAGECONFIG_ALSA}', d)}" |
| 24 | |
| 25 | PACKAGECONFIG[alsa] = "--with-default-audio=alsa,,alsa-lib" |
| 26 | PACKAGECONFIG[esd] = ",,esound" |
| 27 | PACKAGECONFIG[jack] = ",,jack" |
| 28 | PACKAGECONFIG[openal] = ",,openal-soft" |
| 29 | PACKAGECONFIG[portaudio] = ",,portaudio-v19" |
| 30 | PACKAGECONFIG[pulseaudio] = "--with-default-audio=pulse,,pulseaudio" |
| 31 | PACKAGECONFIG[sdl] = ",,libsdl2" |
| 32 | |
| 33 | # Following are possible sound output modules: |
| 34 | # alsa arts coreaudio dummy esd jack nas openal os2 oss portaudio pulse sdl sndio sun tinyalsa win32 win32_wasapi |
| 35 | AUDIOMODS += "${@bb.utils.filter('PACKAGECONFIG', 'alsa esd jack openal portaudio sdl', d)}" |
| 36 | AUDIOMODS += "${@bb.utils.contains('PACKAGECONFIG', 'pulseaudio', 'pulse', '', d)}" |
| 37 | |
| 38 | EXTRA_OECONF = " \ |
| 39 | --enable-shared \ |
| Andrew Geissler | 517393d | 2023-01-13 08:55:19 -0600 | [diff] [blame] | 40 | --enable-largefile \ |
| 41 | --disable-lfs-alias \ |
| Patrick Williams | 92b42cb | 2022-09-03 06:53:57 -0500 | [diff] [blame] | 42 | --with-audio='${AUDIOMODS}' \ |
| 43 | ${@bb.utils.contains('TUNE_FEATURES', 'neon', '--with-cpu=neon', '', d)} \ |
| 44 | ${@bb.utils.contains('TUNE_FEATURES', 'altivec', '--with-cpu=altivec', '', d)} \ |
| 45 | ${@bb.utils.contains('TARGET_FPU', 'soft', '--with-cpu=generic_nofpu', '', d)} \ |
| 46 | " |
| 47 | # Fails to build with thumb-1 (qemuarm) |
| 48 | #| {standard input}: Assembler messages: |
| 49 | #| {standard input}:47: Error: selected processor does not support Thumb mode `smull r5,r6,r7,r4' |
| 50 | #| {standard input}:48: Error: shifts in CMP/MOV instructions are only supported in unified syntax -- `mov r5,r5,lsr#24' |
| 51 | #... |
| 52 | #| make[3]: *** [equalizer.lo] Error 1 |
| 53 | ARM_INSTRUCTION_SET:armv4 = "arm" |
| 54 | ARM_INSTRUCTION_SET:armv5 = "arm" |