| Andrew Geissler | 517393d | 2023-01-13 08:55:19 -0600 | [diff] [blame^] | 1 | SUMMARY = "A library for bits of crypto UI and parsing etc" |
| 2 | DESCRIPTION = "GCR is a library for displaying certificates, and crypto UI, \ |
| 3 | accessing key stores. It also provides the viewer for crypto files on the \ |
| 4 | GNOME desktop." |
| 5 | HOMEPAGE = "https://gitlab.gnome.org/GNOME/gcr" |
| 6 | BUGTRACKER = "https://gitlab.gnome.org/GNOME/gcr/issues" |
| 7 | |
| 8 | LICENSE = "GPL-2.0-only" |
| 9 | LIC_FILES_CHKSUM = "file://COPYING;md5=55ca817ccb7d5b5b66355690e9abc605" |
| 10 | |
| 11 | DEPENDS = "p11-kit glib-2.0 libgcrypt gnupg-native \ |
| 12 | ${@bb.utils.contains('GI_DATA_ENABLED', 'True', 'libxslt-native', '', d)}" |
| 13 | |
| 14 | CACHED_CONFIGUREVARS += "ac_cv_path_GPG='gpg2'" |
| 15 | |
| 16 | CFLAGS += "-D_GNU_SOURCE" |
| 17 | |
| 18 | GNOMEBASEBUILDCLASS = "meson" |
| 19 | GTKDOC_MESON_OPTION = "gtk_doc" |
| 20 | inherit gnomebase gtk-icon-cache gi-docgen features_check upstream-version-is-even vala gobject-introspection gettext mime mime-xdg |
| 21 | UPSTREAM_CHECK_REGEX = "[^\d\.](?P<pver>3.(?!9\d+)\d+(\.\d+)+)\.tar" |
| 22 | |
| 23 | SRC_URI = "https://download.gnome.org/sources/gcr/3.41/gcr-${PV}.tar.xz;name=archive" |
| 24 | SRC_URI += "file://0001-meson.build-correctly-handle-disabled-ssh_agent-opti.patch" |
| 25 | SRC_URI[archive.sha256sum] = "bb7128a3c2febbfee9c03b90d77d498d0ceb237b0789802d60185c71c4bea24f" |
| 26 | |
| 27 | S = "${WORKDIR}/gcr-${PV}" |
| 28 | |
| 29 | PACKAGECONFIG ??= " \ |
| 30 | ${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)} \ |
| 31 | ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'gtk', '', d)} \ |
| 32 | ${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'gtk', '', d)} \ |
| 33 | " |
| 34 | PACKAGECONFIG[gtk] = "-Dgtk=true,-Dgtk=false,gtk+3" |
| 35 | PACKAGECONFIG[ssh_agent] = "-Dssh_agent=true,-Dssh_agent=false,libsecret,openssh" |
| 36 | #'Use systemd socket activation for server programs' |
| 37 | PACKAGECONFIG[systemd] = "-Dsystemd=enabled,-Dsystemd=disabled,systemd" |
| 38 | |
| 39 | FILES:${PN} += " \ |
| 40 | ${datadir}/dbus-1 \ |
| 41 | ${datadir}/gcr-3 \ |
| 42 | ${systemd_user_unitdir}/gcr-ssh-agent.socket \ |
| 43 | ${systemd_user_unitdir}/gcr-ssh-agent.service \ |
| 44 | " |
| 45 | |
| 46 | # http://errors.yoctoproject.org/Errors/Details/20229/ |
| 47 | ARM_INSTRUCTION_SET:armv4 = "arm" |
| 48 | ARM_INSTRUCTION_SET:armv5 = "arm" |
| 49 | ARM_INSTRUCTION_SET:armv6 = "arm" |
| 50 | |
| 51 | EXTRA_OEMESON += "--cross-file ${WORKDIR}/meson-${PN}.cross" |
| 52 | do_write_config:append() { |
| 53 | cat >${WORKDIR}/meson-${PN}.cross <<EOF |
| 54 | [binaries] |
| 55 | gpg2 = '${bindir}/gpg2' |
| 56 | ssh-add = '${bindir}/ssh-add' |
| 57 | ssh-agent = '${bindir}/ssh-agent' |
| 58 | EOF |
| 59 | } |