| Brad Bishop | 1a4b7ee | 2018-12-16 17:11:34 -0800 | [diff] [blame^] | 1 | SUMMARY = "XFS Filesystem Utilities" |
| 2 | HOMEPAGE = "http://oss.sgi.com/projects/xfs" |
| 3 | SECTION = "base" |
| 4 | LICENSE = "GPLv2 & LGPLv2.1" |
| 5 | LICENSE_libhandle = "LGPLv2.1" |
| 6 | LIC_FILES_CHKSUM = "file://LICENSES/GPL-2.0;md5=74274e8a218423e49eefdea80bc55038 \ |
| 7 | file://LICENSES/LGPL-2.1;md5=b370887980db5dd40659b50909238dbd" |
| 8 | DEPENDS = "util-linux util-linux-native" |
| 9 | SRC_URI = "https://www.kernel.org/pub/linux/utils/fs/xfs/xfsprogs/${BP}.tar.xz \ |
| 10 | file://remove_flags_from_build_flags.patch \ |
| 11 | file://0001-build-Check-for-sync_file_range-libc-function.patch \ |
| 12 | file://disable-xfs_scrub-build.patch \ |
| 13 | file://0001-Check-for-MAP_SYNC-in-sys-mman.h.patch \ |
| 14 | file://0002-include-include-xfs-linux.h-after-sys-mman.h.patch \ |
| 15 | " |
| 16 | SRC_URI[md5sum] = "5f80b631b68df89a8b9283307e96d2e8" |
| 17 | SRC_URI[sha256sum] = "397dc96f51aeeff73d021d3418d3172377b2685f2740ca60525096c070aa3df1" |
| 18 | |
| 19 | inherit autotools-brokensep |
| 20 | |
| 21 | PACKAGES =+ "${PN}-fsck ${PN}-mkfs ${PN}-repair libhandle" |
| 22 | |
| 23 | DEPENDS += "util-linux" |
| 24 | |
| 25 | RDEPENDS_${PN} = "${PN}-fsck ${PN}-mkfs ${PN}-repair" |
| 26 | |
| 27 | FILES_${PN}-fsck = "${base_sbindir}/fsck.xfs" |
| 28 | FILES_${PN}-mkfs = "${base_sbindir}/mkfs.xfs" |
| 29 | FILES_${PN}-repair = "${base_sbindir}/xfs_repair" |
| 30 | |
| 31 | FILES_libhandle = "${base_libdir}/libhandle${SOLIBS}" |
| 32 | |
| 33 | EXTRA_OECONF = "--enable-gettext=no \ |
| 34 | INSTALL_USER=root \ |
| 35 | INSTALL_GROUP=root \ |
| 36 | ac_cv_header_aio_h=yes \ |
| 37 | ac_cv_lib_rt_lio_listio=yes \ |
| 38 | " |
| 39 | |
| 40 | DISABLE_STATIC = "" |
| 41 | EXTRA_AUTORECONF += "-I ${S}/m4 --exclude=autoheader" |
| 42 | |
| 43 | PACKAGECONFIG ??= "readline blkid" |
| 44 | |
| 45 | PACKAGECONFIG[readline] = "--enable-readline=yes,--enable-readline=no,readline" |
| 46 | PACKAGECONFIG[blkid] = "--enable-blkid=yes,--enable-blkid=no,util-linux" |
| 47 | |
| 48 | export DEBUG="-DNDEBUG" |
| 49 | export BUILD_VERBOSE="1" |
| 50 | export tagname="CC" |
| 51 | |
| 52 | EXTRA_OEMAKE = "DIST_ROOT='${D}'" |
| 53 | |
| 54 | do_configure () { |
| 55 | export BUILD_CC="${BUILD_CC} ${BUILD_CFLAGS}" |
| 56 | # Prevent Makefile from calling configure without arguments, |
| 57 | # when do_configure gets called for a second time. |
| 58 | rm -f ${B}/include/builddefs ${B}/include/platform_defs.h ${B}/configure |
| 59 | # Recreate configure script. |
| 60 | oe_runmake configure |
| 61 | oe_runconf |
| 62 | } |
| 63 | |
| 64 | do_install_append() { |
| 65 | oe_runmake 'DESTDIR=${D}' install-dev |
| 66 | rm ${D}${libdir}/*.la |
| 67 | rmdir --ignore-fail-on-non-empty ${D}${libdir} |
| 68 | } |