Brad Bishop | d7bf8c1 | 2018-02-25 22:55:05 -0500 | [diff] [blame] | 1 | SUMMARY = "Package manager forked from Yum, using libsolv as a dependency resolver" |
| 2 | LICENSE = "GPLv2" |
| 3 | LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \ |
| 4 | file://PACKAGE-LICENSING;md5=bfc29916e11321be06924c4fb096fdcc \ |
| 5 | " |
| 6 | |
| 7 | SRC_URI = "git://github.com/rpm-software-management/dnf.git \ |
| 8 | file://0029-Do-not-set-PYTHON_INSTALL_DIR-by-running-python.patch \ |
| 9 | file://0030-Run-python-scripts-using-env.patch \ |
| 10 | file://0001-Do-not-prepend-installroot-to-logdir.patch \ |
| 11 | file://0001-Do-not-hardcode-etc-and-systemd-unit-directories.patch \ |
| 12 | file://0001-Corretly-install-tmpfiles.d-configuration.patch \ |
| 13 | file://0001-Check-conf.releasever-instead-of-releasever.patch \ |
| 14 | " |
| 15 | |
| 16 | SRCREV = "be2585183ec4485ee4d5e121f242d8669296f065" |
| 17 | UPSTREAM_CHECK_GITTAGREGEX = "(?P<pver>\d+(\.\d+)+)" |
| 18 | |
| 19 | S = "${WORKDIR}/git" |
| 20 | |
| 21 | inherit cmake gettext bash-completion distutils3-base systemd |
| 22 | |
| 23 | DEPENDS += "libdnf librepo libcomps python3-iniparse" |
| 24 | |
| 25 | # manpages generation requires http://www.sphinx-doc.org/ |
| 26 | EXTRA_OECMAKE = " -DWITH_MAN=0 -DPYTHON_INSTALL_DIR=${PYTHON_SITEPACKAGES_DIR} -DPYTHON_DESIRED=3" |
| 27 | |
| 28 | BBCLASSEXTEND = "native nativesdk" |
| 29 | RDEPENDS_${PN}_class-target += "python3-core python3-codecs python3-netclient python3-email python3-threading python3-distutils librepo python3-shell python3-subprocess libcomps libdnf python3-sqlite3 python3-compression python3-rpm python3-iniparse python3-json python3-importlib python3-curses python3-argparse python3-misc python3-gpg" |
| 30 | # Recommend gnupg so that GPG signature check on repository metadata is possible |
| 31 | RRECOMMENDS_${PN}_class-target += "gnupg" |
| 32 | |
| 33 | # Create a symlink called 'dnf' as 'make install' does not do it, but |
| 34 | # .spec file in dnf source tree does (and then Fedora and dnf documentation |
| 35 | # says that dnf binary is plain 'dnf'). |
| 36 | do_install_append() { |
| 37 | lnr ${D}/${bindir}/dnf-3 ${D}/${bindir}/dnf |
| 38 | lnr ${D}/${bindir}/dnf-automatic-3 ${D}/${bindir}/dnf-automatic |
| 39 | } |
| 40 | |
| 41 | # Direct dnf-native to read rpm configuration from our sysroot, not the one it was compiled in |
| 42 | do_install_append_class-native() { |
| 43 | create_wrapper ${D}/${bindir}/dnf \ |
| 44 | RPM_CONFIGDIR=${STAGING_LIBDIR_NATIVE}/rpm \ |
| 45 | RPM_NO_CHROOT_FOR_SCRIPTS=1 |
| 46 | } |
| 47 | |
| 48 | SYSTEMD_SERVICE_${PN} = "dnf-makecache.service dnf-makecache.timer \ |
| 49 | dnf-automatic-download.service dnf-automatic-download.timer \ |
| 50 | dnf-automatic-install.service dnf-automatic-install.timer \ |
| 51 | dnf-automatic-notifyonly.service dnf-automatic-notifyonly.timer \ |
| 52 | " |