| require xorg-driver-video.inc |
| |
| SUMMARY = "X.Org X server -- Intel integrated graphics chipsets driver" |
| |
| DESCRIPTION = "intel is an Xorg driver for Intel integrated graphics \ |
| chipsets. The driver supports depths 8, 15, 16 and 24. On some chipsets, \ |
| the driver supports hardware accelerated 3D via the Direct Rendering \ |
| Infrastructure (DRI)." |
| |
| LIC_FILES_CHKSUM = "file://COPYING;md5=8730ad58d11c7bbad9a7066d69f7808e" |
| |
| SRCREV = "f66d39544bb8339130c96d282a80f87ca1606caf" |
| PV = "2.99.917+git${SRCPV}" |
| S = "${WORKDIR}/git" |
| |
| SRC_URI = "git://anongit.freedesktop.org/xorg/driver/xf86-video-intel \ |
| file://0001-Sync-i915_pciids-upto-8717c6b7414f.patch \ |
| file://0001-i810-Avoid-duplicate-definition-of-I810PatternROP.patch \ |
| " |
| |
| UPSTREAM_CHECK_GITTAGREGEX = "(?P<pver>\d+(\.\d+)+)" |
| |
| DEPENDS += "virtual/libx11 drm libpciaccess pixman" |
| |
| PACKAGECONFIG ??= "sna xvmc uxa udev ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'dri dri2 dri3', '', d)}" |
| |
| PACKAGECONFIG[dri] = "--enable-dri,--disable-dri" |
| PACKAGECONFIG[dri1] = "--enable-dri1,--disable-dri1" |
| PACKAGECONFIG[dri2] = "--enable-dri2,--disable-dri2" |
| PACKAGECONFIG[dri3] = "--enable-dri3,--disable-dri3" |
| PACKAGECONFIG[sna] = "--enable-sna,--disable-sna" |
| PACKAGECONFIG[uxa] = "--enable-uxa,--disable-uxa" |
| PACKAGECONFIG[udev] = "--enable-udev,--disable-udev,udev" |
| PACKAGECONFIG[xvmc] = "--enable-xvmc,--disable-xvmc,libxvmc xcb-util" |
| PACKAGECONFIG[tools] = "--enable-tools,--disable-tools,libxinerama libxrandr libxdamage libxfixes libxcursor libxtst libxrender libxscrnsaver libxext libx11 pixman libxcb libxshmfence" |
| |
| # --enable-kms-only option is required by ROOTLESS_X |
| EXTRA_OECONF += '${@oe.utils.conditional( "ROOTLESS_X", "1", " --enable-kms-only", "", d )}' |
| |
| COMPATIBLE_HOST = '(i.86|x86_64).*-linux' |
| |
| FILES_${PN} += "${datadir}/polkit-1" |