| Brad Bishop | 1932369 | 2019-04-05 15:28:33 -0400 | [diff] [blame] | 1 | SUMMARY = "Advanced tools for certain ALSA sound card drivers" |
| 2 | HOMEPAGE = "http://www.alsa-project.org" |
| 3 | BUGTRACKER = "http://alsa-project.org/main/index.php/Bug_Tracking" |
| 4 | SECTION = "console/utils" |
| 5 | LICENSE = "GPLv2 & LGPLv2+" |
| 6 | DEPENDS = "alsa-lib" |
| 7 | |
| 8 | LIC_FILES_CHKSUM = "file://hdsploader/COPYING;md5=59530bdf33659b29e73d4adb9f9f6552 \ |
| 9 | file://ld10k1/COPYING.LIB;md5=a916467b91076e631dd8edb7424769c7 \ |
| 10 | " |
| 11 | |
| 12 | SRC_URI = "https://www.alsa-project.org/files/pub/tools/${BP}.tar.bz2" |
| 13 | |
| Andrew Geissler | 4ed12e1 | 2020-06-05 18:00:41 -0500 | [diff] [blame] | 14 | SRC_URI[md5sum] = "4e6187d2c3a8c73a9d75d66a72faed27" |
| 15 | SRC_URI[sha256sum] = "bfd3c7aae1289269605d3da02279159b10e3dabdd31e658cbceaa30170957349" |
| Brad Bishop | 1932369 | 2019-04-05 15:28:33 -0400 | [diff] [blame] | 16 | |
| 17 | inherit autotools-brokensep pkgconfig |
| 18 | # brokensep as as10k1 (and probably more) fail out of tree |
| 19 | CLEANBROKEN = "1" |
| 20 | |
| 21 | # Here we use PACKAGECONFIG options to pick which directories we configure/build. |
| 22 | # Remember on upgrades to check that no new tools have been added. |
| 23 | PACKAGECONFIG ??= "as10k1 hdajacksensetest hda-verb hdsploader ld10k1 mixartloader pcxhrloader \ |
| 24 | sb16_csp seq--sbiload sscape_ctl us428control usx2yloader vxloader \ |
| Brad Bishop | 1932369 | 2019-04-05 15:28:33 -0400 | [diff] [blame] | 25 | ${@bb.utils.contains_any('DISTRO_FEATURES', '${GTK3DISTROFEATURES}', 'hdajackretask', '', d)} \ |
| 26 | " |
| 27 | |
| 28 | PACKAGECONFIG[as10k1] = "" |
| 29 | PACKAGECONFIG[echomixer] = ",,gtk+" |
| 30 | PACKAGECONFIG[envy24control] = ",,gtk+" |
| 31 | PACKAGECONFIG[hda-verb] = "" |
| 32 | PACKAGECONFIG[hdajackretask] = ",,gtk+3" |
| 33 | PACKAGECONFIG[hdajacksensetest] = ",,glib-2.0" |
| 34 | PACKAGECONFIG[hdspconf] = ",,fltk" |
| 35 | PACKAGECONFIG[hdsploader] = "" |
| 36 | PACKAGECONFIG[hdspmixer] = ",,fltk" |
| 37 | PACKAGECONFIG[ld10k1] = "" |
| 38 | PACKAGECONFIG[mixartloader] = "" |
| 39 | PACKAGECONFIG[pcxhrloader] = "" |
| 40 | PACKAGECONFIG[qlo10k1] = ",,qt-x11-free" |
| 41 | PACKAGECONFIG[rmedigicontrol] = ",,gtk+" |
| 42 | PACKAGECONFIG[sb16_csp] = "" |
| 43 | PACKAGECONFIG[seq--sbiload] = "" |
| 44 | PACKAGECONFIG[sscape_ctl] = "" |
| 45 | PACKAGECONFIG[us428control] = "" |
| 46 | PACKAGECONFIG[usx2yloader] = "" |
| 47 | PACKAGECONFIG[vxloader] = "" |
| 48 | |
| 49 | # At the time of writing pyalsa is not packaged for OE, so this is not expected |
| 50 | # to work. |
| 51 | PACKAGECONFIG[hwmixvolume] = ",,,python-core python-pygobject pyalsa" |
| 52 | |
| 53 | python do_configure() { |
| 54 | for subdir in d.getVar("PACKAGECONFIG").split(): |
| 55 | subdir = subdir.replace("--", "/") |
| 56 | bb.note("Configuring %s" % subdir) |
| 57 | dd = d.createCopy() |
| 58 | dd.setVar("S", os.path.join(d.getVar("S"), subdir)) |
| 59 | bb.build.exec_func("autotools_do_configure", dd) |
| 60 | } |
| 61 | |
| 62 | python do_compile() { |
| 63 | for subdir in d.getVar("PACKAGECONFIG").split(): |
| 64 | subdir = subdir.replace("--", "/") |
| 65 | bb.note("Compiling %s" % subdir) |
| 66 | dd = d.createCopy() |
| 67 | dd.setVar("S", os.path.join(d.getVar("S"), subdir)) |
| 68 | bb.build.exec_func("autotools_do_compile", dd) |
| 69 | } |
| 70 | |
| 71 | python do_install() { |
| 72 | for subdir in d.getVar("PACKAGECONFIG").split(): |
| 73 | subdir = subdir.replace("--", "/") |
| 74 | bb.note("Installing %s" % subdir) |
| 75 | dd = d.createCopy() |
| 76 | dd.setVar("S", os.path.join(d.getVar("S"), subdir)) |
| 77 | bb.build.exec_func("autotools_do_install", dd) |
| 78 | |
| 79 | # Just remove bash-needing init script that isn't installed as an init script |
| 80 | try: |
| 81 | os.remove(oe.path.join(d.getVar("D"), d.getVar("sbindir"), "ld10k1d")) |
| 82 | except: |
| 83 | pass |
| 84 | } |
| 85 | |
| 86 | FILES_${PN} += "${datadir}" |