| # Firmware Image Package (FIP) |
| # It is a packaging format used by TF-A to package the |
| # firmware images in a single binary. |
| |
| DESCRIPTION = "fiptool - Trusted Firmware tool for packaging" |
| LICENSE = "BSD-3-Clause" |
| |
| SRC_URI_TRUSTED_FIRMWARE_A ?= "git://git.trustedfirmware.org/TF-A/trusted-firmware-a.git;protocol=https" |
| SRC_URI = "${SRC_URI_TRUSTED_FIRMWARE_A};destsuffix=fiptool-${PV};branch=${SRCBRANCH}" |
| LIC_FILES_CHKSUM = "file://docs/license.rst;md5=b2c740efedc159745b9b31f88ff03dde" |
| |
| # Use fiptool from TF-A v2.9.0 |
| SRCREV = "d3e71ead6ea5bc3555ac90a446efec84ef6c6122" |
| SRCBRANCH = "master" |
| |
| DEPENDS += "openssl-native" |
| |
| inherit native |
| |
| EXTRA_OEMAKE = "V=1 HOSTCC='${BUILD_CC}' OPENSSL_DIR=${STAGING_DIR_NATIVE}/${prefix_native}" |
| |
| do_compile () { |
| # This is still needed to have the native fiptool executing properly by |
| # setting the RPATH |
| sed -i '/^LDLIBS/ s,$, \$\{BUILD_LDFLAGS},' ${S}/tools/fiptool/Makefile |
| sed -i '/^INCLUDE_PATHS/ s,$, \$\{BUILD_CFLAGS},' ${S}/tools/fiptool/Makefile |
| |
| oe_runmake fiptool |
| } |
| |
| do_install () { |
| install -D -p -m 0755 tools/fiptool/fiptool ${D}${bindir}/fiptool |
| } |