| Andrew Geissler | 517393d | 2023-01-13 08:55:19 -0600 | [diff] [blame^] | 1 | SUMMARY = "Open Package Manager" |
| 2 | SUMMARY:libopkg = "Open Package Manager library" |
| 3 | SECTION = "base" |
| 4 | HOMEPAGE = "http://code.google.com/p/opkg/" |
| 5 | DESCRIPTION = "Opkg is a lightweight package management system based on Ipkg." |
| 6 | BUGTRACKER = "http://code.google.com/p/opkg/issues/list" |
| 7 | LICENSE = "GPL-2.0-or-later" |
| 8 | LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \ |
| 9 | file://src/opkg.c;beginline=4;endline=18;md5=d6200b0f2b41dee278aa5fad333eecae" |
| 10 | |
| 11 | DEPENDS = "libarchive" |
| 12 | |
| 13 | PE = "1" |
| 14 | |
| 15 | SRC_URI = "http://downloads.yoctoproject.org/releases/${BPN}/${BPN}-${PV}.tar.gz \ |
| 16 | file://opkg.conf \ |
| 17 | file://0001-opkg_conf-create-opkg.lock-in-run-instead-of-var-run.patch \ |
| 18 | file://0002-opkg-key-remove-no-options-flag-from-gpg-calls.patch \ |
| 19 | file://run-ptest \ |
| 20 | " |
| 21 | |
| 22 | SRC_URI[sha256sum] = "e87fccb575c64d3ac0559444016a2795f12125986a0da896bab97c4a1a2f1b2a" |
| 23 | |
| 24 | # This needs to be before ptest inherit, otherwise all ptest files end packaged |
| 25 | # in libopkg package if OPKGLIBDIR == libdir, because default |
| 26 | # PTEST_PATH ?= "${libdir}/${BPN}/ptest" |
| 27 | PACKAGES =+ "libopkg" |
| 28 | |
| 29 | inherit autotools pkgconfig ptest |
| 30 | |
| 31 | target_localstatedir := "${localstatedir}" |
| 32 | OPKGLIBDIR ??= "${target_localstatedir}/lib" |
| 33 | |
| 34 | PACKAGECONFIG ??= "libsolv" |
| 35 | |
| 36 | PACKAGECONFIG[gpg] = "--enable-gpg,--disable-gpg,\ |
| 37 | gnupg gpgme libgpg-error,\ |
| 38 | ${@ "gnupg" if ("native" in d.getVar("PN")) else "gnupg-gpg"}\ |
| 39 | " |
| 40 | PACKAGECONFIG[curl] = "--enable-curl,--disable-curl,curl" |
| 41 | PACKAGECONFIG[ssl-curl] = "--enable-ssl-curl,--disable-ssl-curl,curl openssl" |
| 42 | PACKAGECONFIG[sha256] = "--enable-sha256,--disable-sha256" |
| 43 | PACKAGECONFIG[zstd] = "--enable-zstd,--disable-zstd,zstd" |
| 44 | PACKAGECONFIG[libsolv] = "--with-libsolv,--without-libsolv,libsolv" |
| 45 | |
| 46 | EXTRA_OECONF:class-native = "--localstatedir=/${@os.path.relpath('${localstatedir}', '${STAGING_DIR_NATIVE}')} --sysconfdir=/${@os.path.relpath('${sysconfdir}', '${STAGING_DIR_NATIVE}')}" |
| 47 | |
| 48 | do_install:append () { |
| 49 | install -d ${D}${sysconfdir}/opkg |
| 50 | install -m 0644 ${WORKDIR}/opkg.conf ${D}${sysconfdir}/opkg/opkg.conf |
| 51 | echo "option lists_dir ${OPKGLIBDIR}/opkg/lists" >>${D}${sysconfdir}/opkg/opkg.conf |
| 52 | echo "option info_dir ${OPKGLIBDIR}/opkg/info" >>${D}${sysconfdir}/opkg/opkg.conf |
| 53 | echo "option status_file ${OPKGLIBDIR}/opkg/status" >>${D}${sysconfdir}/opkg/opkg.conf |
| 54 | |
| 55 | # We need to create the lock directory |
| 56 | install -d ${D}${OPKGLIBDIR}/opkg |
| 57 | } |
| 58 | |
| 59 | do_install_ptest () { |
| 60 | sed -i -e '/@echo $^/d' ${D}${PTEST_PATH}/tests/Makefile |
| 61 | sed -i -e '/@PYTHONPATH=. $(PYTHON) $^/a\\t@if [ "$$?" != "0" ];then echo "FAIL:"$^;else echo "PASS:"$^;fi' ${D}${PTEST_PATH}/tests/Makefile |
| 62 | } |
| 63 | |
| 64 | RDEPENDS:${PN} = "${VIRTUAL-RUNTIME_update-alternatives} opkg-arch-config libarchive" |
| 65 | RDEPENDS:${PN}:class-native = "" |
| 66 | RDEPENDS:${PN}:class-nativesdk = "" |
| 67 | RDEPENDS:${PN}-ptest += "make binutils python3-core python3-compression" |
| 68 | RREPLACES:${PN} = "opkg-nogpg opkg-collateral" |
| 69 | RCONFLICTS:${PN} = "opkg-collateral" |
| 70 | RPROVIDES:${PN} = "opkg-collateral" |
| 71 | |
| 72 | FILES:libopkg = "${libdir}/*.so.* ${OPKGLIBDIR}/opkg/" |
| 73 | |
| 74 | BBCLASSEXTEND = "native nativesdk" |
| 75 | |
| 76 | CONFFILES:${PN} = "${sysconfdir}/opkg/opkg.conf" |