Brad Bishop | 6e60e8b | 2018-02-01 10:27:11 -0500 | [diff] [blame] | 1 | DESCRIPTION = "FFTW" |
| 2 | SECTION = "libs" |
| 3 | LICENSE = "GPLv2" |
| 4 | LIC_FILES_CHKSUM = "file://COPYING;md5=59530bdf33659b29e73d4adb9f9f6552" |
| 5 | |
| 6 | SRC_URI = " \ |
| 7 | http://www.fftw.org/fftw-${PV}-pl1.tar.gz \ |
| 8 | file://0001-NEON-autodetection-segfaults-assume-neon-present.patch \ |
| 9 | " |
| 10 | SRC_URI[md5sum] = "682a0e78d6966ca37c7446d4ab4cc2a1" |
| 11 | SRC_URI[sha256sum] = "1ef4aa8427d9785839bc767f3eb6a84fcb5e9a37c31ed77a04e7e047519a183d" |
| 12 | |
| 13 | S = "${WORKDIR}/fftw-${PV}-pl1" |
| 14 | |
| 15 | inherit autotools pkgconfig |
| 16 | |
| 17 | # we had multiple recipes in the past |
| 18 | PROVIDES = "fftwl fftwf" |
| 19 | |
| 20 | EXTRA_OECONF = "--disable-fortran --enable-shared --enable-threads" |
| 21 | |
| 22 | CFLAGS += "-D_GNU_SOURCE" |
| 23 | |
| 24 | FFTW_NEON = "${@bb.utils.contains('TUNE_FEATURES', 'neon', '--enable-neon', '', d)}" |
| 25 | FFTW_NEON_class-native = "" |
| 26 | |
| 27 | do_configure() { |
| 28 | # configure fftw |
| 29 | rm -rf ${WORKDIR}/build-fftw |
| 30 | mkdir -p ${B} |
| 31 | cd ${B} |
| 32 | # full (re)configure |
| 33 | autotools_do_configure |
| 34 | mv ${B} ${WORKDIR}/build-fftw |
| 35 | |
| 36 | # configure fftwl |
| 37 | rm -rf ${WORKDIR}/build-fftwl |
| 38 | mkdir -p ${B} |
| 39 | cd ${B} |
| 40 | # configure only |
| 41 | oe_runconf --enable-long-double |
| 42 | mv ${B} ${WORKDIR}/build-fftwl |
| 43 | |
| 44 | # configure fftwf |
| 45 | rm -rf ${WORKDIR}/build-fftwf |
| 46 | mkdir -p ${B} |
| 47 | cd ${B} |
| 48 | # configure only |
| 49 | oe_runconf --enable-single ${FFTW_NEON} |
| 50 | mv ${B} ${WORKDIR}/build-fftwf |
| 51 | } |
| 52 | |
| 53 | do_compile() { |
| 54 | for lib in fftw fftwl fftwf; do |
| 55 | cd ${WORKDIR}/build-$lib |
| 56 | autotools_do_compile |
| 57 | done |
| 58 | } |
| 59 | |
| 60 | do_install() { |
| 61 | for lib in fftw fftwl fftwf; do |
| 62 | cd ${WORKDIR}/build-$lib |
| 63 | autotools_do_install |
| 64 | done |
| 65 | } |
| 66 | |
| 67 | |
| 68 | PACKAGES =+ "libfftw libfftwl libfftwf" |
| 69 | FILES_libfftw = "${libdir}/libfftw3.so.* ${libdir}/libfftw3_*.so.*" |
| 70 | FILES_libfftwl = "${libdir}/libfftw3l.so.* ${libdir}/libfftw3l_*.so.*" |
| 71 | FILES_libfftwf = "${libdir}/libfftw3f.so.* ${libdir}/libfftw3f_*.so.*" |
| 72 | |
| 73 | PACKAGES =+ "fftw-wisdom fftwl-wisdom fftwf-wisdom fftw-wisdom-to-conf" |
| 74 | FILES_fftw-wisdom = "${bindir}/fftw-wisdom" |
| 75 | FILES_fftwl-wisdom = "${bindir}/fftwl-wisdom" |
| 76 | FILES_fftwf-wisdom = "${bindir}/fftwf-wisdom" |
| 77 | FILES_fftw-wisdom-to-conf = "${bindir}/fftw-wisdom-to-conf" |
| 78 | |
| 79 | RDEPENDS_${PN}-dev = "" |
| 80 | |
| 81 | BBCLASSEXTEND = "native" |