| # Copyright (c) 2012-2014 LG Electronics, Inc. |
| SUMMARY = "c-ares is a C library that resolves names asynchronously." |
| HOMEPAGE = "http://daniel.haxx.se/projects/c-ares/" |
| SECTION = "libs" |
| LICENSE = "MIT" |
| LIC_FILES_CHKSUM = "file://LICENSE.md;md5=fdbc58a6da11a9f68aa73c453818decc" |
| |
| SRC_URI = "https://c-ares.org/download/${BPN}-${PV}.tar.gz \ |
| file://run-ptest" |
| SRC_URI[sha256sum] = "bed58c4f02b009080ebda6c2467ba469722ac6aebbf4497dc44a83d8c6194e50" |
| |
| PACKAGECONFIG ?= "${@bb.utils.contains('PTEST_ENABLED', '1', 'tests', '', d)}" |
| PACKAGECONFIG[manpages] = "" |
| PACKAGECONFIG[tests] = "-DCARES_BUILD_TESTS=ON,-DCARES_BUILD_TESTS=OFF,googletest" |
| |
| inherit cmake manpages pkgconfig ptest |
| |
| EXTRA_OECMAKE = "-DCARES_STATIC=${@ 'ON' if d.getVar('DISABLE_STATIC') == '' else 'OFF' }" |
| |
| do_install_ptest () { |
| install -d ${D}${PTEST_PATH} |
| install -m 0755 ${B}/bin/arestest ${D}${PTEST_PATH} |
| install -m 0755 ${WORKDIR}/run-ptest ${D}${PTEST_PATH} |
| } |
| |
| PACKAGE_BEFORE_PN = "${PN}-utils" |
| |
| FILES:${PN}-utils = "${bindir}" |
| |
| BBCLASSEXTEND = "native nativesdk" |