| Andrew Geissler | 517393d | 2023-01-13 08:55:19 -0600 | [diff] [blame^] | 1 | SUMMARY = "Xfce4 Panel" |
| 2 | SECTION = "x11" |
| 3 | LICENSE = "GPL-2.0-or-later" |
| 4 | LIC_FILES_CHKSUM = "file://COPYING;md5=26a8bd75d8f8498bdbbe64a27791d4ee" |
| 5 | DEPENDS = "garcon exo gtk+3 cairo virtual/libx11 libxml2 libwnck3 vala-native" |
| 6 | |
| 7 | inherit xfce gtk-doc gobject-introspection features_check mime-xdg |
| 8 | |
| 9 | # xfce4 depends on libwnck3, gtk+3 and libepoxy need to be built with x11 PACKAGECONFIG. |
| 10 | # cairo would at least needed to be built with xlib. |
| 11 | ANY_OF_DISTRO_FEATURES = "${GTK3DISTROFEATURES}" |
| 12 | |
| 13 | SRC_URI += " \ |
| 14 | file://0001-windowmenu-do-not-display-desktop-icon-when-no-windo.patch \ |
| 15 | file://0002-use-lxdm-to-replace-dm-tool.patch \ |
| 16 | " |
| 17 | SRC_URI[sha256sum] = "be80023fd546587831bab25ded15ae4c9e346289a75744b6ba4cf4ee53794710" |
| 18 | |
| 19 | EXTRA_OECONF += "--disable-vala" |
| 20 | |
| 21 | python populate_packages:prepend() { |
| 22 | plugin_dir = d.expand('${libdir}/xfce4/panel/plugins/') |
| 23 | plugin_name = d.expand('${PN}-plugin-%s') |
| 24 | do_split_packages(d, plugin_dir, r'^lib(.*)\.so$', plugin_name, |
| 25 | '${PN} plugin for %s', extra_depends='', prepend=True, |
| 26 | aux_files_pattern=['${datadir}/xfce4/panel/plugins/%s.desktop', |
| 27 | '${sysconfdir}/xdg/xfce/panel/%s-*', |
| 28 | '${datadir}/icons/hicolor/48x48/apps/*-%s.png', |
| 29 | '${bindir}/*%s*']) |
| 30 | } |
| 31 | |
| 32 | PACKAGES_DYNAMIC += "^${PN}-plugin-.*" |
| 33 | |
| 34 | PACKAGES =+ "${PN}-gtk3" |
| 35 | |
| 36 | FILES:${PN} += "${libdir}/xfce4/panel/migrate \ |
| 37 | ${libdir}/xfce4/panel/wrapper-1.0" |
| 38 | |
| 39 | FILES:${PN}-dev += "${libdir}/xfce4/panel/plugins/*.la" |
| 40 | |
| 41 | FILES:${PN}-gtk3 = " \ |
| 42 | ${libdir}/libxfce4panel-2.0${SOLIBS} \ |
| 43 | ${libdir}/xfce4/panel/wrapper-2.0 \ |
| 44 | " |