| SUMMARY = "Universal Boot Loader for embedded devices" |
| HOMEPAGE = "http://www.denx.de/wiki/U-Boot/WebHome" |
| SECTION = "bootloaders" |
| PROVIDES = "virtual/bootloader" |
| |
| LICENSE = "GPLv2+" |
| LIC_FILES_CHKSUM = "file://Licenses/README;md5=a2c678cfd4a4d97135585cad908541c6" |
| |
| SRC_URI = "git://git.denx.de/u-boot.git;branch=master" |
| |
| S = "${WORKDIR}/git" |
| |
| PACKAGE_ARCH = "${MACHINE_ARCH}" |
| |
| inherit uboot-config deploy |
| |
| EXTRA_OEMAKE = 'CROSS_COMPILE=${TARGET_PREFIX} CC="${TARGET_PREFIX}gcc ${TOOLCHAIN_OPTIONS}" V=1' |
| EXTRA_OEMAKE += 'HOSTCC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}"' |
| |
| PACKAGECONFIG ??= "openssl" |
| # u-boot will compile its own tools during the build, with specific |
| # configurations (aka when CONFIG_FIT_SIGNATURE is enabled) openssl is needed as |
| # a host build dependency. |
| PACKAGECONFIG[openssl] = ",,openssl-native" |
| |
| # Allow setting an additional version string that will be picked up by the |
| # u-boot build system and appended to the u-boot version. If the .scmversion |
| # file already exists it will not be overwritten. |
| UBOOT_LOCALVERSION ?= "" |
| |
| # Some versions of u-boot use .bin and others use .img. By default use .bin |
| # but enable individual recipes to change this value. |
| UBOOT_SUFFIX ??= "bin" |
| UBOOT_IMAGE ?= "u-boot-${MACHINE}-${PV}-${PR}.${UBOOT_SUFFIX}" |
| UBOOT_BINARY ?= "u-boot.${UBOOT_SUFFIX}" |
| UBOOT_SYMLINK ?= "u-boot-${MACHINE}.${UBOOT_SUFFIX}" |
| UBOOT_MAKE_TARGET ?= "all" |
| |
| # Output the ELF generated. Some platforms can use the ELF file and directly |
| # load it (JTAG booting, QEMU) additionally the ELF can be used for debugging |
| # purposes. |
| UBOOT_ELF ?= "" |
| UBOOT_ELF_SUFFIX ?= "elf" |
| UBOOT_ELF_IMAGE ?= "u-boot-${MACHINE}-${PV}-${PR}.${UBOOT_ELF_SUFFIX}" |
| UBOOT_ELF_BINARY ?= "u-boot.${UBOOT_ELF_SUFFIX}" |
| UBOOT_ELF_SYMLINK ?= "u-boot-${MACHINE}.${UBOOT_ELF_SUFFIX}" |
| |
| # Some versions of u-boot build an SPL (Second Program Loader) image that |
| # should be packaged along with the u-boot binary as well as placed in the |
| # deploy directory. For those versions they can set the following variables |
| # to allow packaging the SPL. |
| SPL_BINARY ?= "" |
| SPL_BINARYNAME ?= "${@os.path.basename(d.getVar("SPL_BINARY", True))}" |
| SPL_IMAGE ?= "${SPL_BINARYNAME}-${MACHINE}-${PV}-${PR}" |
| SPL_SYMLINK ?= "${SPL_BINARYNAME}-${MACHINE}" |
| |
| # Additional environment variables or a script can be installed alongside |
| # u-boot to be used automatically on boot. This file, typically 'uEnv.txt' |
| # or 'boot.scr', should be packaged along with u-boot as well as placed in the |
| # deploy directory. Machine configurations needing one of these files should |
| # include it in the SRC_URI and set the UBOOT_ENV parameter. |
| UBOOT_ENV_SUFFIX ?= "txt" |
| UBOOT_ENV ?= "" |
| UBOOT_ENV_BINARY ?= "${UBOOT_ENV}.${UBOOT_ENV_SUFFIX}" |
| UBOOT_ENV_IMAGE ?= "${UBOOT_ENV}-${MACHINE}-${PV}-${PR}.${UBOOT_ENV_SUFFIX}" |
| UBOOT_ENV_SYMLINK ?= "${UBOOT_ENV}-${MACHINE}.${UBOOT_ENV_SUFFIX}" |
| |
| do_compile () { |
| if [ "${@bb.utils.contains('DISTRO_FEATURES', 'ld-is-gold', 'ld-is-gold', '', d)}" = "ld-is-gold" ] ; then |
| sed -i 's/$(CROSS_COMPILE)ld$/$(CROSS_COMPILE)ld.bfd/g' config.mk |
| fi |
| |
| unset LDFLAGS |
| unset CFLAGS |
| unset CPPFLAGS |
| |
| if [ ! -e ${B}/.scmversion -a ! -e ${S}/.scmversion ] |
| then |
| echo ${UBOOT_LOCALVERSION} > ${B}/.scmversion |
| echo ${UBOOT_LOCALVERSION} > ${S}/.scmversion |
| fi |
| |
| if [ "x${UBOOT_CONFIG}" != "x" ] |
| then |
| for config in ${UBOOT_MACHINE}; do |
| i=`expr $i + 1`; |
| for type in ${UBOOT_CONFIG}; do |
| j=`expr $j + 1`; |
| if [ $j -eq $i ] |
| then |
| oe_runmake O=${config} ${config} |
| oe_runmake O=${config} ${UBOOT_MAKE_TARGET} |
| cp ${S}/${config}/${UBOOT_BINARY} ${S}/${config}/u-boot-${type}.${UBOOT_SUFFIX} |
| fi |
| done |
| unset j |
| done |
| unset i |
| else |
| oe_runmake ${UBOOT_MACHINE} |
| oe_runmake ${UBOOT_MAKE_TARGET} |
| fi |
| |
| } |
| |
| do_install () { |
| if [ "x${UBOOT_CONFIG}" != "x" ] |
| then |
| for config in ${UBOOT_MACHINE}; do |
| i=`expr $i + 1`; |
| for type in ${UBOOT_CONFIG}; do |
| j=`expr $j + 1`; |
| if [ $j -eq $i ] |
| then |
| install -d ${D}/boot |
| install ${S}/${config}/u-boot-${type}.${UBOOT_SUFFIX} ${D}/boot/u-boot-${type}-${PV}-${PR}.${UBOOT_SUFFIX} |
| ln -sf u-boot-${type}-${PV}-${PR}.${UBOOT_SUFFIX} ${D}/boot/${UBOOT_BINARY}-${type} |
| ln -sf u-boot-${type}-${PV}-${PR}.${UBOOT_SUFFIX} ${D}/boot/${UBOOT_BINARY} |
| fi |
| done |
| unset j |
| done |
| unset i |
| else |
| install -d ${D}/boot |
| install ${S}/${UBOOT_BINARY} ${D}/boot/${UBOOT_IMAGE} |
| ln -sf ${UBOOT_IMAGE} ${D}/boot/${UBOOT_BINARY} |
| fi |
| |
| if [ "x${UBOOT_ELF}" != "x" ] |
| then |
| if [ "x${UBOOT_CONFIG}" != "x" ] |
| then |
| for config in ${UBOOT_MACHINE}; do |
| i=`expr $i + 1`; |
| for type in ${UBOOT_CONFIG}; do |
| j=`expr $j + 1`; |
| if [ $j -eq $i ] |
| then |
| install ${S}/${config}/${UBOOT_ELF} ${D}/boot/u-boot-${type}-${PV}-${PR}.${UBOOT_ELF_SUFFIX} |
| ln -sf u-boot-${type}-${PV}-${PR}.${UBOOT_ELF_SUFFIX} ${D}/boot/${UBOOT_BINARY}-${type} |
| ln -sf u-boot-${type}-${PV}-${PR}.${UBOOT_ELF_SUFFIX} ${D}/boot/${UBOOT_BINARY} |
| fi |
| done |
| unset j |
| done |
| unset i |
| else |
| install ${S}/${UBOOT_ELF} ${D}/boot/${UBOOT_ELF_IMAGE} |
| ln -sf ${UBOOT_ELF_IMAGE} ${D}/boot/${UBOOT_ELF_BINARY} |
| fi |
| fi |
| |
| if [ -e ${WORKDIR}/fw_env.config ] ; then |
| install -d ${D}${sysconfdir} |
| install -m 644 ${WORKDIR}/fw_env.config ${D}${sysconfdir}/fw_env.config |
| fi |
| |
| if [ "x${SPL_BINARY}" != "x" ] |
| then |
| if [ "x${UBOOT_CONFIG}" != "x" ] |
| then |
| for config in ${UBOOT_MACHINE}; do |
| i=`expr $i + 1`; |
| for type in ${UBOOT_CONFIG}; do |
| j=`expr $j + 1`; |
| if [ $j -eq $i ] |
| then |
| install ${S}/${config}/${SPL_BINARY} ${D}/boot/${SPL_IMAGE}-${type}-${PV}-${PR} |
| ln -sf ${SPL_IMAGE}-${type}-${PV}-${PR} ${D}/boot/${SPL_BINARYNAME}-${type} |
| ln -sf ${SPL_IMAGE}-${type}-${PV}-${PR} ${D}/boot/${SPL_BINARYNAME} |
| fi |
| done |
| unset j |
| done |
| unset i |
| else |
| install ${S}/${SPL_BINARY} ${D}/boot/${SPL_IMAGE} |
| ln -sf ${SPL_IMAGE} ${D}/boot/${SPL_BINARYNAME} |
| fi |
| fi |
| |
| if [ "x${UBOOT_ENV}" != "x" ] |
| then |
| install ${WORKDIR}/${UBOOT_ENV_BINARY} ${D}/boot/${UBOOT_ENV_IMAGE} |
| ln -sf ${UBOOT_ENV_IMAGE} ${D}/boot/${UBOOT_ENV_BINARY} |
| fi |
| } |
| |
| FILES_${PN} = "/boot ${sysconfdir}" |
| |
| do_deploy () { |
| if [ "x${UBOOT_CONFIG}" != "x" ] |
| then |
| for config in ${UBOOT_MACHINE}; do |
| i=`expr $i + 1`; |
| for type in ${UBOOT_CONFIG}; do |
| j=`expr $j + 1`; |
| if [ $j -eq $i ] |
| then |
| install -d ${DEPLOYDIR} |
| install ${S}/${config}/u-boot-${type}.${UBOOT_SUFFIX} ${DEPLOYDIR}/u-boot-${type}-${PV}-${PR}.${UBOOT_SUFFIX} |
| cd ${DEPLOYDIR} |
| ln -sf u-boot-${type}-${PV}-${PR}.${UBOOT_SUFFIX} ${UBOOT_SYMLINK}-${type} |
| ln -sf u-boot-${type}-${PV}-${PR}.${UBOOT_SUFFIX} ${UBOOT_SYMLINK} |
| ln -sf u-boot-${type}-${PV}-${PR}.${UBOOT_SUFFIX} ${UBOOT_BINARY}-${type} |
| ln -sf u-boot-${type}-${PV}-${PR}.${UBOOT_SUFFIX} ${UBOOT_BINARY} |
| fi |
| done |
| unset j |
| done |
| unset i |
| else |
| install -d ${DEPLOYDIR} |
| install ${S}/${UBOOT_BINARY} ${DEPLOYDIR}/${UBOOT_IMAGE} |
| cd ${DEPLOYDIR} |
| rm -f ${UBOOT_BINARY} ${UBOOT_SYMLINK} |
| ln -sf ${UBOOT_IMAGE} ${UBOOT_SYMLINK} |
| ln -sf ${UBOOT_IMAGE} ${UBOOT_BINARY} |
| fi |
| |
| if [ "x${UBOOT_ELF}" != "x" ] |
| then |
| if [ "x${UBOOT_CONFIG}" != "x" ] |
| then |
| for config in ${UBOOT_MACHINE}; do |
| i=`expr $i + 1`; |
| for type in ${UBOOT_CONFIG}; do |
| j=`expr $j + 1`; |
| if [ $j -eq $i ] |
| then |
| install ${S}/${config}/${UBOOT_ELF} ${DEPLOYDIR}/u-boot-${type}-${PV}-${PR}.${UBOOT_ELF_SUFFIX} |
| ln -sf u-boot-${type}-${PV}-${PR}.${UBOOT_ELF_SUFFIX} ${DEPLOYDIR}/${UBOOT_ELF_BINARY}-${type} |
| ln -sf u-boot-${type}-${PV}-${PR}.${UBOOT_ELF_SUFFIX} ${DEPLOYDIR}/${UBOOT_ELF_BINARY} |
| ln -sf u-boot-${type}-${PV}-${PR}.${UBOOT_ELF_SUFFIX} ${DEPLOYDIR}/${UBOOT_ELF_SYMLINK}-${type} |
| ln -sf u-boot-${type}-${PV}-${PR}.${UBOOT_ELF_SUFFIX} ${DEPLOYDIR}/${UBOOT_ELF_SYMLINK} |
| fi |
| done |
| unset j |
| done |
| unset i |
| else |
| install ${S}/${UBOOT_ELF} ${DEPLOYDIR}/${UBOOT_ELF_IMAGE} |
| ln -sf ${UBOOT_ELF_IMAGE} ${DEPLOYDIR}/${UBOOT_ELF_BINARY} |
| ln -sf ${UBOOT_ELF_IMAGE} ${DEPLOYDIR}/${UBOOT_ELF_SYMLINK} |
| fi |
| fi |
| |
| |
| if [ "x${SPL_BINARY}" != "x" ] |
| then |
| if [ "x${UBOOT_CONFIG}" != "x" ] |
| then |
| for config in ${UBOOT_MACHINE}; do |
| i=`expr $i + 1`; |
| for type in ${UBOOT_CONFIG}; do |
| j=`expr $j + 1`; |
| if [ $j -eq $i ] |
| then |
| install ${S}/${config}/${SPL_BINARY} ${DEPLOYDIR}/${SPL_IMAGE}-${type}-${PV}-${PR} |
| rm -f ${DEPLOYDIR}/${SPL_BINARYNAME} ${DEPLOYDIR}/${SPL_SYMLINK}-${type} |
| ln -sf ${SPL_IMAGE}-${type}-${PV}-${PR} ${DEPLOYDIR}/${SPL_BINARYNAME}-${type} |
| ln -sf ${SPL_IMAGE}-${type}-${PV}-${PR} ${DEPLOYDIR}/${SPL_BINARYNAME} |
| ln -sf ${SPL_IMAGE}-${type}-${PV}-${PR} ${DEPLOYDIR}/${SPL_SYMLINK}-${type} |
| ln -sf ${SPL_IMAGE}-${type}-${PV}-${PR} ${DEPLOYDIR}/${SPL_SYMLINK} |
| fi |
| done |
| unset j |
| done |
| unset i |
| else |
| install ${S}/${SPL_BINARY} ${DEPLOYDIR}/${SPL_IMAGE} |
| rm -f ${DEPLOYDIR}/${SPL_BINARYNAME} ${DEPLOYDIR}/${SPL_SYMLINK} |
| ln -sf ${SPL_IMAGE} ${DEPLOYDIR}/${SPL_BINARYNAME} |
| ln -sf ${SPL_IMAGE} ${DEPLOYDIR}/${SPL_SYMLINK} |
| fi |
| fi |
| |
| |
| if [ "x${UBOOT_ENV}" != "x" ] |
| then |
| install ${WORKDIR}/${UBOOT_ENV_BINARY} ${DEPLOYDIR}/${UBOOT_ENV_IMAGE} |
| rm -f ${DEPLOYDIR}/${UBOOT_ENV_BINARY} ${DEPLOYDIR}/${UBOOT_ENV_SYMLINK} |
| ln -sf ${UBOOT_ENV_IMAGE} ${DEPLOYDIR}/${UBOOT_ENV_BINARY} |
| ln -sf ${UBOOT_ENV_IMAGE} ${DEPLOYDIR}/${UBOOT_ENV_SYMLINK} |
| fi |
| } |
| |
| addtask deploy before do_build after do_compile |