| KBRANCH ?= "v5.15/standard/base" |
| |
| require recipes-kernel/linux/linux-yocto.inc |
| |
| # board specific branches |
| KBRANCH:qemuarm ?= "v5.15/standard/arm-versatile-926ejs" |
| KBRANCH:qemuarm64 ?= "v5.15/standard/qemuarm64" |
| KBRANCH:qemumips ?= "v5.15/standard/mti-malta32" |
| KBRANCH:qemuppc ?= "v5.15/standard/qemuppc" |
| KBRANCH:qemuriscv64 ?= "v5.15/standard/base" |
| KBRANCH:qemuriscv32 ?= "v5.15/standard/base" |
| KBRANCH:qemux86 ?= "v5.15/standard/base" |
| KBRANCH:qemux86-64 ?= "v5.15/standard/base" |
| KBRANCH:qemumips64 ?= "v5.15/standard/mti-malta64" |
| |
| SRCREV_machine:qemuarm ?= "c33f2e2ad3fdcc1c9539f80fb51b49f68c544c03" |
| SRCREV_machine:qemuarm64 ?= "e8a14fadeb24619f20d3caebc01c7f26c49f768a" |
| SRCREV_machine:qemumips ?= "c5f07eee39e4e03e90de3e71a3f6448fdb73921a" |
| SRCREV_machine:qemuppc ?= "b5873d3a40b837059a36179174863cb4c7f9e109" |
| SRCREV_machine:qemuriscv64 ?= "efe20512212b0e85b5f884b1bfc8fbba2b43541a" |
| SRCREV_machine:qemuriscv32 ?= "efe20512212b0e85b5f884b1bfc8fbba2b43541a" |
| SRCREV_machine:qemux86 ?= "efe20512212b0e85b5f884b1bfc8fbba2b43541a" |
| SRCREV_machine:qemux86-64 ?= "efe20512212b0e85b5f884b1bfc8fbba2b43541a" |
| SRCREV_machine:qemumips64 ?= "a6c0767511eed80395777e42d33fdc8405bff2b4" |
| SRCREV_machine ?= "efe20512212b0e85b5f884b1bfc8fbba2b43541a" |
| SRCREV_meta ?= "f7f709bf874f85baff9f2fb0ac0341c08399b144" |
| |
| # set your preferred provider of linux-yocto to 'linux-yocto-upstream', and you'll |
| # get the <version>/base branch, which is pure upstream -stable, and the same |
| # meta SRCREV as the linux-yocto-standard builds. Select your version using the |
| # normal PREFERRED_VERSION settings. |
| BBCLASSEXTEND = "devupstream:target" |
| SRCREV_machine:class-devupstream ?= "d676d6149a2f4b4d66b8ea0a1dfef30a54cf5750" |
| PN:class-devupstream = "linux-yocto-upstream" |
| KBRANCH:class-devupstream = "v5.15/base" |
| |
| SRC_URI = "git://git.yoctoproject.org/linux-yocto.git;name=machine;branch=${KBRANCH}; \ |
| git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=yocto-5.15;destsuffix=${KMETA}" |
| |
| LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46" |
| LINUX_VERSION ?= "5.15.59" |
| |
| DEPENDS += "${@bb.utils.contains('ARCH', 'x86', 'elfutils-native', '', d)}" |
| DEPENDS += "openssl-native util-linux-native" |
| DEPENDS += "gmp-native libmpc-native" |
| |
| PV = "${LINUX_VERSION}+git${SRCPV}" |
| |
| KMETA = "kernel-meta" |
| KCONF_BSP_AUDIT_LEVEL = "1" |
| |
| KERNEL_DEVICETREE:qemuarmv5 = "versatile-pb.dtb" |
| |
| COMPATIBLE_MACHINE = "qemuarm|qemuarmv5|qemuarm64|qemux86|qemuppc|qemuppc64|qemumips|qemumips64|qemux86-64|qemuriscv64|qemuriscv32" |
| |
| # Functionality flags |
| KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc" |
| KERNEL_FEATURES:append = " ${KERNEL_EXTRA_FEATURES}" |
| KERNEL_FEATURES:append:qemuall=" cfg/virtio.scc features/drm-bochs/drm-bochs.scc" |
| KERNEL_FEATURES:append:qemux86=" cfg/sound.scc cfg/paravirt_kvm.scc" |
| KERNEL_FEATURES:append:qemux86-64=" cfg/sound.scc cfg/paravirt_kvm.scc" |
| KERNEL_FEATURES:append = " ${@bb.utils.contains("TUNE_FEATURES", "mx32", " cfg/x32.scc", "", d)}" |
| KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/scsi/scsi-debug.scc", "", d)}" |
| KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/gpio/mockup.scc", "", d)}" |
| KERNEL_FEATURES:append:powerpc =" arch/powerpc/powerpc-debug.scc" |
| KERNEL_FEATURES:append:powerpc64 =" arch/powerpc/powerpc-debug.scc" |
| KERNEL_FEATURES:append:powerpc64le =" arch/powerpc/powerpc-debug.scc" |
| |
| INSANE_SKIP:kernel-vmlinux:qemuppc64 = "textrel" |
| |