| Andrew Geissler | 517393d | 2023-01-13 08:55:19 -0600 | [diff] [blame^] | 1 | SUMMARY = "Redis key-value store" |
| 2 | DESCRIPTION = "Redis is an open source, advanced key-value store." |
| 3 | HOMEPAGE = "http://redis.io" |
| 4 | SECTION = "libs" |
| 5 | LICENSE = "BSD-3-Clause" |
| 6 | LIC_FILES_CHKSUM = "file://COPYING;md5=8ffdd6c926faaece928cf9d9640132d2" |
| 7 | DEPENDS = "readline lua ncurses" |
| 8 | |
| 9 | SRC_URI = "http://download.redis.io/releases/${BP}.tar.gz \ |
| 10 | file://redis.conf \ |
| 11 | file://init-redis-server \ |
| 12 | file://redis.service \ |
| 13 | file://hiredis-use-default-CC-if-it-is-set.patch \ |
| 14 | file://lua-update-Makefile-to-use-environment-build-setting.patch \ |
| 15 | file://oe-use-libc-malloc.patch \ |
| 16 | file://0001-src-Do-not-reset-FINAL_LIBS.patch \ |
| 17 | file://GNU_SOURCE.patch \ |
| 18 | file://0006-Define-correct-gregs-for-RISCV32.patch \ |
| 19 | " |
| 20 | SRC_URI[sha256sum] = "f91ab24bcb42673cb853292eb5d43c2017d11d659854808ed6a529c97297fdfe" |
| 21 | |
| 22 | inherit autotools-brokensep update-rc.d systemd useradd |
| 23 | |
| 24 | FINAL_LIBS:x86:toolchain-clang = "-latomic" |
| 25 | FINAL_LIBS:riscv32:toolchain-clang = "-latomic" |
| 26 | FINAL_LIBS:mips = "-latomic" |
| 27 | FINAL_LIBS:arm = "-latomic" |
| 28 | FINAL_LIBS:powerpc = "-latomic" |
| 29 | |
| 30 | export FINAL_LIBS |
| 31 | |
| 32 | USERADD_PACKAGES = "${PN}" |
| 33 | USERADD_PARAM:${PN} = "--system --home-dir /var/lib/redis -g redis --shell /bin/false redis" |
| 34 | GROUPADD_PARAM:${PN} = "--system redis" |
| 35 | |
| 36 | REDIS_ON_SYSTEMD = "${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}" |
| 37 | |
| 38 | do_compile:prepend() { |
| 39 | (cd deps && oe_runmake hiredis lua linenoise) |
| 40 | } |
| 41 | |
| 42 | do_install() { |
| 43 | export PREFIX=${D}/${prefix} |
| 44 | oe_runmake install |
| 45 | install -d ${D}/${sysconfdir}/redis |
| 46 | install -m 0644 ${WORKDIR}/redis.conf ${D}/${sysconfdir}/redis/redis.conf |
| 47 | install -d ${D}/${sysconfdir}/init.d |
| 48 | install -m 0755 ${WORKDIR}/init-redis-server ${D}/${sysconfdir}/init.d/redis-server |
| 49 | install -d ${D}/var/lib/redis/ |
| 50 | chown redis.redis ${D}/var/lib/redis/ |
| 51 | |
| 52 | install -d ${D}${systemd_system_unitdir} |
| 53 | install -m 0644 ${WORKDIR}/redis.service ${D}${systemd_system_unitdir} |
| 54 | sed -i 's!/usr/sbin/!${sbindir}/!g' ${D}${systemd_system_unitdir}/redis.service |
| 55 | |
| 56 | if [ "${REDIS_ON_SYSTEMD}" = true ]; then |
| 57 | sed -i 's!daemonize yes!# daemonize yes!' ${D}/${sysconfdir}/redis/redis.conf |
| 58 | fi |
| 59 | } |
| 60 | |
| 61 | CONFFILES:${PN} = "${sysconfdir}/redis/redis.conf" |
| 62 | |
| 63 | INITSCRIPT_NAME = "redis-server" |
| 64 | INITSCRIPT_PARAMS = "defaults 87" |
| 65 | |
| 66 | SYSTEMD_SERVICE:${PN} = "redis.service" |