| Brad Bishop | 6e60e8b | 2018-02-01 10:27:11 -0500 | [diff] [blame] | 1 | SUMMARY = "Xfce4 Panel" |
| 2 | SECTION = "x11" |
| 3 | LICENSE = "GPLv2" |
| 4 | LIC_FILES_CHKSUM = "file://COPYING;md5=26a8bd75d8f8498bdbbe64a27791d4ee" |
| 5 | DEPENDS = "libxfce4util garcon libxfce4ui xfconf exo gtk+ gtk+3 dbus cairo virtual/libx11 libxml2 libwnck" |
| 6 | |
| 7 | inherit xfce gtk-doc distro_features_check |
| 8 | |
| 9 | REQUIRED_DISTRO_FEATURES = "x11" |
| 10 | |
| 11 | SRC_URI[md5sum] = "0b943f2e72a3693dddb1af559826cb62" |
| 12 | SRC_URI[sha256sum] = "93d58b80cca9c9eb58adb281bc75404df7cf6cae89f7f98bb9f38690009aa2e8" |
| 13 | SRC_URI += " \ |
| 14 | file://0001-clock-time-make-change-of-system-s-timezone-change-t.patch \ |
| 15 | file://0002-windowmenu-do-not-display-desktop-icon-when-no-windo.patch \ |
| 16 | " |
| 17 | |
| 18 | EXTRA_OECONF += "--enable-gtk3" |
| 19 | |
| 20 | python populate_packages_prepend() { |
| 21 | plugin_dir = d.expand('${libdir}/xfce4/panel/plugins/') |
| 22 | plugin_name = d.expand('${PN}-plugin-%s') |
| 23 | do_split_packages(d, plugin_dir, '^lib(.*).so$', plugin_name, |
| 24 | '${PN} plugin for %s', extra_depends='', prepend=True, |
| 25 | aux_files_pattern=['${datadir}/xfce4/panel/plugins/%s.desktop', |
| 26 | '${sysconfdir}/xdg/xfce/panel/%s-*', |
| 27 | '${datadir}/icons/hicolor/48x48/apps/*-%s.png', |
| 28 | '${bindir}/*%s*']) |
| 29 | } |
| 30 | |
| 31 | PACKAGES_DYNAMIC += "^${PN}-plugin-.*" |
| 32 | |
| 33 | PACKAGES =+ "${PN}-gtk3" |
| 34 | |
| 35 | FILES_${PN} += "${libdir}/xfce4/panel/migrate \ |
| 36 | ${libdir}/xfce4/panel/wrapper-1.0" |
| 37 | |
| 38 | FILES_${PN}-gtk3 = " \ |
| 39 | ${libdir}/libxfce4panel-2.0${SOLIBS} \ |
| 40 | ${libdir}/xfce4/panel/wrapper-2.0 \ |
| 41 | " |
| 42 | FILES_${PN}-dbg += "${libdir}/xfce4/panel/plugins/.debug \ |
| 43 | " |