| KBRANCH ?= "v5.10/standard/base" |
| |
| require recipes-kernel/linux/linux-yocto.inc |
| |
| # board specific branches |
| KBRANCH:qemuarm ?= "v5.10/standard/arm-versatile-926ejs" |
| KBRANCH:qemuarm64 ?= "v5.10/standard/qemuarm64" |
| KBRANCH:qemumips ?= "v5.10/standard/mti-malta32" |
| KBRANCH:qemuppc ?= "v5.10/standard/qemuppc" |
| KBRANCH:qemuriscv64 ?= "v5.10/standard/base" |
| KBRANCH:qemuriscv32 ?= "v5.10/standard/base" |
| KBRANCH:qemux86 ?= "v5.10/standard/base" |
| KBRANCH:qemux86-64 ?= "v5.10/standard/base" |
| KBRANCH:qemumips64 ?= "v5.10/standard/mti-malta64" |
| |
| SRCREV_machine:qemuarm ?= "1cf6a458134cbbe232467622d8e34d2e9d10e92b" |
| SRCREV_machine:qemuarm64 ?= "5db230097771631366812f12c9b04c8379f53c24" |
| SRCREV_machine:qemumips ?= "795276fa64f0874a4ee0dcfa9c78e572314bdfa1" |
| SRCREV_machine:qemuppc ?= "6ccfcf5138703538662241bf8ed897a1ef2a3def" |
| SRCREV_machine:qemuriscv64 ?= "c6515d2a698792220bed8fd39ccbcfec64d1130f" |
| SRCREV_machine:qemuriscv32 ?= "c6515d2a698792220bed8fd39ccbcfec64d1130f" |
| SRCREV_machine:qemux86 ?= "c6515d2a698792220bed8fd39ccbcfec64d1130f" |
| SRCREV_machine:qemux86-64 ?= "c6515d2a698792220bed8fd39ccbcfec64d1130f" |
| SRCREV_machine:qemumips64 ?= "4d6b146f00b8efc99e3d3d1d8a63220c29590c8d" |
| SRCREV_machine ?= "c6515d2a698792220bed8fd39ccbcfec64d1130f" |
| SRCREV_meta ?= "4476e17760bea9d68c392368f2396a2e9efa86c3" |
| |
| SRC_URI = "git://git.yoctoproject.org/linux-yocto.git;name=machine;branch=${KBRANCH}; \ |
| git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=yocto-5.10;destsuffix=${KMETA}" |
| |
| LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46" |
| LINUX_VERSION ?= "5.10.180" |
| |
| DEPENDS += "${@bb.utils.contains('ARCH', 'x86', 'elfutils-native', '', d)}" |
| DEPENDS += "openssl-native util-linux-native" |
| DEPENDS += "gmp-native libmpc-native" |
| |
| PV = "${LINUX_VERSION}+git${SRCPV}" |
| |
| KMETA = "kernel-meta" |
| KCONF_BSP_AUDIT_LEVEL = "1" |
| |
| KERNEL_DEVICETREE:qemuarmv5 = "versatile-pb.dtb" |
| |
| COMPATIBLE_MACHINE = "^(qemuarm|qemuarmv5|qemuarm64|qemux86|qemuppc|qemuppc64|qemumips|qemumips64|qemux86-64|qemuriscv64|qemuriscv32)$" |
| |
| # Functionality flags |
| KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc" |
| KERNEL_FEATURES:append = " ${KERNEL_EXTRA_FEATURES}" |
| KERNEL_FEATURES:append:qemuall=" cfg/virtio.scc features/drm-bochs/drm-bochs.scc" |
| KERNEL_FEATURES:append:qemux86=" cfg/sound.scc cfg/paravirt_kvm.scc" |
| KERNEL_FEATURES:append:qemux86-64=" cfg/sound.scc cfg/paravirt_kvm.scc" |
| KERNEL_FEATURES:append:powerpc =" arch/powerpc/powerpc-debug.scc" |
| KERNEL_FEATURES:append:powerpc64 =" arch/powerpc/powerpc-debug.scc" |
| KERNEL_FEATURES:append:powerpc64le =" arch/powerpc/powerpc-debug.scc" |
| KERNEL_FEATURES:append = " ${@bb.utils.contains("TUNE_FEATURES", "mx32", " cfg/x32.scc", "", d)}" |
| KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/scsi/scsi-debug.scc", "", d)}" |
| KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/gpio/mockup.scc", "", d)}" |