Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 1 | SUMMARY = "NetworkManager" |
| 2 | HOMEPAGE = "https://wiki.gnome.org/Projects/NetworkManager" |
| 3 | SECTION = "net/misc" |
| 4 | |
| 5 | LICENSE = "GPL-2.0-or-later & LGPL-2.1-or-later" |
| 6 | LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \ |
| 7 | file://COPYING.LGPL;md5=4fbd65380cdd255951079008b364516c \ |
| 8 | " |
| 9 | |
| 10 | DEPENDS = " \ |
| 11 | coreutils-native \ |
| 12 | intltool-native \ |
| 13 | libxslt-native \ |
| 14 | libnl \ |
| 15 | udev \ |
| 16 | util-linux \ |
| 17 | libndp \ |
| 18 | libnewt \ |
| 19 | curl \ |
| 20 | dbus \ |
| 21 | " |
| 22 | |
| 23 | GNOMEBASEBUILDCLASS = "meson" |
| 24 | inherit gnomebase gettext update-rc.d systemd gobject-introspection gtk-doc update-alternatives upstream-version-is-even |
| 25 | |
| 26 | SRC_URI = " \ |
| 27 | ${GNOME_MIRROR}/NetworkManager/${@gnome_verdir("${PV}")}/NetworkManager-${PV}.tar.xz \ |
| 28 | file://${BPN}.initd \ |
| 29 | file://enable-dhcpcd.conf \ |
| 30 | file://enable-iwd.conf \ |
| 31 | file://0001-do-not-ask-host-for-ifcfg-defaults.patch \ |
| 32 | " |
| 33 | SRC_URI[sha256sum] = "ab855cbe3b41832e9a3b003810e7c7313dfe19e630d29806d14d87fdd1470cab" |
| 34 | |
| 35 | S = "${WORKDIR}/NetworkManager-${PV}" |
| 36 | |
| 37 | # ['auto', 'symlink', 'file', 'netconfig', 'resolvconf'] |
| 38 | NETWORKMANAGER_DNS_RC_MANAGER_DEFAULT ??= "auto" |
| 39 | |
| 40 | # ['dhcpcanon', 'dhclient', 'dhcpcd', 'internal', 'nettools'] |
| 41 | NETWORKMANAGER_DHCP_DEFAULT ??= "internal" |
| 42 | |
| 43 | EXTRA_OEMESON = "\ |
| 44 | -Difcfg_rh=false \ |
| 45 | -Dtests=yes \ |
| 46 | -Dnmtui=true \ |
| 47 | -Dudev_dir=${nonarch_base_libdir}/udev \ |
| 48 | -Dlibpsl=false \ |
| 49 | -Dqt=false \ |
| 50 | -Dconfig_dns_rc_manager_default=${NETWORKMANAGER_DNS_RC_MANAGER_DEFAULT} \ |
| 51 | -Dconfig_dhcp_default=${NETWORKMANAGER_DHCP_DEFAULT} \ |
| 52 | -Ddhcpcanon=false \ |
| 53 | " |
| 54 | |
| 55 | # stolen from https://github.com/void-linux/void-packages/blob/master/srcpkgs/NetworkManager/template |
| 56 | # avoids: |
| 57 | # | ../NetworkManager-1.16.0/libnm-core/nm-json.c:106:50: error: 'RTLD_DEEPBIND' undeclared (first use in this function); did you mean 'RTLD_DEFAULT'? |
| 58 | CFLAGS:append:libc-musl = " \ |
| 59 | -DRTLD_DEEPBIND=0 \ |
| 60 | " |
| 61 | |
| 62 | do_compile:prepend() { |
| 63 | export GI_TYPELIB_PATH="${B}}/src/libnm-client-impl${GI_TYPELIB_PATH:+:$GI_TYPELIB_PATH}" |
| 64 | } |
| 65 | |
| 66 | PACKAGECONFIG ??= "readline nss ifupdown dnsmasq nmcli vala \ |
| 67 | ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'systemd', bb.utils.contains('DISTRO_FEATURES', 'x11', 'consolekit', '', d), d)} \ |
| 68 | ${@bb.utils.contains('DISTRO_FEATURES', 'bluetooth', 'bluez5', '', d)} \ |
| 69 | ${@bb.utils.filter('DISTRO_FEATURES', 'wifi polkit', d)} \ |
| 70 | ${@bb.utils.contains('DISTRO_FEATURES', 'selinux', 'selinux audit', '', d)} \ |
| 71 | " |
| 72 | |
| 73 | inherit ${@bb.utils.contains('PACKAGECONFIG', 'nmcli', 'bash-completion', '', d)} |
| 74 | inherit ${@bb.utils.contains('PACKAGECONFIG', 'vala', 'vala', '', d)} |
| 75 | |
| 76 | PACKAGECONFIG[systemd] = "\ |
| 77 | -Dsystemdsystemunitdir=${systemd_unitdir}/system -Dsession_tracking=systemd,\ |
| 78 | -Dsystemdsystemunitdir=no -Dsystemd_journal=false -Dsession_tracking=no\ |
| 79 | " |
| 80 | PACKAGECONFIG[polkit] = "-Dpolkit=true,-Dpolkit=false,polkit" |
| 81 | PACKAGECONFIG[bluez5] = "-Dbluez5_dun=true,-Dbluez5_dun=false,bluez5" |
| 82 | # consolekit is not picked by shlibs, so add it to RDEPENDS too |
| 83 | PACKAGECONFIG[consolekit] = "-Dsession_tracking_consolekit=true,-Dsession_tracking_consolekit=false,consolekit,consolekit" |
| 84 | PACKAGECONFIG[modemmanager] = "-Dmodem_manager=true,-Dmodem_manager=false,modemmanager mobile-broadband-provider-info" |
| 85 | PACKAGECONFIG[ppp] = "-Dppp=true,-Dppp=false,ppp,ppp" |
| 86 | PACKAGECONFIG[dnsmasq] = "-Ddnsmasq=${bindir}/dnsmasq" |
| 87 | PACKAGECONFIG[nss] = "-Dcrypto=nss,,nss" |
| 88 | PACKAGECONFIG[resolvconf] = "-Dresolvconf=${base_sbindir}/resolvconf,-Dresolvconf=no,,resolvconf" |
| 89 | PACKAGECONFIG[gnutls] = "-Dcrypto=gnutls,,gnutls" |
| 90 | PACKAGECONFIG[wifi] = "-Dwext=true -Dwifi=true,-Dwext=false -Dwifi=false" |
| 91 | PACKAGECONFIG[iwd] = "-Diwd=true,-Diwd=false" |
| 92 | PACKAGECONFIG[ifupdown] = "-Difupdown=true,-Difupdown=false" |
| 93 | PACKAGECONFIG[cloud-setup] = "-Dnm_cloud_setup=true,-Dnm_cloud_setup=false" |
| 94 | PACKAGECONFIG[nmcli] = "-Dnmcli=true,-Dnmcli=false" |
| 95 | PACKAGECONFIG[readline] = "-Dreadline=libreadline,,readline" |
| 96 | PACKAGECONFIG[libedit] = "-Dreadline=libedit,,libedit" |
| 97 | PACKAGECONFIG[ovs] = "-Dovs=true,-Dovs=false,jansson" |
| 98 | PACKAGECONFIG[audit] = "-Dlibaudit=yes,-Dlibaudit=no" |
| 99 | PACKAGECONFIG[selinux] = "-Dselinux=true,-Dselinux=false,libselinux" |
| 100 | PACKAGECONFIG[vala] = "-Dvapi=true,-Dvapi=false" |
| 101 | PACKAGECONFIG[dhcpcd] = "-Ddhcpcd=yes,-Ddhcpcd=no,,dhcpcd" |
| 102 | PACKAGECONFIG[dhclient] = "-Ddhclient=yes,-Ddhclient=no,,dhcp" |
| 103 | PACKAGECONFIG[concheck] = "-Dconcheck=true,-Dconcheck=false" |
| 104 | |
| 105 | |
| 106 | PACKAGES =+ " \ |
| 107 | ${PN}-adsl \ |
| 108 | ${PN}-bluetooth \ |
| 109 | ${PN}-cloud-setup \ |
| 110 | ${PN}-nmcli ${PN}-nmcli-doc \ |
| 111 | ${PN}-nmtui ${PN}-nmtui-doc \ |
| 112 | ${PN}-wifi \ |
| 113 | ${PN}-wwan \ |
| 114 | ${PN}-ovs ${PN}-ovs-doc \ |
| 115 | ${PN}-ppp \ |
| 116 | " |
| 117 | |
| 118 | SYSTEMD_PACKAGES = "${PN} ${PN}-cloud-setup" |
| 119 | |
| 120 | NETWORKMANAGER_PLUGINDIR = "${libdir}/NetworkManager/${PV}" |
| 121 | |
| 122 | FILES:${PN}-adsl = "${NETWORKMANAGER_PLUGINDIR}/libnm-device-plugin-adsl.so" |
| 123 | |
| 124 | FILES:${PN}-bluetooth = "${NETWORKMANAGER_PLUGINDIR}/libnm-device-plugin-bluetooth.so" |
| 125 | |
| 126 | FILES:${PN}-cloud-setup = " \ |
| 127 | ${libexecdir}/nm-cloud-setup \ |
| 128 | ${systemd_system_unitdir}/nm-cloud-setup.service \ |
| 129 | ${systemd_system_unitdir}/nm-cloud-setup.timer \ |
| 130 | ${libdir}/NetworkManager/dispatcher.d/90-nm-cloud-setup.sh \ |
| 131 | ${libdir}/NetworkManager/dispatcher.d/no-wait.d/90-nm-cloud-setup.sh \ |
| 132 | " |
| 133 | ALLOW_EMPTY:${PN}-cloud-setup = "1" |
| 134 | SYSTEMD_SERVICE:${PN}-cloud-setup = "${@bb.utils.contains('PACKAGECONFIG', 'cloud-setup', 'nm-cloud-setup.service nm-cloud-setup.timer', '', d)}" |
| 135 | |
| 136 | FILES:${PN}-nmcli = " \ |
| 137 | ${bindir}/nmcli \ |
| 138 | " |
| 139 | |
| 140 | FILES:${PN}-nmcli-doc = " \ |
| 141 | ${mandir}/man1/nmcli* \ |
| 142 | " |
| 143 | |
| 144 | FILES:${PN}-nmtui = " \ |
| 145 | ${bindir}/nmtui \ |
| 146 | ${bindir}/nmtui-edit \ |
| 147 | ${bindir}/nmtui-connect \ |
| 148 | ${bindir}/nmtui-hostname \ |
| 149 | " |
| 150 | |
| 151 | FILES:${PN}-nmtui-doc = " \ |
| 152 | ${mandir}/man1/nmtui* \ |
| 153 | " |
| 154 | |
| 155 | FILES:${PN}-wifi = "${NETWORKMANAGER_PLUGINDIR}/libnm-device-plugin-wifi.so" |
| 156 | |
| 157 | FILES:${PN}-wwan = "\ |
| 158 | ${NETWORKMANAGER_PLUGINDIR}/libnm-device-plugin-wwan.so \ |
| 159 | ${NETWORKMANAGER_PLUGINDIR}/libnm-wwan.so \ |
| 160 | " |
| 161 | |
| 162 | FILES:${PN}-ovs = "\ |
| 163 | ${NETWORKMANAGER_PLUGINDIR}/libnm-device-plugin-ovs.so \ |
| 164 | ${systemd_system_unitdir}/NetworkManager.service.d/NetworkManager-ovs.conf \ |
| 165 | " |
| 166 | |
| 167 | FILES:${PN}-ovs-doc = "\ |
| 168 | ${mandir}/man7/nm-openvswitch.7* \ |
| 169 | " |
| 170 | |
| 171 | FILES:${PN}-ppp = "\ |
| 172 | ${NETWORKMANAGER_PLUGINDIR}/libnm-ppp-plugin.so \ |
| 173 | ${libdir}/pppd/*/nm-pppd-plugin.so \ |
| 174 | " |
| 175 | |
| 176 | FILES:${PN}-dev += " \ |
| 177 | ${libdir}/pppd/*/*.la \ |
| 178 | ${libdir}/NetworkManager/*.la \ |
| 179 | ${NETWORKMANAGER_PLUGINDIR}/*.la \ |
| 180 | " |
| 181 | |
| 182 | FILES:${PN} += " \ |
| 183 | ${libexecdir} \ |
| 184 | ${libdir}/NetworkManager \ |
| 185 | ${nonarch_libdir}/firewalld/zones \ |
| 186 | ${nonarch_libdir}/NetworkManager/conf.d \ |
| 187 | ${nonarch_libdir}/NetworkManager/dispatcher.d \ |
| 188 | ${nonarch_libdir}/NetworkManager/dispatcher.d/pre-down.d \ |
| 189 | ${nonarch_libdir}/NetworkManager/dispatcher.d/pre-up.d \ |
| 190 | ${nonarch_libdir}/NetworkManager/dispatcher.d/no-wait.d \ |
| 191 | ${nonarch_libdir}/NetworkManager/VPN \ |
| 192 | ${nonarch_libdir}/NetworkManager/system-connections \ |
| 193 | ${datadir}/polkit-1 \ |
| 194 | ${datadir}/dbus-1 \ |
| 195 | ${nonarch_base_libdir}/udev/* \ |
| 196 | ${systemd_system_unitdir} \ |
| 197 | " |
| 198 | |
| 199 | RRECOMMENDS:${PN} += "\ |
| 200 | iptables \ |
| 201 | ${@bb.utils.filter('PACKAGECONFIG', 'dnsmasq', d)} \ |
| 202 | ${@bb.utils.contains('PACKAGECONFIG','adsl','${PN}-adsl','',d)} \ |
| 203 | ${@bb.utils.contains('PACKAGECONFIG','bluez5','${PN}-bluetooth','',d)} \ |
| 204 | ${@bb.utils.contains('PACKAGECONFIG','cloud-setup','${PN}-cloud-setup','',d)} \ |
| 205 | ${@bb.utils.contains('PACKAGECONFIG','nmcli','${PN}-nmcli','',d)} \ |
| 206 | ${@bb.utils.contains('PACKAGECONFIG','nmtui','${PN}-nmtui','',d)} \ |
| 207 | ${@bb.utils.contains('PACKAGECONFIG','wifi','${PN}-wifi','',d)} \ |
| 208 | ${@bb.utils.contains('PACKAGECONFIG','wwan','${PN}-wwan','',d)} \ |
| 209 | ${@bb.utils.contains('PACKAGECONFIG','ovs','${PN}-ovs','',d)} \ |
| 210 | ${@bb.utils.contains('PACKAGECONFIG','ppp','${PN}-ppp','',d)} \ |
| 211 | " |
| 212 | RCONFLICTS:${PN} = "connman" |
| 213 | |
| 214 | |
| 215 | INITSCRIPT_NAME = "network-manager" |
| 216 | SYSTEMD_SERVICE:${PN} = "\ |
| 217 | NetworkManager.service \ |
| 218 | NetworkManager-dispatcher.service \ |
| 219 | " |
| 220 | |
| 221 | ALTERNATIVE_PRIORITY = "100" |
| 222 | ALTERNATIVE:${PN} = "${@bb.utils.contains('DISTRO_FEATURES','systemd','resolv-conf','',d)}" |
| 223 | ALTERNATIVE_TARGET[resolv-conf] = "${@bb.utils.contains('DISTRO_FEATURES','systemd','${sysconfdir}/resolv-conf.NetworkManager','',d)}" |
| 224 | ALTERNATIVE_LINK_NAME[resolv-conf] = "${@bb.utils.contains('DISTRO_FEATURES','systemd','${sysconfdir}/resolv.conf','',d)}" |
| 225 | |
| 226 | do_install:append() { |
| 227 | install -Dm 0755 ${WORKDIR}/${BPN}.initd ${D}${sysconfdir}/init.d/network-manager |
| 228 | |
| 229 | rm -rf ${D}/run ${D}${localstatedir}/run |
| 230 | |
| 231 | if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then |
| 232 | # For read-only filesystem, do not create links during bootup |
| 233 | ln -sf ../run/NetworkManager/resolv.conf ${D}${sysconfdir}/resolv-conf.NetworkManager |
| 234 | |
| 235 | # systemd v210 and newer do not need this rule file |
| 236 | rm ${D}/${nonarch_base_libdir}/udev/rules.d/84-nm-drivers.rules |
| 237 | fi |
| 238 | |
| 239 | # Enable iwd if compiled |
| 240 | if ${@bb.utils.contains('PACKAGECONFIG','iwd','true','false',d)}; then |
| 241 | install -Dm 0644 ${WORKDIR}/enable-iwd.conf ${D}${libdir}/NetworkManager/conf.d/enable-iwd.conf |
| 242 | fi |
| 243 | |
| 244 | # Enable dhcpd if compiled |
| 245 | if ${@bb.utils.contains('PACKAGECONFIG','dhcpcd','true','false',d)}; then |
| 246 | install -Dm 0644 ${WORKDIR}/enable-dhcpcd.conf ${D}${libdir}/NetworkManager/conf.d/enable-dhcpcd.conf |
| 247 | fi |
| 248 | } |